Comment mettre un texte sur une Editbox Ruban via VBA (Excel)

Comment puis-je mettre un texte dans un Ruban Editbox? Je ne peux pas le trouver sur internet :/

Je ne peux trouver des exemples de cliquez sur l'événement, mais rien à propos d'un texte à partir d'un Sous.

Ainsi, par exemple, je veux quelque chose comme ceci:

Sub settingText()
   editboxname = "my text"
end sub

Voulez-vous dire que vous voulez une zone de texte apparaît dans le Ruban? Serait-ce similaire à la police déroulante dans l'onglet Accueil, par exemple?
Non, j'ai déjà la zone de texte dans le Ruban, et je veux juste mettre un texte en tout temps lorsque j'exécute un code. Je suis nouveau à cela et j'apprends, donc je vais vérifier sur la liste déroulante des trucs.
Je sais juste une façon de mettre un texte quand j'ouvre la feuille de calcul, mais je ne sais toujours pas comment mettre un texte quand je suis à l'aide de la feuille de calcul
J'ai trouvé une solution! Il y a quelques lignes pour le faire :S shulerent.com/2011/08/16/...
Merci de poster votre solution comme une réponse.

OriginalL'auteur Braulio | 2013-09-06

La solution que j'ai trouvé sur ce lien: http://www.shulerent.com/2011/08/16/changing-the-value-of-an-editbox-office-ribbon-control-at-runtime/

Voici un exemple que j'ai testé et ça a bien fonctionné:

'Global Variables:
Public MyRibbonUI As IRibbonUI
Public GBLtxtCurrentDate As String

Private Sub OnRibbonLoad(ribbonUI As IRibbonUI)

    Set MyRibbonUI = ribbonUI
    GBLtxtCurrentDate = ""

End Sub

Private Sub ocCurrentDate(control As IRibbonControl, ByRef text)

    GBLtxtCurrentDate = text
    MyRibbonUI.InvalidateControl (control.id)

End Sub

Private Sub onGetEbCurrentDate(control As IRibbonControl, ByRef text)
    text = GBLtxtCurrentDate
End Sub

Public Sub MyTest()
    'Here is an example which you are setting a text to the editbox
    'When you call InvalidateControl it is going to refresh the editbox, when it happen the onGetEbCurrentDate (which is the Gettext) will be called and the text will be atributed.
    GBLtxtCurrentDate = "09/09/2013"
    MyRibbonUI.InvalidateControl ("ebCurrentDate")
End Sub

<?xml version="1.0" encoding="UTF-8"?>
<customUI xmlns="http://schemas.microsoft.com/office/2009/07/customui" onLoad="OnRibbonLoad">
  <ribbon>
    <tabs>
      <tab id="Objects" label="Objects">
        <group id="grp" label="My Group">
          <editBox id="ebCurrentDate" label="Date" onChange="ocCurrentDate" getText="onGetEbCurrentDate"/>
        </group>
      </tab>
    </tabs>
  </ribbon>
</customUI>

OriginalL'auteur Braulio

C'est un petit moment que cette réponse a été publiée, et il semble y avoir une récente-ish à modifier le comportement du ruban, ce qui signifie que l'original de la réponse affichée peut ne pas être une solution de plus. Pour le dossier, j'utilise Excel 2013 avec quelques mises à jour qui sont datées d'après Braulio réponse.

Le cœur de la différence, c'est que Invalider et InvalidateControl sur le ruban ne se comportent pas de la même manière que précédemment. Cela signifie que InvalidateControl n'appelle pas la getText rappel sur la zone de texte. J'ai remplacé le InvalidateControl appels avec Invalidate (donc les forces d'un nouveau tirage au sort sur l'ensemble du ruban), et qui ne déclencher le rappel comme prévu.

Donc voici le code de ma solution pour un nom de fichier/bouton de navigation (remarque, j'ai inclus le code supplémentaire pour la mise en cache de l'INTERFACE utilisateur du ruban de référence sur un très caché de la feuille, de sorte que réinitialise au cours du développement de ne pas faire le ruban inaccessible).

Private sobjRibbon As IRibbonUI
Private strFilename As String
Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (destination As Any, source As Any, ByVal length As Long)
Private Function GetRibbon() As IRibbonUI
If sobjRibbon Is Nothing Then
Dim objRibbon As Object
CopyMemory objRibbon, ThisWorkbook.Worksheets("Ribbon_HACK").Range("A1").Value, 4
Set sobjRibbon = objRibbon
End If
Set GetRibbon = sobjRibbon
End Function
'Callback for customUI.onLoad
Sub Ribbon_Load(ribbon As IRibbonUI)
Set sobjRibbon = ribbon
Dim lngRibPtr As Long
lngRibPtr = ObjPtr(ribbon)
' Write pointer to worksheet for safe keeping
ThisWorkbook.Worksheets("Ribbon_HACK").Range("A1").Value = lngRibPtr
strFilename = ""
End Sub
'Callback for FileName onChange
Sub OnChangeFilename(control As IRibbonControl, text As String)
strFilename = text
End Sub
'Callback for FileName getText
Sub GetFileNameText(control As IRibbonControl, ByRef returnedVal)
returnedVal = strFilename
End Sub
'Callback for FilenameBrowse onAction (I'm looking for XML files here)
Sub OnClickFilenameBrowse(control As IRibbonControl)
Dim objFileDialog As Office.FileDialog
Set objFileDialog = Application.FileDialog(msoFileDialogFilePicker)
With objFileDialog
.AllowMultiSelect = False
.Title = "Please select the file."
.Filters.Clear
.Filters.Add "XML", "*.xml"
If .Show = True Then
strFilename = .SelectedItems(1)
GetRibbon().Invalidate ' Note the change here, invalidating the entire ribbon not just the individual control
End If
End With
End Sub

Pour mémoire, voici le code XML pour les deux objets que je traite ici:

<editBox id="FileName" onChange="OnChangeFilename" screentip="Filename of the XML file to upload" label="XML file name" showImage="false" getText="GetFileNameText" />
<button id="FilenameBrowse" imageMso="ImportExcel" onAction="OnClickFilenameBrowse" screentip="Find the file to upload" label="Browse" />

OriginalL'auteur greenbutterfly

Vous devez vous connecter pour publier un commentaire.