Comment faire pour rediriger les ex sortie de la commande dans le tampon courant ou d'un fichier?

Comment puis-je rediriger ou de rediriger la sortie d'une commande ex dans ma mémoire tampon ou un fichier?

Par exemple, je veux lire le contenu de tous les registres de la mémoire tampon, ce qui en mode ex est indiqué à l'aide d' :registers.

vi.stackexchange.com/a/13881/10254 peut-être d'intérêt, en gros obtenir l'entrée, puis de lancer la commande, de capturer et mettre. Avec vimscript fonctions, Capture(excmd) PutAfterCapture(command) GetInputCommandThenCaptureAndPut()

InformationsquelleAutor Aman Jain | 2010-04-03

36
```
:redir >name_of_registers_file
:registers
:redir END
:r name_of_registers_file
:help redir
```
La dernière commande est très utile, car il ya beaucoup d'options pour la redirection: pour les variables, de registres, comment faire pour ajouter, outre la corne d'abondance.

Je continue de trouver ça bizarre et ennuyeux que l'on utilise à la FIN de cette façon, mais depuis tout ce qui peut suivre redir doit commencer par un non-mot-de caractère, au moins, il n'est pas ambigu.

PS autant que je sache (ce qui est assez présent dans ce cas) il n'y a pas moyen de le lire directement dans la mémoire tampon: vous devez le stocker dans un registre ou d'une variable de première. Consultez l'aide pour les différentes options de la façon de le faire.

PPS Si vous ne voulez pas pour ce faire à l'aide d'une variable peut-être de l'encapsuler dans une fonction et d'éviter de casser les registres ou des variables globales— vous aurez à convertir le multiligne chaîne qui est écrit sur la variable dans une liste. Par exemple
```
:call append( '.', split(variable_you_redirected_to, "\n") )
```
Sinon (si vous venez de le faire append('.',var)) vous vous retrouvez avec ^@'s (null) au lieu de retours à la ligne, puisque c'est ce que vimscript utilise pour représenter des retours à la ligne dans les variables de Chaîne de caractères.

modifier: comme @Bill Odom mentionne, à l'aide de :put =variable_you_redirected_to est beaucoup plus facile que la complexité de la append() expression. Merci, Bill!

PPP

J'ai écrit un extrait de à faire ce genre de choses plus commode. Il déclare une fonction Redir(command, target) et une commande de R.

La commande analyse de la dernière série des non-caractères d'espace comme une cible de redirection et le passe à la fonction, ce qui ne le passe-partout pour rediriger la sortie de la commande à la cible de redirection.

La commande est tout après R et avant le dernier espace.

Par exemple
```
" Store the vim buffer list in buffer_list.txt
:R ls >buffer_list.txt
" Store error messages emitted by a function being debugged
"   in the 'unnamed register'
:R call FunctionBeingDebugged() @">
```
Il y a quelques limitations: par exemple, vous ne serez pas en mesure d'écrire dans un nom de fichier contient un espace. L'avantage de ceci est que vous n'avez pas de citer votre commande. Je l'ai posté sur gist.github.com et je vais essayer de le garder à jour si j'arrive à la fin de l'améliorer. Ou vous pouvez fourche vous-même</noeuphemism>!

De toute façon l'extrait est disponible ici. Il peut être déposé dans une .fichiers vimrc ou dans un fichier dans ~/.vim/plugins.
- À l'aide de @intuition du Exec fonction de ici, une cartographie comme :inoremap <C-S-C> <C-R>=Exec("")<Left><Left> cartes Ctrl+Maj+C (pour Commande) pour faciliter l'insertion de la sortie d'une commande comme :ls au point en cours dans la mémoire tampon.
InformationsquelleAutor intuited

@intuition est bonne; le redir commande est ce que vous voulez. Un one-liner comme cela insère la sortie de :registers dans le tampon courant:

redir => m | silent registers | redir END | put=m

Ce n'est pas quelque chose que vous aurez envie de taper très souvent, cependant, et ce n'est pas exactement se prêtent à une carte de clés. Je me suis fait assez souvent, donc j'ai écrit une fonction et une poignée de commandes pour le rendre plus facile. En bonus, je peux maintenant envoyer la sortie d'une commande vers une nouvelle fenêtre ou un nouvel onglet, aussi facilement que de l'insérer dans le tampon courant. Voici le code (avec quelques exemples de commande à la fin):

" redir_messages.vim
"
" Inspired by the TabMessage function/command combo found
" at <http://www.jukie.net/~bart/conf/vimrc>.
"

