comment filtrer les nœuds xml à l'aide de xslt..?

supposons que j'ai ce xml:

<college>
    <student>
        <name>amit</name>
        <file>/abc/kk/final.c</file>
        <rollno>22</rollno>
    </student>
    <student>
        <name>sumit</name>
        <file>/abc/kk/up.h</file>
        <rollno>23</rollno>
    </student>
    <student>
        <name>nikhil</name>
        <file>/xyz/up.cpp</file>
        <rollno>24</rollno>
    </student>
    <student>
        <name>bharat</name>
        <file>/abc/kk/down.h</file>
        <rollno>25</rollno>
    </student>
    <student>
        <name>ajay</name>
        <file>/simple/st.h</file>
        <rollno>27</rollno>
    </student>
</college>

je suis à l'aide de chaque ".xsl" pour afficher toutes les entrées de nœuds, mais je ne veux afficher les entrées de ces nœuds uniquement dans qui nom de fichier commence par "/abc/kk" comme je suis nouveau sur xslt..

merci de me donner la solution.

je suis en utilisant :

<xsl:for-each select="college/student">
<tr>
<td><xsl:value-of select="name"/></td>
<td><xsl:value-of select="file"/></td>
<td><xsl:value-of select="rollno"/></td>
</tr>
Veuillez fournir joliment formaté en XML afin de nous permettre de mieux comprendre votre question
Bonne question, +1. Voir ma réponse pour une complète, court et facile solution qui utilise les caractéristiques fondamentales de XSLT, tels que les modèles et les pousser style de traitement. Une explication détaillée est fournie.

OriginalL'auteur kuldeep | 2011-04-07

  1. 6

    Cette transformation:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>


 <xsl:template match="student[starts-with(file,'/abc/kk')]">
  <tr><xsl:apply-templates/></tr>
 </xsl:template>

 <xsl:template match="student/*">
     <td><xsl:apply-templates/></td>
 </xsl:template>

 <xsl:template match="student"/>    
</xsl:stylesheet>

    lorsqu'il est appliqué au document XML fourni:

    <college>
    <student>
        <name>amit</name>
        <file>/abc/kk/final.c</file>
        <rollno>22</rollno>
    </student>
    <student>
        <name>sumit</name>
        <file>/abc/kk/up.h</file>
        <rollno>23</rollno>
    </student>
    <student>
        <name>nikhil</name>
        <file>/xyz/up.cpp</file>
        <rollno>24</rollno>
    </student>
    <student>
        <name>bharat</name>
        <file>/abc/kk/down.h</file>
        <rollno>25</rollno>
    </student>
    <student>
        <name>ajay</name>
        <file>/simple/st.h</file>
        <rollno>27</rollno>
    </student>
</college>

    produit le voulait, résultat correct:

    <tr>
   <td>amit</td>
   <td>/abc/kk/final.c</td>
   <td>22</td>
</tr>
<tr>
   <td>sumit</td>
   <td>/abc/kk/up.h</td>
   <td>23</td>
</tr>
<tr>
   <td>bharat</td>
   <td>/abc/kk/down.h</td>
   <td>25</td>
</tr>

    Explication:

    1. Un modèle correspondant à un student avoir un file enfant dont la valeur de chaîne commence par "/abc/kk'. Cela met juste le contenu généré dans une enveloppe tr élément.

    2. Un modèle correspondant à un student qui n'a pas de corps et efficacement le supprime (ne pas copier cet élément à la sortie). Ce modèle a une priorité plus faible que la première, parce que le premier est plus spécifique. Par conséquent, seuls les student éléments qui ne sont pas compensée par le premier modèle sont traitées avec le deuxième modèle.

    3. Un modèle correspondant à un élément enfant de toute student élément. Cette juste encapsule le contenu dans un td élément.

    +1 Correct de style XSLT.

    OriginalL'auteur Dimitre Novatchev

  2. 3

    Comme ceci:

    <xsl:for-each select="college/student[starts-with(file, '/abc/kk')]">
<!-- ... -->

    Les crochets [ ] délimiter un "filtre", et à l'intérieur de ce filtre, vous pouvez avoir des fonctions comme starts-with()

    +1, bien fait..
    merci de vérifier que cette réponse est correcte. Il vous aidera à obtenir plus de gens prêts à répondre à votre autre question sur DONC.
    +1 Correcte de l'expression XPath.

    OriginalL'auteur Lukas Eder

  3. 0

    Vous pouvez également utiliser [..] dans match:

    <xsl:template match="college/student[starts-with(file, '/abc/kk')]">
    <tr>
        <td><xsl:value-of select="name"/></td>
        <td><xsl:value-of select="file"/></td>
        <td><xsl:value-of select="rollno"/></td>
    </tr>
</xsl:template>

    OriginalL'auteur khachik