Comment obtenir la liste de tous les fichiers avec l'extension ESY dans un répertoire?

En VBA, comment puis-je obtenir une liste de tous les fichiers avec une extension spécifique dans un répertoire spécifique?

je suis incapable de faire Application.FileSearchparce que je suis à l'aide d'excel 2007

source d'informationauteur l--''''''---------''''''''''''

  1. 12

    En réponse à votre commentaire "alors, combien de fois puis-je savoir pour le faire fonctionner?"cet exemple s'exécute jusqu'à ce qu'il répertorie tous les fichiers dont les noms correspondent à strPattern. Modifier la strFolder constante.

    Public Sub ListESY()
Const strFolder As String = "C:\SomeFolder\"
Const strPattern As String = "*.ESY"
Dim strFile As String
strFile = Dir(strFolder & strPattern, vbNormal)
Do While Len(strFile) > 0
    Debug.Print strFile '<- view this in Immediate window; Ctrl+g will take you there
    strFile = Dir
Loop
End Sub
  2. 3

    Dir("C:\yourPath\*.ESY", vbNormal)
    Retourne le premier fichier avec esy extension.
    Chaque appel de la fonction Dir() retourne la prochaine.

  3. 2

    Alternative: utiliser le "Microsoft Scripting Runtime" (bibliothèque de vérifier dans Outils de...Références) pour le FileSystemObject famille d'objets. Quelque chose comme ce qui suit, peut-être:

    Public Function ESYFileCount(dir_path as String) as Long

Dim fil As File

    With New FileSystemObject
        With .GetFolder(dir_path)
            For Each fil In .Files
                If LCase(Right(fil.Name, 4)) = ".esy" Then
                    ESYFileCount = ESYFileCount + 1
                End If
            Next
        End With        
    End With

End Function
  4. 2

    Le code suivant s'exécute sur 19 fois plus rapide que l'utilisation FileSystemObject. Sur ma machine, trouver des 4000 fichiers dans trois différents drectories a pris 1.57 secondes à l'aide d'FileSystemObject, mais seulement 0,08 secondes à l'aide de ce code.

       Public Function CountFilesWithGivenExtension( _
          i_strFolderWithTerminalBackslant As String, _
          i_strExtensionIncludingPeriod As String _
          ) As Long

       If Len(Dir$(i_strFolderWithTerminalBackslant & "*" _
             & i_strExtensionIncludingPeriod)) > 0 Then

          CountFilesWithGivenExtension = 1

          While Len(Dir$) > 0

             CountFilesWithGivenExtension = _
                   CountFilesWithGivenExtension + 1

             DoEvents

          Wend
       Else
          CountFilesWithGivenExtension = 0
       End If

   End Function

    Exemple d'utilisation:

       Debug.Print CountFilesWithGivenExtension("C:\", ".ex*")

    (Le "DoEvents" n'est pas nécessaire, mais permet l'utilisation de Pause/Pause si nécessaire.)