Comment faire pour sauvegarder et restaurer plusieurs sessions différentes dans Vim?

Selon ma tâche dans Vim, j'ai plusieurs onglets ouverts.

Comment puis-je enregistrer des sessions pour les utiliser plus tard?

Je pense que ppl se sentir plus à l'aise de trouver la question ici (avec la police de grande taille, grande mise en forme...) que sur un vieux forum d'école ou d'un terminal de documentation, ou, à dieu ne plaise, un man page
Il n'y a pas beaucoup de mise en forme qu'il soit. Et vous pouvez modifier la police dans Vim 🙂
Personnellement, j'ai toujours été effrayé par l'homme pages b/c ils n'ont pas suffisamment de choses stupides vers le bas. Un peu comme tout le reste dans linux, il a une courbe d'apprentissage abrupte.
Eh bien, tout ce qui vous convient le mieux ...
Je pense qu'il vous manque le point entre le collectif de l'intelligence de nous, de google, et le débordement de la pile de la métaconnaissance de gestion - c'est tout simplement une meilleure façon d'obtenir vos réponses - ce que vous avez besoin, pas d'une longue liste de ésotériques options, aussi que cette page illustre une expérience du monde réel de pièges, et souvent vraiment chouette raccourcis pour rendre votre vie plus facile. Ceci s'applique également à presque n'importe quel manuel, que j'ai regardé (sauf peut-être le php manual en ligne). Viva stackoverflow!
et les gens peuvent utiliser pour référence future, puisque quelqu'un d'autre pourrait avoir besoin.
Je pense que ces questions sont réels dans le sens, que vim débutant ne sait pas beaucoup de choses sur le système d'aide et comment l'utiliser, mais si elles obtiennent plus chevronnés, ils sauront trouver leur chemin dans vim.
Je n'ai pas trouver cette question par la recherche de "sauvegarde d'une session", mais par googler comment sauver un tas d'onglets ouverts. J'ai utilisé les sessions avant, mais j'ai eu un blocage mental sur ce que vous recherchez, et vim de l'aide n'est pas vraiment utile si vous ne savez ce que vous voulez faire et ne pas exactement ce à quoi il est appelé.
C'est un vieux débat, mais mon de 0,02 $ - grande à fournir des réponses à des cas d'utilisation, soutenue par une man de référence où l'on peut apprendre les détails du pourquoi, et comment il allait s'adapter à quelque chose de légèrement différent.
Autosave / autoload version: stackoverflow.com/questions/5142099/...

InformationsquelleAutor Jogusa | 2009-10-29

479

