Comment ouvrir un autre Formulaire à partir de la Forme actuelle?

Dans votre formulaire de connexion, je suppose que vous effectuez votre validation à l'intérieur de la Click méthode d'événements pour un contrôle de bouton. Donc, vous auriez quelque chose comme:

Private Sub btnLogin_Click()
    If ValidatePassword(txtPassword.Text) Then
        ' The password is correct, so show the main form and close the login form
        MainForm.Show
        Unload Me
    Else
        ' The password is incorrect, so leave this form on screen
        MsgBox "Invalid password entered!", vbError
        txtPassword.SetFocus
    End If
End Sub

Les deux caractéristiques intéressantes de ce code sont:

1. La Show méthode, qui vous appel sur la forme de l'objet que vous souhaitez afficher.
   
   Dans ce cas, il sera probablement de votre formulaire principal—remplacer MainForm avec tout ce qu'elle est appelée.

2. La Unload déclaration, qui se ferme et détruit le formulaire indiqué.
   
   Dans ce cas, Me désigne le formulaire de connexion depuis que vous avez fini avec elle.

Mon approche est d'éviter d'essayer d'ouvrir un Formulaire d'ouverture de session comme la première Forme.

Au lieu de laisser le Formulaire principal seront les premiers, et dans sa Charge Spectacle événement de votre Formulaire d'ouverture de session en tant que boîte de dialogue modale. Cela peut être fait en révélant la principale Forme d'abord par faire un Spectacle sur elle. Exemple basé sur le modèle standard "de Journal dans la boîte de Dialogue" Formulaire avec quelques modifications de code:

frmMain.frm

Option Explicit

Private Sub Form_Load()
    Dim Control As Control

    Show
    frmLogin.Show vbModal, Me
    With frmLogin
        txtSuccess.Text = CStr(.LoginSucceeded)
        If .LoginSucceeded Then
            'Proceed normally, perhaps after capturing
            'the User Name, etc.
            txtUserName.Text = .User
            txtPassword.Text = .Password
        Else
            'Do "Unload Me" or disable all controls
            'as shown here, etc.
            For Each Control In Controls
                On Error Resume Next
                Control.Enabled = False
                On Error GoTo 0
            Next
        End If
    End With
    Unload frmLogin
End Sub

frmLogin.frm

Option Explicit

Public LoginSucceeded As Boolean
Public User As String
Public Password As String

Private Sub cmdCancel_Click()
    LoginSucceeded = False
    Hide
End Sub

Private Sub cmdOK_Click()
    'Check for correct password, hard-coded here.
    If txtPassword.Text = "password" Then
        LoginSucceeded = True
        User = txtUserName.Text
        Password = txtPassword.Text
        Hide
    Else
        MsgBox "Invalid Password, try again!", , "Login"
        With txtPassword
            .SetFocus
            .SelStart = 0
            .SelLength = Len(.Text)
        End With
    End If
End Sub