Comment imprimer corde de couleur en langage d'assemblage?

Jan             db  "         January$          "     
string          db  "Sun Mon Tue Wed Thu Fri Sat$"
string1         db  "                 1   2   3$"
string2         db  " 4   5   6   7   8   9  10$"
string3         db  "11  12  13  14  15  16  17$"
string4         db  "18  19  20  21  22  23  24$"
string5         db  "25  26  27  28  29  30  31$"
  • Quelle langue écrivez-vous? Il ya beaucoup de différents assemblée langues.
  • pour masm ou tasm
  • Votre programme en assembleur ne fait rien, il ne définit que certaines chaînes. Qu'avez-vous essayé?
  • double possible de Don sais pas comment faire pour imprimer un Calendrier à la fois
  • La réponse à votre question précédente comprend la couleur, si je comprends bien.
  • L'étiquette indique "windows" mais le dollar signes me font penser que vous pourriez DOS. Les signes dollar ne fonctionne pas, mais cette interruption BIOS pourrait faire ce que tu veux: ctyme.com/intr/rb-0210.htm
  • oui, ils sont en quelque chaîne que je veux imprimer en couleurs, mais je n'ai pas les codes pour les transformer en différentes couleurs comme la couleur. Quelles seront les codes pour que, c'est là que je ne suis pas sûr.
  • Ok, H. N., j'ai édité ma réponse originale à cette question pour le mode graphique.

InformationsquelleAutor 0ptimus | 2015-04-05
  1. 2

    Il y a plusieurs façons d'atteindre votre objectif EN MODE TEXTE :

    1. Affichage char par char : de cette façon, vous pouvez choisir une couleur pour chaque personnage.
    2. Écran d'accès à la mémoire : au segment 0B800:0.
    3. Afficher la totalité de la chaîne de la même couleur.

    Code suivant fait le travail avec la troisième option (le plus facile). Il a été réalisé avec EMU8086:

    .stack 100h
.data

Jan   db  "         January           ",13,10 
      db  "Sun Mon Tue Wed Thu Fri Sat",13,10 
      db  "                 1   2   3 ",13,10 
      db  " 4   5   6   7   8   9  10 ",13,10 
      db  "11  12  13  14  15  16  17 ",13,10 
      db  "18  19  20  21  22  23  24 ",13,10 
      db  "25  26  27  28  29  30  31 "       
color db 181

.code          
;INITIALIZE DATA SEGMENT.
  mov  ax,@data
  mov  ds,ax 

;DISPLAY STRING WITH COLOR.
  mov  es,ax ;ES SEGMENT MUST POINT TO DATA SEGMENT.
  mov  ah,13h ;SERVICE TO DISPLAY STRING WITH COLOR.
  mov  bp,offset Jan ;STRING TO DISPLAY.
  mov  bh,0 ;PAGE (ALWAYS ZERO).
  mov  bl,color
  mov  cx,201 ;STRING LENGTH.
  mov  dl,0 ;X (SCREEN COORDINATE). 
  mov  dh,5 ;Y (SCREEN COORDINATE). 
  int  10h ;BIOS SCREEN SERVICES.  

;FINISH THE PROGRAM PROPERLY.
  mov  ax,4c00h
  int  21h

    Avis, je l'ai enlevé les signes $ (parce 13h service nécessite la longueur de la chaîne, et non pas $). Pour une couleur différente, il suffit de changer la valeur (181) pour la "couleur" de la variable dans le segment de données.

    Pour afficher différentes couleurs pour les différentes chaînes, copier-coller le bloc d'affichage pour chaque chaîne.

    Laissez-nous savoir si cela a fonctionné pour vous.

    La formule à choisir la couleur qui va comme ceci:

    texte-contexte * 16 + texte-couleur

    Prochaine, ce sont les couleurs :

    Black         =  0
Blue          =  1
Green         =  2
Cyan          =  3
Red           =  4
Magenta       =  5
Brown         =  6
LightGray     =  7
DarkGray      =  8
LightBlue     =  9
LightGreen    = 10
LightCyan     = 11
LightRed      = 12
LightMagenta  = 13
Yellow        = 14
White         = 15

    Avec la formule donnée, si vous voulez l'arrière-plan rouge avec un texte jaune vous avez besoin de la couleur 78 :

    4 * 16 + 14 = 78

    Maintenant, laissez-nous le faire dans MODE GRAPHIQUE :

    .stack 100h
.data

