Comment obtenir le dernier indice d'un caractère dans une chaîne de caractères?

J'ai la tâche suivante:

Il y a un élément xml contenant une longue chaîne. J'ai besoin d'utiliser xsl pour transformer cet élément dans un certain nombre de html <input> balises. Il fonctionne comme ceci: si la chaîne est plus longue que celle d'un <input> champ peut contenir sans défilement, je garde le même modèle de manière récursive pour créer un autre champ de saisie avec la remainig texte.

Le problème est que la chaîne est souvent coupée en deux au milieu de la parole qui n'est pas sympa.

Donc j'ai besoin de trouver la position de la dernière space caractère qui n'est pas plus grande que la taille de la sous-chaîne qui s'inscrit dans la <input> balise et d'imprimer uniquement la sous-chaîne avant sur la ligne.

J'ai donc préparer une sous-chaîne de longueur maximale, qui peut s'adapter dans le domaine, mais je n'ai aucune idée de comment faire pour obtenir l'index de la dernière space en elle et de le passer comme paramètre dans le prochain appel de la fonction.

UPD: voici ce que j'ai obtenu jusqu'à présent

<xsl:template name="multilineInput">
    <xsl:param name="input" select="."/>
    <xsl:param name="maxFirst" select="."/>
    <xsl:param name="firstLineWidth" select="."/>



    <input>
        <xsl:attribute name="readonly">readonly</xsl:attribute>
        <xsl:attribute name="class">input_multiline</xsl:attribute>
        <xsl:attribute name="style">width = "<xsl:value-of select="$firstLineWidth"/>"</xsl:attribute>
        <xsl:attribute name="type">text</xsl:attribute>
        <xsl:attribute name="value"><xsl:value-of select="substring($input, 1, $maxFirst)"/></xsl:attribute>
    </input>

    <xsl:if test="$maxFirst &lt; string-length($input)">
        <xsl:call-template name="multilineInput">
            <xsl:with-param name="input" select="substring($input, $maxFirst+1, string-length($input)-$maxFirst)"/>
            <xsl:with-param name="maxFirst" select="110"/>
            <xsl:with-param name="firstLineWidth" select="'980'"/>
        </xsl:call-template>
    </xsl:if>

</xsl:template>

OriginalL'auteur svz | 2012-09-28

Cette transformation imlements un moyen simple et efficace de l'algorithme: le dernier espace dans une chaîne de caractères est le premier espace dans la chaîne inversée:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
     <xsl:call-template name="lastCharIndex">
       <xsl:with-param name="pText" select=
         "'The quick brown fox jumped over the lazy dog.'"/>
     </xsl:call-template>
 </xsl:template>

 <xsl:template name="lastCharIndex">
  <xsl:param name="pText"/>
  <xsl:param name="pChar" select="' '"/>

  <xsl:variable name="vRev">
    <xsl:call-template name="reverse">
     <xsl:with-param name="pStr" select="$pText"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:value-of select=
  "string-length($pText) - string-length(substring-before($vRev, $pChar))"/>
 </xsl:template>

 <xsl:template name="reverse">
  <xsl:param name="pStr"/>

  <xsl:variable name="vLength" select="string-length($pStr)"/>
  <xsl:choose>
    <xsl:when test="$vLength = 1"><xsl:value-of select="$pStr"/></xsl:when>
    <xsl:otherwise>
      <xsl:variable name="vHalfLength" select="floor($vLength div 2)"/>
      <xsl:variable name="vrevHalf1">
        <xsl:call-template name="reverse">
         <xsl:with-param name="pStr" 
              select="substring($pStr, 1, $vHalfLength)"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:variable name="vrevHalf2">
        <xsl:call-template name="reverse">
         <xsl:with-param name="pStr" 
              select="substring($pStr, $vHalfLength+1)"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="concat($vrevHalf2, $vrevHalf1)"/>
    </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

Lorsque cette transformation est appliquée sur n'importe quel document XML (non utilisé), le voulait, résultat correct est produit:

Ok, maintenant que nous avons obtenu ce 41, je ne suis pas sûr de comprendre comment l'utiliser correctement. Il imprime la valeur, mais je ne sais pas comment je dois le passer comme paramètre à un autre modèle ou comment je dois modifier mon template actuel de faire usage de cette. J'ai ajouté un exemple de ce que j'ai en ce moment et seront reconnaissants pour une explication. Merci.

