Comment gérer une pression sur un bouton arrière dans une application Android (Delphi)?

Comment puis-je rendre mon application Android réagir à l'arrière-bouton?

Est-il quelque chose de plus haut niveau VCL est TApplicationEvents le gérer, ou ai-je besoin de plonger dans les bas-niveau Android, des trucs ici?

Aujourd'hui, la plupart des applications de démonstration ont un écran bouton de retour pour revenir à l'écran précédent. En appuyant sur la psysical bouton de semble toujours pour quitter l'application, et dans certaines situations, il provoque une violation d'accès.

source d'informationauteur Wouter van Nifterick

  1. 28

    Dans la forme du OnKey... événements, la Key paramètre est vkHardwareBack sur Android. Par exemple:

    uses
  FMX.Platform, FMX.VirtualKeyboard;

procedure TForm1.FormKeyUp(Sender: TObject; var Key: Word; var KeyChar: Char; Shift: TShiftState);
var
  FService : IFMXVirtualKeyboardService;
begin
  if Key = vkHardwareBack then
  begin
    TPlatformServices.Current.SupportsPlatformService(IFMXVirtualKeyboardService, IInterface(FService));
    if (FService <> nil) and (vksVisible in FService.VirtualKeyBoardState) then
    begin
      // Back button pressed, keyboard visible, so do nothing...
    end else
    begin
      // Back button pressed, keyboard not visible or not supported on this platform, lets exit the app...
      if MessageDlg('Exit Application?', TMsgDlgType.mtConfirmation, [TMsgDlgBtn.mbOK, TMsgDlgBtn.mbCancel], -1) = mrOK then
      begin
        // Exit application here...
      end else
      begin
        // They changed their mind, so ignore the Back button press...
        Key := 0;
      end;
    end;
  end
  ...
end;
  2. 5

    Voici un code mis à jour pour Remy réponse (fonctionne avec Seattle):

    procedure TForm1.FormKeyUp(Sender: TObject; var Key: Word; var KeyChar: Char; Shift: TShiftState);
var
  FService : IFMXVirtualKeyboardService;
begin
  if Key = vkHardwareBack then
  begin
    TPlatformServices.Current.SupportsPlatformService(IFMXVirtualKeyboardService, IInterface(FService));
    if (FService <> nil) and (TVirtualKeyboardState.Visible in FService.VirtualKeyBoardState) then
    begin
      // Back button pressed, keyboard visible, so do nothing...
    end else
    begin
      Key := 0;
      // Back button pressed, keyboard not visible or not supported on this platform, lets exit the app...
      MessageDlg('Exit Application?', TMsgDlgType.mtConfirmation, [TMsgDlgBtn.mbOK, TMsgDlgBtn.mbCancel], -1, OnCloseDialog);
    end;
  end;
end;

procedure TForm1.OnCloseDialog(Sender: TObject; const AResult: TModalResult);
begin
  if AResult = mrOK then
    Close;
end;
  3. 3

    Pour la future référence pour toute personne qui cherche à donner un sens à cette..

    if Key = vkHardwareBack then
    begin
      // your code here
      key := 0;
end;

    La clé := 0; est le secret pour arrêter l'application à partir de la clôture..

    Cela va dans les formes événement OnKeyUp

  4. 1

    Essayez ceci:

    uses FMX.Platform,FMX.VirtualKeyboard,FMX.Helpers.Android;

procedure THeaderFooterForm.FormKeyUp(Sender: TObject; var Key: Word;
  var KeyChar: Char; Shift: TShiftState);

var FService : IFMXVirtualKeyboardService; 
begin
  if Key = vkHardwareBack then
    begin
      TPlatformServices.Current.SupportsPlatformService(IFMXVirtualKeyboardService, IInterface(FService));
      if (FService <> nil) and (vksVisible in FService.VirtualKeyBoardState) then
        begin
          // Back button pressed, keyboard visible, so do nothing...
        end
      else
        begin
          if MessageDlg('Exit Application?', TMsgDlgType.mtConfirmation, [TMsgDlgBtn.mbOK, TMsgDlgBtn.mbCancel], -1) = mrOK then
            begin
            // Exit application here...
              SharedActivity.Finish;
            end;
        end;
     end
  else
    // Menu button pressed
    if Key = sgiUpRightLong then
      begin
        showmessage('Menu button pressed');
      end;
end;
  5. 0

    désolé pour mon précédent message. c'était à propos de l'arrêt de l'application.

    revenir à l'écran précédent dépend de la conception de votre application.

    si vous avez utilisé TTabControl pour afficher les pages, vous pouvez passer à la partie précédente TTabItem.
    si vous avez utilisé TForms pour l'affichage des pages, vous devez utiliser Close() procédure pour la fermeture de la forme actuelle et de revenir à l'écran précédent.