Comment faire pour installer automatiquement Emacs paquets en spécifiant une liste de noms de package?

Je suis en utilisant package à gérer mon Emacs extensions. Afin de synchroniser mon Emacs paramètres sur les différents ordinateurs, je voudrais un moyen de spécifier une liste de noms de package dans .emacs fichier, puis package peut automatiquement rechercher et installer les paquets, de sorte que je n'ai pas besoin de les installer manuellement en appelant M-x package-list-packages. Comment faire?

Si vous êtes en s'appuyant sur le gestionnaire de paquets pour installer votre configuration, vous voudrez probablement pour spécifier les versions exactes (et si ce n'est pas possible, pensez à l'enregistrer tout dans le contrôle de version de vous-même), car sinon vous ne sont pas protégés, alors que les bibliothèques sont mises à jour et commencer à entrer en conflit.

InformationsquelleAutor RNA | 2012-04-10

101
```
; list the packages you want
(setq package-list '(package1 package2))

; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
                         ("gnu" . "http://elpa.gnu.org/packages/")
                         ("marmalade" . "http://marmalade-repo.org/packages/")))

; activate all the packages (in particular autoloads)
(package-initialize)

; fetch the list of packages available 
(unless package-archive-contents
  (package-refresh-contents))

; install the missing packages
(dolist (package package-list)
  (unless (package-installed-p package)
    (package-install package)))
```
- Je préfère: (ou (fichier-existe-p package user-dir) (paquet-de l'actualisation de la table des matieres)) de la accepté de répondre. Le paquet d'actualisation ici augmente le temps de démarrage sur les systèmes qui ont déjà des packages installés. Le reste de cette réponse, c'est parfait, cependant.
- Symbole de la valeur de la variable est nulle: package-archive-contenu. Est-il possible que je peux faire une liste dans .emacs et l'utilisation d'une fonction définie dans il pour installer tous les paquets dans la liste(ignorer si elle est installée, la mise à jour si vieux) comme Vundle pour Vim. Parce que je ne veux pas pousser tous les paquets dans elpa/ pour github, j'ai à faire à chaque fois qu'un paquet est mis à jour en package.
- Que voulez-vous dire @rfinz ? Il ressemble à package-refresh-contents ne serait exécuté si le package n'est pas installé? Comment est (or (file-exists-p package-user-dir)) mieux / comment est-il même pas vérifier si les paquets sont installés?
- oui vous avez raison! Il vérifie si l'utilisateur du répertoire du package existe, et si ça ne marche pas il court package-refresh-contents. Ce sera probablement seulement être exécuté la première fois que vous ouvrez emacs sur un nouvel ordinateur, et je suis très bien avec ça. Si un paquet doit être mis à jour qui peut être fait manuellement.
- Si vous utilisez déjà use-package, vous pouvez utiliser le :ensure mot-clé pour installer les paquets automatiquement. Cela définit aussi package-selected-packages si vous devez accéder à la liste des paquets à travers le personnaliser, ou par programmation.
- Quelle est la différence entre cela et l'aide d'emacs auto install?
InformationsquelleAutor Nicolas Dudebout
45

Sur la base des observations par Profpatsch et réponses ci-dessous:
```
(defun ensure-package-installed (&rest packages)
  "Assure every package is installed, ask for installation if it’s not.

Return a list of installed packages or nil for every skipped package."
  (mapcar
   (lambda (package)
     ;; (package-installed-p 'evil)
     (if (package-installed-p package)
         nil
       (if (y-or-n-p (format "Package %s is missing. Install it? " package))
           (package-install package)
         package)))
   packages))

;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
    (package-refresh-contents))

(ensure-package-installed 'iedit 'magit) ;  --> (nil nil) if iedit and magit are already installed

;; activate installed packages
(package-initialize)
```
- Est-ce que ... une carte avec des effets secondaires? Et abusant de la paresse de or? Oh, wow.
- Eh bien, mapc est les effets secondaires. Mais pourquoi ne pas utiliser unless?
- Précédemment, j'ai utilisé ce code et, parfois, il ne fonctionne pas pour une raison inconnue, en disant: "Paquet bla-bla n'est pas disponible pour l'installation" (ici bla-bla est toujours le premier élément de la liste). Si j'installe le premier paquet manuellement, tout fonctionne bien, mais ce n'est pas une solution. De toute façon, la réponse de Nicolas Dudebois fonctionne très bien.
- mise à jour pour le rendre robuste à la première installation.
- J'avais besoin de (package-initialize) avant la référence à package-user-dir
- Alors, où nous avons fait la liste des paquets que nous voulons installé?
- La liste qui figure dans package-activated-list après l'appel de package-initialize doit être réglé à une variable comme (setq packages '(all yaml-mode)) et puis (apply #'ensure-package-installed packages)
- Deux questions/améliorations: 1) Comment peut-on reporter la o-ou-n-p requête jusqu'à ce qu'une fenêtre est présenté à l'utilisateur, c'est à dire de ne pas exécuter cette fonction lors du démarrage de l'emacs démon. 2) Comment puis-je toujours mettre à jour le package-list avec la dernière avant d'essayer de l'installer? Les deux sont des problèmes que j'ai rencontrés lors de l'utilisation de cet extrait de code. Merci.
- Cela ne semble pas fonctionner me dit que le package n'est pas disponible pour l'installation...
- problème détecté, l'elpa dir existé et qui a empêché le script à partir de l'actualisation de l'index de paquets......
InformationsquelleAutor RNA
38

Emacs 25.1+ conserve automatiquement la trace de l'utilisateur, les logiciels installés dans l'personnalisable package-selected-packages variable. package-install va mettre à jour le personnaliser variable, et vous pouvez installer tous les packages sélectionnés avec le package-install-selected-packages fonction.

Une autre pratique de l'avantage de cette approche est que vous pouvez utiliser package-autoremove pour supprimer automatiquement les paquets qui ne sont pas inclus dans package-selected-packages (bien qu'il permettra de préserver les dépendances).
```
(package-initialize)
(unless package-archive-contents
  (package-refresh-contents))
(package-install-selected-packages)
```
Source: http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html