Vous voulez quelque chose comme
```
:mksession ~/mysession.vim
```
Puis plus tard, vous pouvez source vim fichier et vous aurez votre ancien session:
```
:source ~/mysession.vim
```
ou ouvrir vim avec l'option-S:
```
$ vim -S ~/mysession.vim
```
- Ooo, et j'ai presque oublié, vous pouvez le charger en arrière en tapant: gvim -S ~/ ' mysession.vim
- Merci @Benj. Je suis nouveau dans vim. Comment puis-je "source" dans la ligne de commande?
- Salut Jogusa, C'est à peu près ce que le commentaire ci-dessus a été sur. vim -S
- Ooops! Désolé Benj, je voulais dire en mode commande. J'ai déjà trouvé: `:source ~/ ' mysession.vim.
- Courte est la suivante :alors ~/fichier. Si vous voulez la source du fichier en cours d'un simple :si % va faire le travail pour vous.
- Merci pour l'astuce @Daniel. Très pratique pour actualiser vimrc en cas de changement.
- Un lien vers la documentation de Vim (au cas où quelqu'un veut le lire): vimdoc.sourceforge.net/htmldoc/usr_21.html#21.4
- J'ai mappé les suivantes pour réinitialiser la session (dans le vimrc) à l'aide de la virgule+s: nmap <leader>s :source $HOME/mysession.vim<CR>
- hit :help session pour obtenir de l'aide, ou de regarder vimdoc.sourceforge.net/htmldoc/starting.html#session-file
- Si vous ne spécifiez pas une session de nom de fichier, il sera par défaut à l'écriture et à la lecture de Session.vim. Donc, si vous voulez avoir une seule session enregistré dans votre répertoire courant, vous pouvez utiliser :mksession ou :mks de vim pour enregistrer votre session actuelle, et juste vim -S à ouvrir vers le haut.
- si à l'aide de gvim, il est un moyen de maintenir la taille de la windowsplits? Lorsque j'utilise le suggère, ce n'entre pas en plein écran et mon split tailles sont tout foiré
- Quand je fais cela dans MacVim, il n'a pas l'honneur de la colorscheme j'ai mis dans mon .fichiers vimrc. Je contourner cela en tapant color <colorscheme> ensuite, mais je souhaite qu'il y ait plus de solution pratique.
- Oh man oh man oh man, vous avez fait ma journée
InformationsquelleAutor Benj
58

Vous pouvez définir ces options de session dans votre vimrc. Notamment des options est ennuyeux quand vous avez changé votre vimrc après que vous avez enregistré la session.
```
set ssop-=options    " do not store global and local values in a session
set ssop-=folds      " do not store folds
```
- Super! J'ai eu exactement ce problème hier. Merci beaucoup!
InformationsquelleAutor Jan Christoph
40

Noter que :mksession ne sera pas enregistrer les modifications sur les fichiers que vous avez fait. J'ai fait cette erreur de fermeture de vim après l'enregistrement de la session en supposant que je vais prendre à partir de là. Mais la prochaine fois, j'ai ouvert la session, les modifications que j'avais apportées aux fichiers ont disparu.
- Cela devrait venir avec une réponse liée à :mksession.
- ouais vous avez probablement envie de suivre avec un :wqa
- ou tout simplement :xa Un de moins de touches. Yay!!!
- votre commentaire m'a sauvé la vie !!!!
- Vous pouvez également configurer vim pour enregistrer automatiquement les fichiers (si vous aimez ce genre de chose) dans votre .vimrc: vimrc au FocusLost * silent! wa Ce sera automatiquement enregistrer tout le temps de la mémoire tampon perd le focus.
InformationsquelleAutor Deepanshu
32

Si vous utilisez NERDTree que votre explorateur de fichier/tableau de bord, je vous recommande xolox/vim-session plugin au lieu de :mksession de commande. Pour une raison quelconque, :mksession ne parvient pas à restaurer NERDTree tampons. Votre kilométrage peut varier, mais j'ai pensé partager mon expérience.
- Pour macvim, j'ai besoin de s'assurer: let g:nerdtree_tabs_open_on_gui_startup=0 et let g:nerdtree_tabs_open_on_new_tab=0 de faire xolox/vim-session œuvres.
InformationsquelleAutor gdso
14

Si vous souhaitez automatiser le processus, sans l'aide de tous les plugins, vous pouvez utiliser S'en aller et de revenir de Vim Conseils Wiki.

Chaque fois que vous quittez Vim, il va enregistrer la session en cours en vertu de ~/.vim/sessions et la charge de nouveau une fois que Vim est ouvert. Il est également basé sur l'actuel chemin, de sorte que si vous ouvrez Vim à partir de répertoires différents, vous aurez différentes sessions, ce qui est très utile lorsque vous travaillez sur des projets différents.

Il suffit d'éditer votre ~/.vimrc fichier et ajoutez la ligne suivante:
```
function! MakeSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  if (filewritable(b:sessiondir) != 2)
    exe 'silent !mkdir -p ' b:sessiondir
    redraw!
  endif
  let b:filename = b:sessiondir . '/session.vim'
  exe "mksession! " . b:filename
endfunction

function! LoadSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  let b:sessionfile = b:sessiondir . "/session.vim"
  if (filereadable(b:sessionfile))
    exe 'source ' b:sessionfile
  else
    echo "No session loaded."
  endif
endfunction

" Adding automatons for when entering or leaving Vim
au VimEnter * nested :call LoadSession()
au VimLeave * :call MakeSession()
```
Même pour un débutant ce script est un peu facile à comprendre et à personnaliser.

Veuillez noter ce script ne fonctionnera correctement que pour les systèmes Unix (mac os/Linux), il doit être adapté pour fonctionner sur Windows.

Mise à JOUR: Ajoutant 0xc0desuggestion, vous pouvez remplacer le VimEnter ligne ces si vous souhaitez que Vim chargement d'une session seulement si aucun argument n'est fourni:
```
if(argc() == 0)
  au VimEnter * nested :call LoadSession()
endif
```
- Vous pouvez ouvrir la session uniquement si aucun argument n'est fourni pour vim par exemple. if argc() == 0 au VimEnter * nested :call LoadSession() end
- Merci @0xc0de , très bonne suggestion (j'ai même commencé à l'utiliser moi-même). J'ai mis à jour la réponse.
- comment puis-je modifier cela pour que si j'ouvre vim avec des arguments aussi ne pas enregistrer cette session
- très bon, mais ` exe 'source' b:sessionfile` a besoin d'un point? et le problème, c'est que le chargement automatique de session est dépend du répertoire d'accueil (obtenir par pwd) comment puis-je définir le dernier répertoire de travail avant de quitter vim? afin de charger la dernière séance de travail plutôt qu'à la session en vertu de l' ~/?
- Si vous voulez être en mesure d'avoir des sessions, mais toujours ouvrir les fichiers dans le répertoire sans l'écraser découvrez ma version modifiée de cette question dans la réponse distincte: stackoverflow.com/questions/1642611/...
- Pour éviter d'avoir à supprimer manuellement les sessions que je ne veux pas être sauvé ou qui doivent être effacée pour une raison que j'ai écrit cet alias: alias clearvim="/home/user/.vim/sessions`pwd`". Il efface la session du répertoire courant
InformationsquelleAutor mathielo
5

Il y a un plugin très utile pour cette tâche vim-startify qui s'occupe de beaucoup d'autres choses comme des fichiers récemment ouverts, etc, il a une interface très facile aussi.

Je l'utilise depuis quelques jours et jusqu'à maintenant son travail parfaitement. Espérons qu'il vous aide.

InformationsquelleAutor vivek
3

Il y a ce merveilleux plugin appel vim-session. C'est très puissant. Pour l'installer:
```
cd ~/.vim/bundle
git clone https://github.com/xolox/vim-session.git
```
J'ai mappé sa fonctionnalité dans mon .vimrc fichier comme ceci:
```
nnoremap <leader>so :OpenSession 
nnoremap <leader>ss :SaveSession 
nnoremap <leader>sd :DeleteSession<CR>
nnoremap <leader>sc :CloseSession<CR>
```
Maintenant en mode normal type <leader>ss et vous verrez une commande de ce
```
:SaveSession 
```
Désormais ajouter le nom de votre session
```
 :SaveSession namesession
```
et c'est tout.

Lorsque vous fermez le Vim et le rouvrir, il suffit de ne
```
 :OpenSession
```
et vous verrez que votre session est ouverte.

Il y a beaucoup d'autres de configuration pour ajouter dans votre .vimrc fichier, voir la documentation pour des exemples:
```
let g:session_directory = "~/.vim/tmp/session"  //the directory must be created before the sessions will be saved there
let g:session_autoload = "no"                   //automatic reload sessions
let g:session_autosave = "no"                   //autosave
let g:session_command_aliases = 1
```
Il y a une bonne tutoriel sur YouTube.

InformationsquelleAutor WALID BELRHALMIA
3

Puisque c'est le premier hit sur Google pour moi (et probablement d'autres) sur la façon de travailler avec les sessions dans Vim, j'ai décidé d'ajouter un peu d' @mathielo de réponse sur la façon de rendre cela automatique.