function! RedirMessages(msgcmd, destcmd)
"
" Captures the output generated by executing a:msgcmd, then places this
" output in the current buffer.
"
" If the a:destcmd parameter is not empty, a:destcmd is executed
" before the output is put into the buffer. This can be used to open a
" new window, new tab, etc., before :put'ing the output into the
" destination buffer.
"
" Examples:
"
"   " Insert the output of :registers into the current buffer.
"   call RedirMessages('registers', '')
"
"   " Output :registers into the buffer of a new window.
"   call RedirMessages('registers', 'new')
"
"   " Output :registers into a new vertically-split window.
"   call RedirMessages('registers', 'vnew')
"
"   " Output :registers to a new tab.
"   call RedirMessages('registers', 'tabnew')
"
" Commands for common cases are defined immediately after the
" function; see below.
"
    " Redirect messages to a variable.
    "
    redir => message

    " Execute the specified Ex command, capturing any messages
    " that it generates into the message variable.
    "
    silent execute a:msgcmd

    " Turn off redirection.
    "
    redir END

    " If a destination-generating command was specified, execute it to
    " open the destination. (This is usually something like :tabnew or
    " :new, but can be any Ex command.)
    "
    " If no command is provided, output will be placed in the current
    " buffer.
    "
    if strlen(a:destcmd) " destcmd is not an empty string
        silent execute a:destcmd
    endif

    " Place the messages in the destination buffer.
    "
    silent put=message

endfunction

" Create commands to make RedirMessages() easier to use interactively.
" Here are some examples of their use:
"
"   :BufMessage registers
"   :WinMessage ls
"   :TabMessage echo "Key mappings for Control+A:" | map <C-A>
"
command! -nargs=+ -complete=command BufMessage call RedirMessages(<q-args>, ''       )
command! -nargs=+ -complete=command WinMessage call RedirMessages(<q-args>, 'new'    )
command! -nargs=+ -complete=command TabMessage call RedirMessages(<q-args>, 'tabnew' )

" end redir_messages.vim

Sympa, je ne savais pas que vous pouviez juste :put =var.
nice, j'ai utilisé cette sortie un fichier txt de mon keymappings pour référence, mais juste de commutation à: redir => m | silent map | redir END | put=m
Je n'ai absolument détourné ce dans mon propre vim config. (Avec une attribution, bien sûr, donc je n'ose pas penser je l'ai écrit.) Merci!
Très utile en effet, et tout ce que je cherchais. - Personnellement, je ne veux pas qu'il continue de poser la question si je veux perdre les modifications non enregistrées lorsque je ferme la fenêtre ou l'onglet nouveau, II ne vais pas être de garder les résultats, j'ai donc ajouté une commenté version alternative de "silent exécuter une:destcmd" pour le code ci-dessus en donnant que la variation de l'
Dans l'amour, et DONC une grande partie de ma vimminess est facilité maintenant. Le hic c'est dans mon vimfiles trop! (Avec apt crédits de cours, comme @JonCarter dit.)

InformationsquelleAutor Bill Odom

17
```
:redir @a
:registers
:redir END
"ap
```
:redir @a redirige tous les messages à partir d'ici sur un registre nommé a. Vous suivez avec votre commande dont la sortie que vous souhaitez capturer (:registers dans votre cas). :redir END extrémités de la redirection. "ap moyens, "a utilise le registre nommé a et p met le contenu du registre sélectionné dans le tampon courant.

Voir Capture ex sortie de la commande à Vim Conseils Wiki pour plus d'informations 🙂

InformationsquelleAutor Ashwin Nanjappa
4

Il n'est pas nécessaire d'utiliser une variable temporaire, tant que vous pouvez enregistrer le tampon courant et sont ok avec ajout de messages à la fin du fichier en cours.

À partir de la documentation de Vim:
```
:redi[r] >> {file}      Redirect messages to file {file}.  Append if {file}
                        already exists.  {not in Vi}
```
http://vimdoc.sourceforge.net/htmldoc/various.html#:redir

Donc, pour ajouter les messages de :registers vers le bas du fichier en cours, faites ceci:
```
:write | redir >> % | silent registers | redir END | edit
```
1. :write le fichier de sorte que les changements ne sera pas perdu
2. Commencer redirection de la sortie vers %, le nom du fichier en cours.
3. Silencieusement exécuter le :registers commande.
4. END de la rediriger vers le fichier.
5. :edit le fichier pour voir les nouveaux changements.
Vous pouvez également force de tronquer le fichier actuel et de le remplacer avec les messages de sortie:
```
:redir! > % | silent registers | redir END | edit!
```
Mais ce n'est probablement pas ce que vous voulez faire.

InformationsquelleAutor Nathaniel M. Beaver
4

En outre, :h :redir:

...Pour obtenir la sortie d'une commande de l' |execute()| fonction peut être utilisée.

par exemple
```
put = execute('scriptnames')
put = execute('filter /vimfiles/scriptnames')
```
InformationsquelleAutor Francis Niu
3

Malheureusement je n'ai pas de rep, donc je ne peux pas l'ajouter comme commentaire à "François Niu'.

La execute() fonction ressemble à la meilleure façon d'accomplir cette tâche, et il a été ajouté dans vim 8 .

Répertoriées dans la nouvelle/fonctionnalités étendues sur vim de github. version8.txt

InformationsquelleAutor Erik Olson

Vous devez vous connecter pour publier un commentaire.

PPP