Comment faire pour utiliser une Expression Régulière dans sql server?

Avec le CLR et .Projet NET publié de SQL Server, il est EXTRÊMEMENT efficace. Après avoir commencé à utiliser un CLR Projet VB.Net avec notre 2005 de SQL Server au cours des 2 dernières années, j'ai constaté que chaque occurrence d'une Fonction Scalaire dans TSQL pour lequel j'ai remplacé par de la .NET version, il a considérablement amélioré les performances. Je l'ai utilisé pour l'avancée de la date de la manipulation, la mise en forme et l'analyse, la mise en forme de Chaîne et de l'analyse, Hachage MD5 génération, les longueurs de Vecteur, Chaîne de REJOINDRE Aggragate fonction Split fonction à valeur de Table, et même le chargement en vrac à partir de tables de données sérialisées par l'intermédiaire d'un dossier de partage (ce qui est étonnamment rapide).

Pour les RegEx, car il n'est pas déjà présent, je ne peux que supposer que c'est aussi efficace qu'un EXE compilé serait faire la même chose REGEX, c'est à dire extrêmement rapide.

Je vais partager un fichier de code à partir de mon VB.Net CLR projet qui permet à certains RegEx fonctionnalité.
Ce code serait partie d'une .NET CLR DLL qui est publié sur votre serveur.

Fonction Résumé

Regex_IsMatch(Données,Parttern,Options), tinyint (0/1) de

Par exemple. SELECT dbo.Regex_IsMatch('Darren','[trwq]fr$',NULL) -- renvoie 1 /vrai

Regex_Group(données,motif,groupname,options), nvarchar(max) (groupe de capture de la valeur retournée)

Par exemple. SELECT dbo.Regex_Group('Câble de 180+e10 à 120+e3',' (?[0-9]+)+e[0-9]+','n',NULL) -- renvoie '180'

Regex_Replace(de données,de motif,de remplacement,options), nvarchar(max) (renvoie la chaîne modifiée)

Par exemple. SELECT dbo.Regex_Replace('Câble de 180+e10 à 120+e3',' (?[0-9]+)+e(?[0-9]+)',' ${e}:${n]',NULL) -- renvoie 'Câble 10:180 à 3:120'

