Comment faire pour fusionner les données provenant de deux bases de données access 2007

Si vous avez une table, tblFoo, avec la même structure dans les deux bases de données que vous pourriez essayer d'ajouter le contenu d'un tableau à l'autre. Donc, avec un.accdb ouvert:

INSERT INTO tblFoo
SELECT *
FROM tblFoo IN 'C:\YourPath\b.accdb';

En fait, je suis sceptique sur cette approche va travailler pour vous parce que vous l'avez mentionné, les clés primaires et les doublons. Vous devrez peut-être plus de chance en ajoutant du contenu à partir de deux copies de tblFoo dans une troisième table, tblFooMaster, qui n'ont pas de contraintes primary key ou unique. Dans cette situation, vous devez comprendre ce que vous voulez faire avec les doublons dans tblFooMaster.

J'espère que vous avez des sauvegardes des bases de données avant de tenter toute forme de consolidation.

Modifier: Si cette méthode est satisfaisante, vous n'avez pas besoin de créer une requête pour chaque table. L'utiliser pour générer et exécuter la requête pour vous.

Public Sub ImportTableData(ByVal pstrTable As String, _
        ByVal pstrDb As String)

    Dim strSql As String
    strSql = "INSERT INTO " & pstrTable & vbNewLine & _
        "SELECT *" & vbNewLine & _
        "FROM " & pstrTable & " IN '" & pstrDb & "';"
    'caller will handle errors '
    CurrentDb.Execute strSql, dbFailOnError
End Sub

Depuis votre préférence est de faire le tableau des transferts comme une seule opération, vous pouvez avoir une autre procédure VBA nourrir vos noms de table pour le ImportTableData procédure.

Public Sub ImportAllTables()
    Const cstrDb As String = "C:\YourPath\b.accdb"
    Dim tdf As TableDef
    Dim strMsg As String

On Error GoTo ErrorHandler

    For Each tdf In CurrentDb.TableDefs
        'ignore system and temporary tables '
        If Not (tdf.Name Like "MSys*" Or _
                tdf.Name Like "~*") Then
            Call ImportTableData(tdf.Name, cstrDb)
        End If
    Next tdf

ExitHere:
    On Error GoTo 0
    Set tdf = Nothing
    Exit Sub

ErrorHandler:
    Select Case Err.Number
    Case 3078
        strMsg = "Input table " & tdf.Name & " not found."
        MsgBox strMsg
        Resume Next
    Case Else
        strMsg = "Error " & Err.Number & " (" & Err.Description _
            & ") in procedure ImportAllTables"
        MsgBox strMsg
        GoTo ExitHere
    End Select
End Sub