InformationsquelleAutor Nick McCurdy

Voici le code que j'utilise pour Emacs Prélude:

(require 'package)
(require 'melpa)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)

(setq url-http-attempt-keepalives nil)

(defvar prelude-packages
  '(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
                   gist haml-mode haskell-mode helm helm-projectile inf-ruby
                   magit magithub markdown-mode paredit projectile
                   python sass-mode rainbow-mode scss-mode solarized-theme
                   volatile-highlights yaml-mode yari yasnippet zenburn-theme)
  "A list of packages to ensure are installed at launch.")

(defun prelude-packages-installed-p ()
  (loop for p in prelude-packages
        when (not (package-installed-p p)) do (return nil)
        finally (return t)))

(unless (prelude-packages-installed-p)
  ;; check for new packages (package versions)
  (message "%s" "Emacs Prelude is now refreshing its package database...")
  (package-refresh-contents)
  (message "%s" " done.")
  ;; install the missing packages
  (dolist (p prelude-packages)
    (when (not (package-installed-p p))
      (package-install p))))

(provide 'prelude-packages)

Si vous ne l'utilisez pas MELPA vous n'avez pas besoin de l'exiger (et si vous ne melpa.el a obtenu d'être sur votre load-path (ou installé via MELPA). Le package db n'est pas actualisé à chaque fois (ce qui permettrait de ralentir le démarrage de manière significative) - uniquement s'il y a désinstallé les paquets présents.

En fonction de votre réponse, j'ai modifié un peu et supprimé l'usage de la "boucle" github.com/slipset/emacs/blob/master/ensure-packages.el
Oui, cet exemple est vraiment plus complexe que cela doit l'être. Le code que j'utilise actuellement en Prélude est beaucoup plus simple.

InformationsquelleAutor Bozhidar Batsov

7

Personne n'a mentionné Fût encore, mais il est tout à fait approprié pour cette tâche.

Fondamentalement, vous créez ~/.emacs.d/Cask liste des paquets que vous voulez installer. Par exemple:
```
(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc
```
De course cask à partir de la ligne de commande va installer ces packages pour vous, et toutes les dépendances dont ils ont besoin.

Aussi, vous pouvez automatiquement mettre à jour les paquets installés à l'aide de cask update.
- J'ai été en utilisant fût dans mon fichiers de configuration utilisateur pour un certain temps maintenant, fonctionne très bien.
- Dommage Fût semble avoir besoin de Python. Je me demande si il y a un elisp seule alternative? (C'est dans un paquet; évidemment, les réponses sur cette page, répondre à la elisp exigence.)
- Le script python est une fine enveloppe fût-cli.el, que vous pouvez appeler directement si vous le souhaitez: /path/to/emacs -Q --script /path/to/cask/cask-cli.el -- [args]
- Intéressant! N'est-il pas possible de l'utiliser à partir de l'intérieur d'Emacs? Je suppose que c'est parce que c'est aussi un outil de dev, mais il est plutôt rare d'avoir à sortir de Emacs pour une CLI pour gérer Emacs.
InformationsquelleAutor Alastair
4

Appel package-install avec le nom du package, comme un symbole. Vous pouvez trouver les noms de vos colis en appelant package-install de manière interactive et de remplir sur le nom. La fonction package-installed-p vous permettra de savoir si il est déjà installé.

Par exemple:
```
(mapc
 (lambda (package)
   (or (package-installed-p package)
       (package-install package)))
 '(package1 package2 package3))
```
- Merci, mais j'ai une erreur error: Package dired+ "n'est pas disponible pour l'installation". dired+ est un paquet j'ai essayé avec ton code.
- Ne dired+ afficher lorsque vous exécutez package-list-packages? Je crois que vous aurez besoin d'ajouter de la marmelade ou melpa à votre package-archives. Si oui, pouvez-vous courir (package-install 'dired+)?
- oui, il se montre, en fait je l'avais installé il déjà
- Dans ce cas, (package-installed-p 'dired+) doit retourner t et il sera ignoré dans le code ci-dessus.
- Le package-installed-p seul fonctionne très bien, mais l'ensemble du bloc de code qui ne fonctionne pas. J'ai essayé plusieurs paquets.
- Assurez-vous de ne pas citer de noms de paquets à l'intérieur d'une cité de la liste. Utilisez quelque chose comme '(dired+), pas '('dired+)
- Si je ne suis pas familier avec elisp, je ne vais pas faire cette erreur. Je pense que le problème est que les données de liste de paquet n'est pas chargé automatiquement. L'erreur est allé si j'ajoute package-initialize ou package-refresh-contents avant votre code
- Regarde comme le prélude à Nicolas Dudebout de réponse permet de résoudre ce problème.
InformationsquelleAutor ataylor

(require 'cl)
(require 'package)

(setq cfg-var:packages '(
       emmet-mode
       ergoemacs-mode
       flycheck
       flycheck-pyflakes
       monokai-theme
       py-autopep8
       py-isort
       rainbow-mode
       yafolding
       yasnippet))

(defun cfg:install-packages ()
    (let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
        (when pkgs
            (message "%s" "Emacs refresh packages database...")
            (package-refresh-contents)
            (message "%s" " done.")
            (dolist (p cfg-var:packages)
                (package-install p)))))

(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)

(cfg:install-packages)

InformationsquelleAutor Dunaevsky Maxim

J'aime vérifier si l'utilisateur souhaite installer les paquets d'abord comme le fait le cette réponse. Je suis aussi rafraîchissante mon contenu de l'emballage une fois avant d'installer quoi que ce soit. Je ne suis pas sûr si c'est le meilleur moyen, mais je ne pense pas que les réponses les plus fréquentes étaient le faire pour moi.

(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))

(require 'cl)

(setq pkgs-to-install
      (let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
        (remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))

(when (> (length pkgs-to-install) 0)
  (package-refresh-contents)
  (dolist (pkg pkgs-to-install)
    (package-install pkg)))

InformationsquelleAutor Frank Henard

J'ai rencontré un problème que rien ne s'est passé après l'ajout de (package-install 'org) en .emacs. J'ai voulu installer la mise à jour de la version de org-mode et intégré dans la org-mode est assez vieux.

J'ai creusé le code source de package-install de Emacs 25.3.1. La fonction auto déjà de vérifier si un paquet est installé ou pas et refuse de l'installer si le paquet est déjà installé. Si la case à (unless (package-installed-p package) ...) de réponse Dix million quatre vingt treize mille trois cent douze est en fait injustifiés.

(defun package-install (pkg &optional dont-select)
  "Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'.  Interactively, prompt for its name.

If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.

If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
  (interactive
   (progn
     ;; Initialize the package system to get the list of package
     ;; symbols for completion.
     (unless package--initialized
       (package-initialize t))
     (unless package-archive-contents
       (package-refresh-contents))
     (list (intern (completing-read
                    "Install package: "
                    (delq nil
                          (mapcar (lambda (elt)
                                    (unless (package-installed-p (car elt))
                                      (symbol-name (car elt))))
                                  package-archive-contents))
                    nil t))
           nil)))
  (add-hook 'post-command-hook #'package-menu--post-refresh)
  (let ((name (if (package-desc-p pkg)
                  (package-desc-name pkg)
                pkg)))
    (unless (or dont-select (package--user-selected-p name))
      (package--save-selected-packages
       (cons name package-selected-packages)))
    (if-let ((transaction
              (if (package-desc-p pkg)
                  (unless (package-installed-p pkg)
                    (package-compute-transaction (list pkg)
                                                 (package-desc-reqs pkg)))
                (package-compute-transaction () (list (list pkg))))))
        (package-download-transaction transaction)
      (message "`%s' is already installed" name))))

Le haut- org-mode est aussi installé et package-install refuse d'installer la version la plus récente de ELPA. Après avoir passé quelque temps à la lecture de package.el, je suis venu avec la solution suivante.

(dolist (package (package-compute-transaction
                  () (list (list 'python '(0 25 1))
                           (list 'org '(20171211)))))
  ;; package-download-transaction may be more suitable here and
  ;; I don't have time to check it
  (package-install package))

La raison pour laquelle cela fonctionne est que package-* la famille de fonctions gérer les arguments de façon différente selon que si c'est un symbole ou un package-desc objet. Vous ne pouvez spécifier des informations de version pour package-install via un package-desc objet.

InformationsquelleAutor Lei Zhao

Voici la mienne, c'est plus court 🙂

(mapc
 (lambda (package)
   (unless (package-installed-p package)
     (progn (message "installing %s" package)
            (package-refresh-contents)
            (package-install package))))
 '(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode rainbow-mode fontawesome))

InformationsquelleAutor yPhil

Vous devez vous connecter pour publier un commentaire.