Comment itérer dans Hash (of Hashes) en Perl?

Cette réponse s'appuie sur l'idée derrière Dave Hinton, c'est à dire, à écrire un usage général de la sous-routine de pied d'une valeur de hachage de la structure. Ce hachage walker prend un code de référence et appelle simplement ce code pour chaque nœud feuille dans la table de hachage.

Avec une telle approche, le même hachage walker peut être utilisé pour faire de nombreuses choses, en fonction de rappel que nous lui donnons. Pour encore plus de flexibilité, vous avez besoin de passer deux rappels, l'une pour invoquer lorsque la valeur est une valeur de hachage de référence et l'autre partie à invoquer quand il est une valeur scalaire. Les stratégies de ce genre sont décrites plus en détail dans Marc Jason Dominus' excellent livre, D'Ordre Supérieur Perl.

use strict;
use warnings;

sub hash_walk {
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
    }
}

my %data = (
    a => {
        ab => 1,
        ac => 2,
        ad => {
            ada => 3,
            adb => 4,
            adc => {
                adca => 5,
                adcb => 6,
            },
        },
    },
    b => 7,
    c => {
        ca => 8,
        cb => {
            cba => 9,
            cbb => 10,
        },
    },
);

sub print_keys_and_value {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $v, "@$key_list";
}

hash_walk(\%data, [], \&print_keys_and_value);

Le plus tôt réponses montrent comment déployer votre propre solution, ce qui est bon à faire au moins une fois afin de comprendre les entrailles de la façon dont perl références et structures de données de travail. Vous devriez vraiment lire à travers perldoc perldsc et perldoc perlref si vous ne l'avez pas déjà.

Cependant, vous n'avez pas besoin d'écrire votre propre solution-il y a déjà un module CPAN qui va parcourir de manière arbitraire-des structures de données complexes pour vous: Data::Visiteur.

Ce n'est pas vraiment une nouvelle réponse, mais je voulais partager comment faire pour ne plus que
il suffit d'imprimer toutes les valeurs de hachage de manière récursive, mais aussi de les modifier si nécessaire.

Voici ma jamais à la légère modification de la dave4420 de réponse dans lequel
la valeur est passée à la fonction de rappel comme une référence pour mon rappel
routine pourrait donc modifier chaque valeur dans la table de hachage.

J'ai également eu à reconstruire la table de hachage comme si chaque boucle crée des copies
pas de références.

sub hash_walk {
   my $self = shift;
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            $self->hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
        # Replace old hash values with the new ones
        $hash->{$k} = $v;
    }
}

hash_walk(\%prj, [], \&replace_all_val_strings);

sub replace_all_val_strings {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
    $$v =~ s/oldstr/newstr/;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
}

foreach my $keyname (keys(%foo) {
  my $subhash = $foo{$keyname};
  # stuff with $subhash as the value at $keyname
}