J'aime son code, mais l'ajout de la "seulement si, sans args" solution semblait être un peu défaut. C'est ma version modifiée:
```
function! MakeSession(overwrite)
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  if (filewritable(b:sessiondir) != 2)
    exe 'silent !mkdir -p ' b:sessiondir
    redraw!
  endif
  let b:filename = b:sessiondir . '/session.vim'
  if a:overwrite == 0 && !empty(glob(b:filename))
    return
  endif
  exe "mksession! " . b:filename
endfunction

function! LoadSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  let b:sessionfile = b:sessiondir . "/session.vim"
  if (filereadable(b:sessionfile))
    exe 'source ' b:sessionfile
  else
    echo "No session loaded."
  endif
endfunction

" Adding automatons for when entering or leaving Vim
if(argc() == 0)
  au VimEnter * nested :call LoadSession()
  au VimLeave * :call MakeSession(1)
else
  au VimLeave * :call MakeSession(0)
endif
```
Le changement notable ici est l'option remplacer. Si vous ouvrez Vim sans options, il sera ouvert à toute session existante et écraser les modifications apportées lorsque vous quittez. Si Vim est ouvert avec les options, il ne fera que créer une nouvelle session s'il n'en existe pas, cela signifie que vous pouvez ouvrir des fichiers dans un répertoire qui a une session sans l'écraser. Ensuite, vous pouvez ouvrir Vim sans options pour exécuter la session à la place. Si il n'existe pas de session puis il en crée un nouveau.
- Je viens d'essayer votre ci-dessus posté solution dans Neovim 0.2.2 et placé votre extrait de code dans $HOME/.vim/plugin/sessions.vim mais ce n'est pas de sauver les fichiers de session. \_(ツ)_/
- Ce fil de discussion, et en particulier le commentaire connexe, qui pourraient vous aider: superuser.com/questions/404686/... je l'ai dans mon .vimrc et qui fonctionne très bien.
- ai eu de travail, apparemment je dois quitter (n)vim pour que la session soit écrit insérer une mauvaise blague Merci encore pour le partage
InformationsquelleAutor PMunch
1