Partial Public Class UserDefinedFunctions
''' <summary>
''' Returns 1 (true) or 0 (false) if a pattern passed is matched in the data passed.
''' Returns NULL if Data is NULL.
''' options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"
''' </summary>
''' <param name="data"></param>
''' <param name="pattern"></param>
''' <param name="options">options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"</param>
''' <returns></returns>
''' <remarks></remarks>
<Microsoft.SqlServer.Server.SqlFunction()> _
Public Shared Function Regex_IsMatch(data As SqlChars, pattern As SqlChars, options As SqlString) As SqlByte
If pattern.IsNull Then
Throw New Exception("Pattern Parameter in ""RegEx_IsMatch"" cannot be NULL")
End If
If data.IsNull Then
Return SqlByte.Null
Else
Return CByte(If(Regex.IsMatch(data.Value, pattern.Value, Regex_Options(options)), 1, 0))
End If
End Function
''' <summary>
''' Returns the Value of a RegularExpression Pattern Group by Name or Number.
''' Group needs to be captured explicitly. Example Pattern "[a-z](?&lt;m&gt;[0-9][0-9][0-9][0-9])" to capture the numeric portion of an engeneering number by the group called "m".
''' Returns NULL if The Capture was not successful.
''' Returns NULL if Data is NULL.
''' options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"
''' </summary>
''' <param name="data"></param>
''' <param name="pattern"></param>
''' <param name="groupName">Name used in the explicit capture group</param>
''' <param name="options">options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"</param>
<Microsoft.SqlServer.Server.SqlFunction()> _
Public Shared Function Regex_Group(data As SqlChars, pattern As SqlChars, groupName As SqlString, options As SqlString) As SqlChars
If pattern.IsNull Then
Throw New Exception("Pattern Parameter in ""RegEx_IsMatch"" cannot be NULL")
End If
If groupName.IsNull Then
Throw New Exception("GroupName Parameter in ""RegEx_IsMatch"" cannot be NULL")
End If
If data.IsNull Then
Return SqlChars.Null
Else
Dim m As Match = Regex.Match(data.Value, pattern.Value, Regex_Options(options))
If m.Success Then
Dim g As Group
If IsNumeric(groupName.Value) Then
g = m.Groups(CInt(groupName.Value))
Else
g = m.Groups(groupName.Value)
End If
If g.Success Then
Return New SqlChars(g.Value)
Else ' group did not return or was not found.
Return SqlChars.Null
End If
Else 'match failed.
Return SqlChars.Null
End If
End If
End Function
''' <summary>
''' Does the Equivalent toi Regex.Replace in .NET.
''' Replacement String Replacement Markers are done in this format "${test}" = Replaces the capturing group (?&lt;test&gt;...)
''' If the replacement pattern is $1 or $2 then it replaces the first or second captured group by position.
''' Returns NULL if Data is NULL.
''' options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"
''' </summary>
''' <param name="data"></param>
''' <param name="pattern"></param>
''' <param name="replacement">Replacement String Replacement Markers are done in this format "${test}" = Replaces the capturing group (?&lt;test&gt;...). If the replacement pattern is $1 or $2 then it replaces the first or second captured group by position.</param>
''' <param name="options">options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"</param>
''' <returns></returns>
''' <remarks></remarks>
<SqlFunction()> _
Public Shared Function Regex_Replace(data As SqlChars, pattern As SqlChars, replacement As SqlChars, options As SqlString) As SqlChars
If pattern.IsNull Then
Throw New Exception("Pattern Parameter in ""Regex_Replace"" cannot be NULL")
End If
If replacement.IsNull Then
Throw New Exception("Replacement Parameter in ""Regex_Replace"" cannot be NULL")
End If
If data.IsNull Then
Return SqlChars.Null
Else
Return New SqlChars(Regex.Replace(data.Value, pattern.Value, replacement.Value, Regex_Options(options)))
End If
End Function
''' <summary>
''' Buffered list of options by name for speed.
''' </summary>
Private Shared m_Regex_Buffered_Options As New Generic.Dictionary(Of String, RegexOptions)(StrComp)
''' <summary>
''' Default regex options used when options value is NULL or an Empty String
''' </summary>
Private Shared ReadOnly m_Regex_DefaultOptions As RegexOptions = RegexOptions.IgnoreCase Or RegexOptions.ExplicitCapture Or RegexOptions.Multiline
''' <summary>
''' Get the regular expressions options to use by a passed string of data.
''' Formatted like command line arguments.
''' </summary>
''' <param name="options">options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline "</param>
Private Shared Function Regex_Options(options As SqlString) As RegexOptions
Return Regex_Options(If(options.IsNull, "", options.Value))
End Function
''' <summary>
''' Get the regular expressions options to use by a passed string of data.
''' Formatted like command line arguments.
''' </summary>
''' <param name="options">options example, full or partial names can be used after slashes or hypens with or without spaces, some are exclusive of each other "/ic /ex -s" = "\ignorecase -explicitcapture/singleline"</param>
Private Shared Function Regex_Options(options As String) As RegexOptions
'empty options string is considered default options.
If options Is Nothing OrElse options = "" Then
Return m_Regex_DefaultOptions
Else
Dim out As RegexOptions
If m_Regex_Buffered_Options.TryGetValue(options, out) Then
Return out
Else
'must build options and store them
If options Like "*[/\-]n*" Then
out = RegexOptions.None
End If
If options Like "*[/\-]s*" Then
out = out Or RegexOptions.Singleline
End If
If options Like "*[/\-]m*" Then
out = out Or RegexOptions.Multiline
End If
If options Like "*[/\-]co*" Then
out = out Or RegexOptions.Compiled
End If
If options Like "*[/\-]c[ui]*" Then
out = out Or RegexOptions.CultureInvariant
End If
If options Like "*[/\-]ecma*" Then
out = out Or RegexOptions.ECMAScript
End If
If options Like "*[/\-]e[xc]*" Then
out = out Or RegexOptions.ExplicitCapture
End If
If options Like "*[/\-]i[c]*" OrElse options Like "*[/\-]ignorec*" Then
out = out Or RegexOptions.IgnoreCase
End If
If options Like "*[/\-]i[pw]*" OrElse options Like "*[/\-]ignore[pw]*" Then
out = out Or RegexOptions.IgnorePatternWhitespace
End If
If options Like "*[/\-]r[tl]*" Then
out = out Or RegexOptions.RightToLeft
End If
'store the options for next call (for speed)
m_Regex_Buffered_Options(options) = out
Return out
End If
End If
End Function
End Class