Jan   db  "         January           ",13
      db  "Sun Mon Tue Wed Thu Fri Sat",13
      db  "                 1   2   3 ",13
      db  " 4   5   6   7   8   9  10 ",13
      db  "11  12  13  14  15  16  17 ",13
      db  "18  19  20  21  22  23  24 ",13
      db  "25  26  27  28  29  30  31 ",0
color db 181
x     db 0     ;SCREEN COORDINATE (COL).
y     db 0     ;SCREEN COORDINATE (ROW).

.code          
;INITIALIZE DATA SEGMENT.
  mov  ax,@data
  mov  ds,ax 

;SWITCH SCREEN TO GRAPHICS MODE.
  mov  ah,0
  mov  al,13h  ;320x240x256.
  int  10H

  mov  di, offset jan
while:      
  call gotoxy  ;SET CURSOR POSITION FOR CURRENT CHAR.
  mov  al, [ di ]  ;CHAR TO DISPLAY.
  cmp  al, 13    ;IF CHAR == 13
  je   linebreak ;THEN JUMP TO LINEBREAK.
  cmp  al, 0   ;IF CHAR == 0
  je   finish  ;THEN JUMP TO FINISH.
  call char_display  ;DISPLAY CHAR IN AL WITH "COLOR".
  inc  x  ;NEXT CHARACTER GOES TO THE RIGHT.
  jmp  next_char
linebreak:  
  inc  y  ;MOVE TO NEXT LINE.    
  mov  x, 0  ;X GOES TO THE LEFT.
next_char:
  inc  di  ;NEXT CHAR IN "JAN".
  jmp  while

finish:

;WAIT FOR ANY KEY.
  mov  ah,7
  int  21h

;FINISH THE PROGRAM PROPERLY.
  mov  ax,4c00h
  int  21h        

;-------------------------------------------------     
;DISPLAY ONE CHARACTER IN "AL" WITH "COLOR".

proc char_display
  mov  ah, 9
  mov  bh, 0
  mov  bl, color  ;ANY COLOR.
  mov  cx, 1  ;HOW MANY TIMES TO DISPLAY CHAR.
  int  10h
  ret
endp    

;-------------------------------------------------     
proc gotoxy
  mov dl, x
  mov dh, y
  mov ah, 2 ;SERVICE TO SET CURSOR POSITION.
  mov bh, 0 ;PAGE.
  int 10h   ;BIOS SCREEN SERVICES.  
  ret
endp

    Mes graphiques algorithme nécessite l'utilisation de char(13) pour les retours à la ligne ((pas 13,10) et de la chaîne pour en finir avec 0.

    • que faire si je dois écrire ces chaînes en mode vidéo?
    • Mode vidéo? Voulez-vous dire graphiques non en mode texte?
    • Je veux dire de l'écriture dans la mémoire vidéo
    • Oh, tu veux dire le mode graphique. Travail sur elle . . .
    InformationsquelleAutor Jose Manuel Abarca Rodríguez
  2. 1

    Code Pour Toutes les combinaisons de couleurs d'arrière-plan:

    Include Irvine32.inc

.data

str1 byte "F",0dh,0ah,0          ;character initialized (0dh,0ah for next line)

foreground Dword ?               ;variable declaration
background Dword ?
counter Dword ?

.code

main PROC

mov ecx,16                     ; initializing ecx with 16

l1:                             ;outer loop
mov counter,ecx
mov foreground,ecx
dec foreground
mov ecx,16



l2:                            ;inner loop

mov background , ecx
dec background

mov eax,background      ; Set EAX = background
shl eax,4               ; Shift left, equivalent to multiplying EAX by 16
add eax,foreground      ; Add foreground to EAX

call settextcolor       ;set foreground and background color


mov edx, offset str1    ; string is moved to edx for writing
call writestring


loop l2                  ;calling loop

mov ecx,counter

loop l1
    exit
main ENDP
END main
    InformationsquelleAutor Ghost
  3. 0
    Include Irvine32.inc

.data

str1 BYTE "different color string",0dh,0ah,0        ;string initializing

counter dword ?                                     ;save loop value in counter

.code

main PROC

mov ecx,4                                          ;loop repeated 4 times

l1:
    mov counter,ecx                                ;counter save loop no

    mov eax,counter                          ;eax contain loop no 
                                                ;which is equal to counter
                                                                           ; color no

    call    SetTextColor                           ;Call color library

    mov edx,offset  str1                       ;string reference is moved to edx

    call    WriteString                            ;string is write from reference

loop l1                                            ; calling loop l1

    exit
main ENDP
END main
    InformationsquelleAutor Ghost