Merci @mathielo
L'exemple suivant de @mathielo, j'ai ajouté la ligne ci-dessous pour .vimrc pour enregistrer la session en cours (le cas échéant):
```
au VimLeave * if this_session != "" | exe "mksession! ".this_session
```
Si vous voulez mettre plus de lignes, vous devez utiliser endif:
```
au VimLeave * if v:this_session != ""
au VimLeave *   exe "mksession! ".this_session
au VimLeave * endif
```
Vous avez seulement besoin d'enregistrer une nouvelle session dans vim avec
```
:mks [Session filename]
```
et après commencer avec
```
$ vim -S [Session filename]
```
vim sera le début de la séance et vous n'avez pas besoin d'enregistrer la session chaque fois que vous fermez vim.

Si vous n'avez pas une session active .vimrc de ne pas faire n'importe quoi. Comme avant.

C'est ce que je cherchais! Merci encore @mathielo!
- C'est ce que je cherchais trop. Super ! Je ne me souviens pas combien de fois j'ai perdu ma session faire :q au lieu de :bd... Merci !
InformationsquelleAutor oml

Personnellement, je ne enveloppement au Tim Pape s' Obsession plugin pour permettre la définition d'un sessiondir et éviter de taper le chemin d'accès:

let g:sessiondir = $HOME . ".vim/sessions"

command! -nargs=1 MkSession call MkSession(<f-args>)
function! MkSession(sessionfile)
  if !isdirectory(g:sessiondir)
    call mkdir(g:sessiondir, "p")
  endif
  exe 'Obsession' g:sessiondir . '/' . a:sessionfile
endfunction

command! -nargs=1 LoadSession call LoadSession(<f-args>)
function! LoadSession(sessionfile)

  let a:sessionpath = g:sessiondir . a:sessionfile
  if (filereadable(a:sessionpath))
    exe 'source ' a:sessionpath
  else
    echo "No session loaded."
  endif
endfunction

j'ai eu des problèmes spécifiques avec la compagnie Aérienne plugin et des sessions. De commutation à l'aide de l'Obsession résolu les problèmes, c'était une découverte étonnante après des semaines de lutte. Voir github.com/vim-airline/vim-airline/issues/...

InformationsquelleAutor archf

0

Vous pouvez stocker la session où vous le souhaitez.

Ex:
```
:mksession! D:/session.ses
```
Ce magasins de la séance D entraînement.

Peut être ouvert en tapant
```
:so D:/session.ses
```
dans l'un des fichiers vim.

InformationsquelleAutor Sagar Jain

Ci-dessous est la seule conf. cela a vraiment fonctionné pour moi. Je l'ai pris de ici, où vous pouvez également prendre un plus complet/complexe version.

set viewoptions+=cursor,folds,slash,unix
set viewoptions-=options

augroup vimrc
    autocmd BufWritePost *
    \   if expand('%') != '' && &buftype !~ 'nofile'
    \|      mkview
    \|  endif
    autocmd BufRead *
    \   if expand('%') != '' && &buftype !~ 'nofile'
    \|      silent loadview
    \|  endif
augroup END

InformationsquelleAutor JohnTortugo

0

Si vous prévoyez d'avoir seulement 1 séance pour le projet vient de faire
```
:mks
```
qui permettra de créer une Session.vim fichier dans le répertoire courant, puis d'ouvrir la session (à partir du même répertoire):
```
vim -S
```
Si vous modifiez la session et souhaitez l'enregistrer:
```
:mks!
```
Cela permet d'économiser la session, pas les fichiers eux-mêmes!

Si vous prévoyez d'avoir plusieurs sessions, je préfère les enregistrer dans des fichiers cachés dans le répertoire du projet:
```
:mks .session-name.vim
```
Pour l'ouvrir (dans le même répertoire):
```
vim -S .session-name.vim
```
Sauvegarder la session:
```
:mks! .session-name.vim
```
Étant donné que les séances sont enregistrées dans des fichiers cachés, à les voir, n'oubliez pas -a
```
ls -a
```
InformationsquelleAutor cute_ptr
0

Pour la gestion de plusieurs sessions (par répertoire/pensions de base), j'ai récemment passé de la vim-session plugin pour vim-espace de travail. Sa gestion de session est relativement simple et fonctionne plutôt bien.

InformationsquelleAutor jaybay

Vous devez vous connecter pour publier un commentaire.