Comment faire pour exécuter un fichier bat à jour spécifique de la semaine/heure?

J'ai un fichier bat qui je veux courir à jour/heure dans chaque trimestre pendant un an.
Je suis nouveau sur la ligne de commande et je sais comment l'exécuter via un planificateur de tâches, ce qui est très facile.

Disons que pour chaque trimestre, pour la 1ère et la 2ème mois, mon fichier bat doit s'exécuter d'autres semaines. Pour le troisième mois d'un trimestre, il devrait fonctionner de façon hebdomadaire. De temps Possible serait tôt le matin 6:00 Comment aurais-je le faire? S'il vous plaît laissez-moi savoir. Merci.

InformationsquelleAutor Nemo | 2012-06-13
  1. 2

    Il y a le le planificateur de tâches windows, mais je doute que vous allez être en mesure de faire un horaire avancé avec juste le planificateur de tâche de windows.

    Ce que je voudrais faire c'est d'écrire de la programmation logique (par exemple, lorsque vous souhaitez que votre fichier de commandes pour exécuter) dans certains langage de haut niveau (C#, JAVA, etc.), ensuite appeler ce programme au début de votre fichier de commandes pour voir si c'est un rendez-vous.

    Le fichier de commandes peut être configuré pour s'exécuter chaque jour ou plusieurs fois par jour si nécessaire) en utilisant le planificateur de tâche de windows, mais il ne serait que de faire la "choses sérieuses" si votre C#/JAVA programme a indiqué que c'était un jour vous vous préoccupiez.

    • Merci dcp pour votre i/p. Si le Planificateur de tâches windows est une meilleure façon de le faire - à l'horaire avancé, je vais le faire de cette façon. J'étais en train de penser à la création d'un script vbs qui pourrait appeler et exécuter mon fichier bat à la date prévue, en temps comme mentionné dans ma question. De cette façon, je n'aurai pas à planifier mon fichier bat pour l'exécuter à plusieurs reprises par le planificateur. S'il vous plaît laissez-moi savoir si c'est faisable.? Merci encore.
    • Le fichier bat encore besoin de courir au moins une fois par jour, et vous pouvez utiliser le planificateur de pour que. Si votre script n'aurez pas besoin de s'exécuter à des moments différents, vous pouvez simplement exécuter la même heure chaque jour. Vous pouvez probablement le code de la vérification de la date de la logique en vbs, aussi longtemps que vbs a calendrier des objets, etc. où vous pouvez voir si il est le premier trimestre, etc. Mais oui, je pense que c'est faisable.
    InformationsquelleAutor dcp
  2. 3

    Le fichier de commandes ci-dessous faire ce que vous voulez:

    @echo off
rem Get the "monthInQuarter@weekInMonth" value of the last run:
set /P lastRun=< scheduler.txt
rem Get values from today date
for /F "tokens=1,2 delims=/" %%a in ("%date%") do (
   set /A "monthInQuarter=(1%%a-100)%%4, weekInMonth=(1%%b-101)/7+1, oddWeekInMonth=weekInMonth%%2"
)
if %weekInMonth% gtr 4 (
  set /A weekInMonth=4, oddWeekInMonth=0
)
set thisRun=%monthInQuarter%@%weekInMonth%
rem For 1st and 2nd month in each quarter:
if %monthInQuarter% leq 2 (
   rem For alternative weeks (1=yes, 2=no, 3=yes, 4=no):
   if %oddWeekInMonth% equ 1 (
      if "%thisRun%" neq "%lastRun%" (
         echo %thisRun%> scheduler.txt
         call :TheProcess
      )
   )
rem For the third month of a quarter:
) else if %monthInQuarter% equ 3 (
   rem Run it weekly:
   if "%thisRun%" neq "%lastRun%" (
      echo %thisRun%> scheduler.txt
      call :TheProcess
   )
)
exit

:TheProcess
rem Place here the desired process, ie:
echo This run only on selected weeks!
exit /B

    Ce tableau de valeurs peut aider à comprendre la programmation logique:

    month:          1 2 3 4 5 6 7 8 9 10 11 12
monthInQuarter: 1 2 3 0 1 2 3 0 1  2  3  0

day:            1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 ...
weekInMonth:    1 1 1 1 1 1 1 2 2  2  2  2  2  2  3  3  3  3  3 ...
oddWeekInMonth: 1 1 1 1 1 1 1 0 0  0  0  0  0  0  1  1  1  1  1 ...

    Notes:

    • Ce fichier de commandes supposer que ECHO %DATE% de la commande affiche la date en JJ/MM/AAAA format de gauche de zéro si le mois ou le jour est inférieur à 10. Si ce n'est pas votre format de date locale, une légère modification est nécessaire.

    • Bien qu'il est possible de modifier ce programme fonctionne avec n'importe quel format de date, je pense que ce n'est PAS d'un usage général de fichier, mais un très particulier de la demande pour vos besoins spécifiques.

    • Ce programme doit s'exécuter tous les jours à 6:00 am via le planificateur de tâches.

    • La première fois le programme exécuté "Le système ne peut pas trouver le fichier spécifié." message d'apparaître, avant d'auxiliaire SCHEDULE.TXT le fichier sera créé.

    J'espère que cela aide.

    Antonio

    PS - je ne pense pas que ce problème peut être résolu d'une manière plus facile via script vbs ou C#, JAVA, etc...

    • Grâce Aacini pour votre effort. J'aimerais comprendre votre code. J'ai moins d'expérience dans l'écriture d'un fichier de commandes. Quelques commentaires supplémentaires à chaque ligne pourrait m'aider à mieux le comprendre. Juste une pensée. Merci encore. 🙂 Votre aide est grandement appréciée. 🙂
    InformationsquelleAutor Aacini