Comment obtenir le maximum de valeur au titre du même nœud dans xslt

J'ai un xml comme ci-dessous :

<Report xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
  <Name>HourlyReport</Name>
  <Id>8</Id>
  <TotalResults>1</TotalResults>
  <TotalPages>1</TotalPages>
  <Items>
    <Item>
      <Id>1</Id>
      <Hour0>23</Hour0>
      <Hour1>12</Hour1>
      <Hour2>7</Hour2>
      <Hour3>18</Hour3>
      <Hour4>32</Hour4>
      .
      .
      .
      <Hour20>28</Hour20>
      <Hour21>39</Hour21>
      <Hour22>51</Hour22>
      <Hour23>49</Hour23>
    </Item>
  </Items>
</Report>

j'ai Besoin d'un maximum de valeur à partir de ci-dessus XML à l'aide de xslt . Dans le cas ci-dessus, la valeur maximale est 51. Comment je peux obtenir? Aussi est-il possible d'obtenir cette valeur maximale dans toute variable xslt, donc je peux l'utiliser quelque part d'autre. Je ne suis pas aller de toute façon. Vous pouvez utiliser n'importe quelle version de xslt 1.0 ou 2.0 .

OriginalL'auteur Popeye | 2013-07-31

  1. 16

    Donné XSLT 2.0, il devrait suffire d'utiliser

    <xsl:variable name="max" select="max(/Report/Items/Item/*[starts-with(local-name(), 'Hour')]/xs:integer(.)"/>

    (où la feuille de style aurait besoin de déclarer xmlns:xs="http://www.w3.org/2001/XMLSchema").

    Et avec XSLT 1.0, je voudrais simplement de tri et de prendre le maximum de valeur que dans

    <xsl:variable name="max">
  <xsl:for-each select="/Report/Items/Item/*[starts-with(local-name(), 'Hour')]">
    <xsl:sort select="." data-type="number" order="descending"/>
    <xsl:if test="position() = 1"><xsl:value-of select="."/></xsl:if>
  </xsl:for-each>
</xsl:variable>
    Voir aussi: stackoverflow.com/a/10359896/59087

    OriginalL'auteur Martin Honnen

  2. 3

    Dans XSLT 2.0, avec le Point comme le nœud de contexte, l'utilisation 

    max(*[starts-with(local-name(), 'Hour')])

    OriginalL'auteur Michael Kay

  3. 2

    Cette XSL:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

    <!-- Putting the maximum hour from the list into a variable. -->
    <xsl:variable name="max-hour">
      <xsl:call-template name="find-max">
        <!-- Select the list of hour elements you want to look at. -->
        <xsl:with-param name="hours" select="//*[contains(local-name(), 'Hour')]"/>
      </xsl:call-template>
    </xsl:variable>

  <xsl:template match="*">   
    <!-- Displaying the result you are after. -->
    <result>
      <xsl:value-of select="$max-hour"/>
    </result>
  </xsl:template>

  <!-- This template works recursively on the list of hours. -->
  <xsl:template name="find-max">
    <xsl:param name="hours"/>

    <!-- The value of the first hour in this list. -->
    <xsl:variable name="this-hour">
      <xsl:value-of select="$hours[position() = 1]"/>
    </xsl:variable>

    <xsl:choose>
      <xsl:when test="$hours">
        <!-- The maximum value of the remaining hours in this list. -->
        <xsl:variable name="other-hours">
          <xsl:call-template name="find-max">
            <xsl:with-param name="hours" select="$hours[position() != 1]"/>
          </xsl:call-template>
        </xsl:variable>

        <!-- Return the maximum of this hour and the remaining hours. -->
        <xsl:choose>
          <xsl:when test="$other-hours &gt; $this-hour">
            <xsl:value-of select="$other-hours"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="$this-hour"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:when>

      <!-- We've reached the last hour in the list. -->
      <xsl:otherwise/>
    </xsl:choose>

  </xsl:template>

</xsl:stylesheet>

    vous donne la sortie suivante:

    <result>51</result>
    Bon. Modèles, même récursive, sont presque toujours plus rapide que pour les uns ou les autres constructions en boucle.

    OriginalL'auteur Ben L

  4. 0

    Dans XSLT 1 vous pouvez utiliser la suite-frère

    <xsl:value-of select="/Report/Items/Item/*[starts-with(name(), 'Hour')][not(.&lt;following-sibling::*[starts-with(name(), 'Hour')])]"/>

    OriginalL'auteur Person A