OriginalL'auteur Dimitre Novatchev

Le récursive modèle peut être utilisé pour retourner le dernier index d'un délimiteur:

<xsl:template name="last-index-of">
    <xsl:param name="txt"/>
    <xsl:param name="remainder" select="$txt"/>
    <xsl:param name="delimiter" select="' '"/>

    <xsl:choose>
        <xsl:when test="contains($remainder, $delimiter)">
            <xsl:call-template name="last-index-of">
                <xsl:with-param name="txt" select="$txt"/>
                <xsl:with-param name="remainder" select="substring-after($remainder, $delimiter)"/>
                <xsl:with-param name="delimiter" select="$delimiter"/>
            </xsl:call-template>      
        </xsl:when>
        <xsl:otherwise>
            <xsl:variable name="lastIndex" select="string-length(substring($txt, 1, string-length($txt)-string-length($remainder)))+1"/>
            <xsl:choose>
                <xsl:when test="string-length($remainder)=0">
                    <xsl:value-of select="string-length($txt)"/>
                </xsl:when>
                <xsl:when test="$lastIndex>0">
                    <xsl:value-of select="($lastIndex - string-length($delimiter))"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="0"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Elle peut être invoquée comme ceci:

<xsl:call-template name="last-index-of">
    <xsl:with-param name="txt" select="'The quick brown fox jumped over the lazy dog.'"/>
    <xsl:with-param name="delimiter" select="' '"></xsl:with-param>
 </xsl:call-template>

Et retours: 41

Vous pouvez attribuer le résultat du modèle d'appel à une variable comme ceci:

<xsl:variable name="last-index">
    <xsl:call-template name="last-index-of">
        <xsl:with-param name="txt" select="'The quick brown fox jumped over the lazy dog.'"/>
        <xsl:with-param name="delimiter" select="' '"></xsl:with-param>
     </xsl:call-template>
</xsl:variable>

Bonne réponse, mais je pense que le bon indice est de 41 ?
Ok, maintenant que nous avons obtenu ce 41, je ne suis pas sûr de comprendre comment l'utiliser correctement. Il imprime la valeur, mais je ne sais pas comment je dois le passer comme paramètre à un autre modèle ou comment je dois modifier mon template actuel de faire usage de cette. J'ai ajouté un exemple de ce que j'ai en ce moment et seront reconnaissants pour une explication. Merci.
Votre question est bien défini et a été entièrement résolus. S'il vous plaît, pensez à bien comment définir une nouvelle question avec le problème que vous êtes maintenant face -- il doit y avoir une complète (mais petite) document XML source, l'exact résultat voulu, et la description des règles du jeu que la transformation doit mettre en œuvre. S pour utiliser le résultat de l'appel d'un modèle -- vous devez appeler le modèle à l'intérieur du corps d'un xsl:variable -- puis utilisez cette variable, dans notre cas, sa valeur sera de 41.
Novatchev, je vous Remercie. Juste ne pense pas que cela valait la peine de poster une nouvelle question.
Oui, 41 est la position correcte. Je pensais à une 0 index de base; la suite de travailler avec plusieurs langues et connaissance de Java et de JavaScript. J'ai aussi mis ma réponse à la poignée à plusieurs cas de bord que j'ai remarqué.

OriginalL'auteur Mads Hansen

1

Vous pouvez utiliser le EXSLT split modèle (description; la mise en œuvre) ou tokenize de diviser la chaîne en place par des espaces. Ensuite, vous pouvez imprimer tous les nœuds de texte à l'exception de la dernière, et/ou de l'utilisation de la longueur du dernier nœud de texte pour obtenir l'index de la dernière de l'espace.

Voir aussi ce modèle qui pourraient s'adapter à vos besoins.

Merci pour votre réponse. Va vérifier ça dès que je peux.
Malheureusement, il n'y a pas de EXSLT de soutien dans le processeur XSL.
La mise en œuvre je lien ne nécessite pas une prise en charge spéciale. C'est juste une norme XSLT 1.0 modèle.

OriginalL'auteur LarsH

Vous devez vous connecter pour publier un commentaire.