Comment lire/écrire un texte de carte en ligne?

J'essaie de lecture/écriture en ligne, ID du/fichier txt stocker dans la carte SD à l'aide de Auduino Uno. Mais je n'ai pas sucsess.
S'il vous plaît aider moi. Grâce

InformationsquelleAutor | 2014-09-15

arduino arduino-uno

Vous pouvez utiliser

if (myFile) {
 while (myFile.available()) {
  String line = myFile.readStringUntil('\n');
 }
}

InformationsquelleAutor Tavinson

Veuillez commencer avec la Arduino > Exemples > SD > ReadWrite:

/*
  SD card read/write

 This example shows how to read and write data to and from an SD card file
 The circuit:
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4

 created   Nov 2010
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe

 This example code is in the public domain.

 */

#include <SPI.h>
#include <SD.h>

File myFile;

void setup()
{
  //Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; //wait for serial port to connect. Needed for Leonardo only
  }


  Serial.print("Initializing SD card...");
  //On the Ethernet Shield, CS is pin 4. It's set as an output by default.
  //Note that even if it's not used as the CS pin, the hardware SS pin
  //(10 on most Arduino boards, 53 on the Mega) must be left as an output
  //or the SD library functions will not work.
  pinMode(10, OUTPUT);

  if (!SD.begin(4)) {
    Serial.println("initialization failed!");
    return;
  }
  Serial.println("initialization done.");

  //open the file. note that only one file can be open at a time,
  //so you have to close this one before opening another.
  myFile = SD.open("test.txt", FILE_WRITE);

  //if the file opened okay, write to it:
  if (myFile) {
    Serial.print("Writing to test.txt...");
    myFile.println("testing 1, 2, 3.");
    //close the file:
    myFile.close();
    Serial.println("done.");
  } else {
    //if the file didn't open, print an error:
    Serial.println("error opening test.txt");
  }

  //re-open the file for reading:
  myFile = SD.open("test.txt");
  if (myFile) {
    Serial.println("test.txt:");

    //read from the file until there's nothing else in it:
    while (myFile.available()) {
      Serial.write(myFile.read());
    }
    //close the file:
    myFile.close();
  } else {
    //if the file didn't open, print an error:
    Serial.println("error opening test.txt");
  }
}

void loop()
{
  //nothing happens after setup
}

Le code devrait fonctionner. Assurez-vous que vos broches sont correctement connectés.

Thanhs pour votre aide, Mes épingles se connecter correctement et j'ai lu de succès que vous me montrer. Mais je veux lire EN LIGNE.Par exple, j'ai un login.txt: 41001662<br>41001536<br>.....Et je veux lire 41001662 dans la Chaîne de données1, 41001536 en data2.......

InformationsquelleAutor George Profenza

Pas sûr que vous avez encore besoin d'aide, mais va ici.

Première suggestion - la modification de l'login.txt

Au lieu d'utiliser les balises br, essayez de l'insérer "\r\n" entre vos Identifiants. Par exemple, si vous créez votre login.txt en faisant un PHP+base de données SQL de la requête, et écrit les résultats dans un fichier, remplacez le br dans votre code avec des "\r\n". Ou, si vous êtes en mesure d'ouvrir et de modifier le login.txt le faire, et de remplacer chacun des br avec une nouvelle ligne.

Tout ce que vous avez à faire est de lire chacune des lignes dans votre fichier, un par un.

#include <SD.h>
#include <SPI.h>

int CS_PIN = 10;
char logfile[] = {"login.txt"};

File file;

void setup() {

  Serial.begin(9600);
  initializeSD();

  openFile(logfile);
  while(file.available()) {
    //print the lines to serial monitor
    Serial.println(readLine());
  }
  closeFile();
}
void loop() {
}

void initializeSD() {
  Serial.println("Initializing SD card...");
  pinMode(CS_PIN, OUTPUT);

  if (SD.begin()) {
    Serial.println("SD card is ready to use.");
  } else {
    Serial.println("SD card initialization failed");
    return;
  }
}

void closeFile() {
  if (file) {
    file.close();
    Serial.println("File closed");
  }
}

int openFile(char filename[]) {
  file = SD.open(filename);
  if (file) {
    Serial.println("File opened with success!");
    return 1;
  } else {
    Serial.println("Error opening file...");
    return 0;
  }
}

String readLine() {
  String received = "";
  char ch;
  while (file.available()) {
    ch = file.read();
    if (ch == '\n') {
      return String(received);
    } else {
      received += ch;
    }
  }
  return "";
}

C'est un raccourci, non testé, et un peu la version modifiée du code publié sur ce Lien YouTube (voir la vidéo descripton d'un lien vers le code complet). Aussi, assurez-vous de vérifier le câblage, il est donc comme indiqué dans la vidéo.

Deuxième suggestion: changer la façon dont les entrants caractères sont lus

Si vous ne parvenez pas à modifier la structure de la login.txt fichier, et ne peut le lire à partir d'une carte SD, essayez ce code afin de le lire à partir d'un fichier (version modifiée de l'un dans la première suggestion):

String readLine() {
  String received = "";
  char ch;
  while (file.available()) {
    ch = file.read();
    if (ch == '<') {            //Is the tag starting?
      return String(received);  //Return what you have so far (ID)
    } else if(ch == '>') {      //Is the tag ending?
      received = "";            //Empty the string, we don't need br
    } else {                    //Everything's OK, append to the string
      received += ch;
    }
  }
  return "";
}

Veuillez noter que les deux suggestions ne stocker les lignes dans variables distinctes. Je vous suggère de faire ce que vous voulez faire (impression à la série, flash LED, etc) avec chacune des lignes dans le fichier, que vous les lisez.

InformationsquelleAutor FiddlingAway

Answare par Tavinson est correct, ce qui est

if (myFile) {
 while (myFile.available()) {
  String line = myFile.readStringUntil('\n');
 }
}

InformationsquelleAutor BHAVIK BHANSALI

Vous devez vous connecter pour publier un commentaire.