Comment obtenir la longueur maximum de chaque colonne dans unix?

Suppose, j'ai un fichier source de ce genre.

ID|NAME|ADDRESS
1|ABC|PUNE
2|XYZA|MUMBAI
12|VB|NAGPUR

Je veux obtenir la longueur maximum de chaque colonne (à l'exclusion des noms d'en-tête).
La sortie devrait ressembler à ceci.
2/4/6

J'ai essayé la commande comme ceci.
queue +2 nom de fichier | cut-d"|" -f1 | awk '{ print length }' | sort -r | uniq

Cela fonctionne pour la 1ère colonne. Est-il une option disponible dans awk pour obtenir un max de longueur pour chaque colonne?

InformationsquelleAutor Vicky | 2014-07-09
  1. 11

    Ce peut être une façon de le faire, de sorte que vous n'avez pas de soins sur le nombre de champs que vous avez: stocker les longueurs dans un tableau et vérifier en permanence si c'est le maximum ou pas. Enfin, la boucle à travers eux et imprimer les résultats.

    awk -F'|' 'NR>1{for (i=1; i<=NF; i++) max[i]=(length($i)>max[i]?length($i):max[i])}
           END {for (i=1; i<=NF; i++) printf "%d%s", max[i], (i==NF?RS:FS)}' file

    Voir sortie:

    $ awk -F'|' 'NR>1{for (i=1; i<=NF; i++) max[i]=(length($i)>max[i]?length($i):max[i])} END {for (i=1; i<=NF; i++) printf "%d%s", max[i], (i==NF?RS:FS)}' a
2|4|6

    Pour nombre variable de colonnes, on peut stocker le montant maximal de colonnes, par exemple, dans cols:

    $ awk -F'|' 'NR>1{cols=(cols<=NF?NF:cols); for (i=1; i<=NF; i++) max[i]=(length($i)>max[i]?length($i):max[i])} END {for (i=1; i<=cols; i++) printf "%d%s", max[i], (i==cols?RS:FS)}' a
2|4|6
    • Grâce fedorqui. il fonctionne pour moi.
    • Qui peut imprimer sortie correcte si toutes les lignes ont le même nombre de champs, que si la dernière ligne en manque un?
    • si oui, nous pouvons emmagasiner le maximum NF et boucle sur cette base. Voir mise à jour.
    InformationsquelleAutor fedorqui
  2. 3

    Cela pourrait fonctionner pour vous (mais si il y a de nombreux domaines, je ne l'utiliserais for cycle et un tableau pour stocker la longueur de champs...): 

    awk -F '|' 'NR>1 {if ( length($1) > l1 ) { l1=length($1) }
                  if ( length($2) > l2 ) { l2=length($2) }
                  if ( length($3) > l2 ) { l3=length($3) }
                 }
             END { print l1 "|" l2 "|" l3 }' INPUTFILE
    InformationsquelleAutor Zsolt Botykai