Comment obtenir un nom de contrôle par son nom?

J'ai une fonction simple où il y a une zone de liste modifiable. Si la zone de liste déroulante la valeur est égale à "Désactiver", je vais désactiver la zone de texte B. Il y a beaucoup de zones de liste déroulante avec leurs correspondants de zone de texte B, disposées en rangées et nommé par la main. Si la boîte combo d'Un nommé Product1, la zone de texte B sera nommé Product1_status

Je pensais à quelque chose comme:

If value_of_a = "disable" Then 
 Dim name_of_b as String
 name_of_b = Me.Combo.Name + "_status"
 get_object_by_name(name_of_b).Enabled = False
End If

Comment puis-je faire cela?

OriginalL'auteur Damon Aw | 2012-09-08

  1. 5

    Je ne sais pas comment vous appelez cela, mais voici une procédure qui devraient vous aider:

    Sub test()

Dim ws As Excel.Worksheet
Dim ProductCombo As OLEObject
Dim ProductText As OLEObject

Set ws = ThisWorkbook.Sheets(1)
With ws
    Set ProductCombo = .OLEObjects("Product1")
    Set ProductText = .OLEObjects(ProductCombo.Name & "_status")
    ProductText.Enabled = ProductCombo.Object.Text <> "Disabled"
End With
End Sub

    EDIT: j'ai vraiment hate de la feuille de calcul contrôles - je commencer à partir de zéro à chaque fois que je programme! Néanmoins, je pensais que je voudrais ajouter ce sous-programme qui remet chaque zone de texte dont le nom correspond à la formulation du Produit de besseymd _status, selon ses jumelé zone de liste déroulante. La logique ne supposent que les noms de commencer avec Produit1, Produit2, etc., sans un décalage dans la numérotation:

    Sub test2()

Dim ws As Excel.Worksheet
Dim ctl As OLEObject
Dim i As Long
Dim ProductComboboxesCount
Dim ProductCombo As OLEObject
Dim ProductText As OLEObject
Const ControlPrefix As String = "Product"

Set ws = ThisWorkbook.Sheets(1)
With ws
    For Each ctl In .OLEObjects
        If TypeOf ctl.Object Is MSForms.ComboBox And Left(ctl.Name, Len(ControlPrefix)) = ControlPrefix Then
            ProductComboboxesCount = ProductComboboxesCount + 1
        End If
    Next ctl
    For i = 1 To ProductComboboxesCount
        Set ProductCombo = .OLEObjects(ControlPrefix & i)
        Set ProductText = .OLEObjects(ControlPrefix & i & "_status")
        ProductText.Enabled = ProductCombo.Object.Text <> "Disabled"
    Next i
End With
End Sub
    Merci! C'est génial. Juste pour info, ma copine du projet contraintes fondamentalement juste utilisé ActiveSheet.OLEObjects("name_of_target_control") pour obtenir le contro et suppose que c'est la bonne. -_-

    OriginalL'auteur Doug Glancy

  2. 3

    VBA

    Edit: (Changement de macro VBA)

    Sub Macro1()
'
' GetControl By Name
'
    If value_of_a = "disable" Then
        GetControl(ComboBox1.Name + "_status").Enabled = False
    End If

End Sub

Function GetControl(nameOfControl As String) As OLEObject
    Dim ctrl As OLEObject

    For Each ctrl In ActiveSheet.OLEObjects
        If ctrl.Name = nameOfControl Then
            Set GetControl = ctrl
        End If
    Next ctrl
End Function

    VB.Net

    Code pour VB.Net si quelqu'un la veut pour cette raison:

    Sub Main()
    If value_of_a = "disable" Then 
        GetControl(ComboBox_1.Name + "_status").Enabled = False
    End If
End Sub

Function GetControl(nameOfControl As String) As Control
    For Each ctrl In Me.Controls
        If ctrl.Name = nameOfControl Then
            Return ctrl
        End If
    Next ctrl

    Return Nothing
End Function
    VBA n'utilise pas Return - le VBA équivalent serait Set GetControl = ctrl
    Ahh ok merci, je vais modifier ma réponse. Désolé combat.
    Merci pour la réponse. Je trouve que les deux réponses en grande partie ce que je voulais faire, c'est juste que Doug est un miroir de mon scénario de plus près.
    Oui c'est très bien. Bonne chance!

    OriginalL'auteur Nate-Wilkins