Comment la Force de remplacer la macro s'applique sur l'en-tête aussi

Je veux trouver & remplacer un texte dans un document word. J'ai créé une macro comme ci-dessous.

Sub Macro1()
  ActiveDocument.Content.Find.Execute FindText:="#Text1", ReplaceWith:="acca", _
     Replace:=wdReplaceAll   
End Sub

Il a remplacé toutes eu lieu, mais pas dans l'en-tête/pied de page!!
Comment forcés de travailler sur l'ensemble du document inclure l'en-tête/corps/pied de page?

Il y a un quelques idées dans cette recherche

InformationsquelleAutor Moh Tarvirdi | 2012-07-26

J'ai toujours utilisé ce code VBA pour Rechercher/Remplacer, et il va faire des en-Têtes/Pieds de page ainsi que le corps du document:

    Dim myStoryRange As Range


        For Each myStoryRange In ActiveDocument.StoryRanges
        With myStoryRange.Find
            .Text = "Text to find to replace goes here"
            .Replacement.Text = "And the replacement text goes here"
            .Wrap = wdFindContinue
            .Execute Replace:=wdReplaceAll
        End With
        Do While Not (myStoryRange.NextStoryRange Is Nothing)
            Set myStoryRange = myStoryRange.NextStoryRange
            With myStoryRange.Find
                .Text = "Text to find to replace goes here"
                .Replacement.Text = "And the replacement text goes here"
                .Wrap = wdFindContinue
                .Execute Replace:=wdReplaceAll
            End With
        Loop
    Next myStoryRange

Vous pouvez également copier et coller un tas de fois dans le même Sous de remplacer des chaînes différentes en même temps.

+1 pour être beaucoup plus lisse que ma réponse.
+1 pour la solution de contournement. Le seul problème, c'est quand vous avez eu "coller un tas de fois dans le même sous" les macros devenir vraiment lent...

InformationsquelleAutor L. Miller

Il devrait y avoir une meilleure façon, mais je ne le trouve pas:

Sub ReplaceHeaderFooterandBody(findString As String, replaceString As String)
ActiveDocument.Windows(1).View.SeekView = wdSeekPrimaryHeader
With Selection.Find
        .Text = findString
        .Replacement.Text = replaceString
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
ActiveDocument.Windows(1).View.SeekView = wdSeekPrimaryFooter
With Selection.Find
        .Text = findString
        .Replacement.Text = replaceString
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
ActiveDocument.Windows(1).View.SeekView = wdSeekMainDocument
With Selection.Find
        .Text = findString
        .Replacement.Text = replaceString
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

Il semble que Word refuse de recherche sur une zone, sauf si c'est votre vue actuelle (ce qui est ridicule à mon avis). Vous ne pouvez pas même une recherche dans l'ensemble du document, y compris les en-têtes et pieds de page à la fois par le biais de l'INTERFACE utilisateur. Voici une question à un autre site qui semble obtenir la même réponse.

InformationsquelleAutor Daniel

0

Je ne vois pas de moyen de "forcer" le dialogue Rechercher et Remplacer pour inclure l'en-tête et pied de page de texte. J'ai enregistré une macro lors de la modification de texte d'en-tête et a obtenu ce code:
```
Sub Macro1()
'
' Macro1 Macro
' Macro recorded 7/26/2012 by Jimmy Peña
'
  If ActiveWindow.View.SplitSpecial <> wdPaneNone Then
    ActiveWindow.Panes(2).Close
  End If
  If ActiveWindow.ActivePane.View.Type = wdNormalView Or ActiveWindow. _
    ActivePane.View.Type = wdOutlineView Then
    ActiveWindow.ActivePane.View.Type = wdPrintView
  End If
  ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
  Selection.MoveRight Unit:=wdCharacter, Count:=1
  Selection.Delete Unit:=wdCharacter, Count:=1
  Selection.TypeText Text:="d"
End Sub
```
Je suis allé à Vue » en-Tête/Pied de page, supprimé un personnage et tapé un nouveau.

Ce que vous probablement avez à faire est de Trouver & remplacer dans VBA:
- Lire le contenu de l'en-tête dans une variable de Chaîne
- Analyser la Chaîne variable, en remplacement de texte si nécessaire, puis
- Écrire le contenu de la variable de Chaîne de retour à l'en-tête
Répétez l'opération pour le pied de page.

InformationsquelleAutor JimmyPena

J'ai trouvé le bon code ici, Il va faire un texte de remplacement, même dans les zones de texte dans le pied de page/header.

 Sub FindReplaceAnywhere(ByVal pFindTxt As String, ByVal pReplaceTxt As String)
  Dim rngStory As Word.Range
  Dim lngJunk As Long
  Dim oShp As Shape
TryAgain:
  'Fix the skipped blank Header/Footer problem
  lngJunk = ActiveDocument.Sections(1).Headers(1).Range.StoryType
  'Iterate through all story types in the current document
  For Each rngStory In ActiveDocument.StoryRanges
    'Iterate through all linked stories
    Do
      SearchAndReplaceInStory rngStory, pFindTxt, pReplaceTxt
      On Error Resume Next
      Select Case rngStory.StoryType
      Case 6, 7, 8, 9, 10, 11
        If rngStory.ShapeRange.Count > 0 Then
          For Each oShp In rngStory.ShapeRange
            If oShp.TextFrame.HasText Then
              SearchAndReplaceInStory oShp.TextFrame.TextRange, _
                  pFindTxt, pReplaceTxt
            End If
          Next
        End If
      Case Else
        'Do Nothing
      End Select
      On Error GoTo 0
      'Get next linked story (if any)
      Set rngStory = rngStory.NextStoryRange
    Loop Until rngStory Is Nothing
  Next
End Sub
Sub SearchAndReplaceInStory(ByVal rngStory As Word.Range, _
    ByVal strSearch As String, ByVal strReplace As String)
  With rngStory.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = strSearch
    .Replacement.Text = strReplace
    .Wrap = wdFindContinue
    .Execute Replace:=wdReplaceAll
  End With
End Sub

Comment est différente de performance de la réponse "correcte"

InformationsquelleAutor l0pan

Vous devez vous connecter pour publier un commentaire.