Comment faire pour supprimer les espaces de noms XML à l'aide de XSLT

Votre XSLT supprime les attributs aussi, parce que vous ne disposez pas d'un modèle qui permettrait de les copier. <xsl:template match="*"> ne correspond qu'à des éléments, des attributs (ou du texte, des commentaires ou des instructions de traitement).

Ci-dessous est une feuille de style qui supprime toutes les définitions d'espaces de noms à partir du document traité, mais des copies de tous les autres nœuds et des valeurs: des éléments, des attributs, des commentaires de texte et les instructions de traitement. S'il vous plaît prêter attention à 2 choses

1. De copier les attributs en tant que tel n'est pas suffisant pour supprimer tous les espaces de noms. Également un attribut peut appartenir à un espace de noms, même lorsque le contenant élément n'appartient pas à un espace de noms. Par conséquent également les attributs doivent être créés, tels que des éléments. Création d'attributs est fait avec <xsl:attribute> élément.
2. Un document XML valide, ne peut pas contenir un élément qui a deux ou plusieurs attributs avec le même nom augmenté, mais les éléments peuvent contenir plusieurs attributs avec le même nom local si les attributs sont des espaces de noms différents. Cela signifie que la suppression d'un préfixe d'espace de noms à partir d'un nom d'attribut sera la cause de dataloss si il y a un élément qui a à lea deux attributs avec le même nom local. L'autre de ces attributs seront supprimés (ou écrasé).

...et le code:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output indent="yes" method="xml" encoding="utf-8" omit-xml-declaration="yes"/>

    <!-- Stylesheet to remove all namespaces from a document -->
    <!-- NOTE: this will lead to attribute name clash, if an element contains
        two attributes with same local name but different namespace prefix -->
    <!-- Nodes that cannot have a namespace are copied as such -->

    <!-- template to copy elements -->
    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@* | node()"/>
        </xsl:element>
    </xsl:template>

    <!-- template to copy attributes -->
    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

    <!-- template to copy the rest of the nodes -->
    <xsl:template match="comment() | text() | processing-instruction()">
        <xsl:copy/>
    </xsl:template>

</xsl:stylesheet>

Vous pouvez également utiliser <xsl:template match="node()"> à la place de ce dernier modèle, mais alors vous devriez utiliser priority attribut pour empêcher les éléments correspondant à ce modèle.

OriginalL'auteur jasso

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" encoding="UTF-8"/>
<xsl:template match="/">
    <xsl:copy>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>
<xsl:template match="@*">
    <xsl:attribute name="{local-name()}">
        <xsl:value-of select="current()"/>
    </xsl:attribute>
</xsl:template>
<xsl:template match="*">
    <xsl:element name="{local-name()}">
        <xsl:apply-templates select="@* | * | text()"/>
    </xsl:element>
</xsl:template>
<xsl:template match="text()">
    <xsl:copy>
        <xsl:value-of select="current()"/>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

OriginalL'auteur Konstantin