comment prévenir l'Image.FromFile() la méthode de verrouiller le fichier

Lorsque vous utilisez le Image.FromFile(strFileName) méthode pour créer le Image, la méthode verrouille le fichier jusqu'à ce que vous relâchez le Image. La raison exacte est expliqué ci-dessous. Et c'est pourquoi vous ne pouvez pas avoir accès à plus d'une seule fois pour le même fichier image avec cette méthode.

Au contraire:

• utiliser le Image.FromStream(stream) méthode.
• que vous utilisez avec un Nouveau FileStream ou un MemoryStream que vous créer à partir du fichier image.

Possibles de la mise en œuvre d'une coutume SafeImageFromFile méthode qui n'a pas de verrouiller le fichier image:

Public Shared Function SafeImageFromFile(path As String) As Image
    Using fs As New FileStream(path, FileMode.Open, FileAccess.Read)
        Dim img = Image.FromStream(fs)
        Return img
    End using
End Function

Ou

Public Shared Function SafeImageFromFile(path As String) As Image
    Dim bytes = File.ReadAllBytes(path)
    Using ms As New MemoryStream(bytes)
        Dim img = Image.FromStream(ms)
        Return img
    End Using
End Function

Utilisation

If strFileName.ToLower.EndsWith(".jpg") Then
    Dim inImg As Image = SafeImageFromFile(strFileName)
    Dim index as integer = DataGridView4.Rows.Add()
    DataGridView4.Rows(index).Cells(0).Value = inImg
End If

Remarque importante

Ici, j'ai créer le FileStream ou un MemoryStream à l'aide d'un Using déclaration assurez-vous que le flux est libéré. Il fonctionne très bien sur mon système et il semble que cela fonctionne pour vous aussi, si MSDN dit à propos de Image.FromStream(stream) méthode:

Vous devez garder le flux ouvert pour la durée de vie de l'Image.

La raison de cette phrase est expliquer ici: KB814675 Bitmap et une Image de constructeur dépendances

GDI+, et donc le Système.Le dessin de l'espace de noms, peut reporter la
le décodage de l'image raw bits jusqu'à ce que les bits sont requis par l'image.
En outre, même une fois que l'image a été décodé, GDI+ peut
déterminer qu'il est plus efficace de le jeter à la mémoire d'un grand
Bitmap et de re-décoder plus tard. Par conséquent, GDI+ doit avoir accès à l'
source de bits pour l'image de la vie de l'image ou de l'Image
objet.

Pour conserver l'accès à la source de bits, GDI+ verrouille n'importe quel fichier source, et
les forces de l'application afin de maintenir la vie de tous les cours d'eau de source, pour
la durée de vie de l'image ou de l'objet Image.

Afin de connaître le code ci-dessus pourrait générer GDIexceptions parce que de libérer le flux à l'aide Using. Il pourrait se produire lorsque vous enregistrez l'image à partir du fichier ou lors de la création de l'image. À partir de ce fil Chargement d'une image à partir d'un flux sans maintenir le flux ouvert et Hans Passant de commentaire elles correction de plusieurs problèmes avec indexé formats de pixel dans la version Vista de gdiplus.dll., il ne se produit que sur XP.

Pour éviter cela, vous devez garder le flux ouvert. Les méthodes serait:

Public Shared Function SafeImageFromFile(path As String) As Image
    Dim fs As New FileStream(path, FileMode.Open, FileAccess.Read)
    Dim img = Image.FromStream(fs)
    Return img
End Function

Ou

Public Shared Function SafeImageFromFile(path As String) As Image
    Dim bytes = File.ReadAllBytes(path)
    Dim ms = New MemoryStream(bytes)
    Dim img = Image.FromStream(ms)
    Return img
End Function

Mais ces derniers ont des méthodes de certains inconvénient, comme ne pas libérer le flux de données (problème de mémoire) et ils violent la règle CA2000 Disposer les objets avant de perdre portée .

La base de connaissances l'article donne quelques solutions de contournement:

Créer une Image Indexée

Cette approche exige que la nouvelle image dans un non-indexé pixel
format (plus de 8 bits par pixel), même si l'image d'origine a été en
indexé format. Cette solution utilise les Graphiques.DrawImage()
méthode pour copier l'image dans un nouvel objet Bitmap:

1. Construire l'image d'origine à partir du flux, de la mémoire, ou à partir du fichier.
2. Créer une nouvelle image de la même taille, avec un format de pixel de plus de 8 bits par pixel (BPP).
3. Utiliser le Graphique.FromImage() méthode pour obtenir un objet Graphique pour la deuxième Image.
4. Utiliser Des Graphiques.DrawImage() pour tracer la première image Bitmap sur la deuxième Image.
5. Utiliser Des Graphiques.Dispose() de disposer de la carte Graphique.
6. L'Utilisation De Bitmap.Dispose() de disposer de la première Image.

Créer une Image Indexée

Cette solution crée un objet Bitmap dans un indexée format:

1. Construire l'image d'origine à partir du flux, de la mémoire, ou à partir du fichier.
2. Créer une nouvelle image avec la même taille et le format de pixel que le premier Bitmap.
3. Du Bitmap.LockBits() la méthode de verrouillage de l'ensemble de l'image pour les deux objets Bitmap dans leur propre format de pixel.
4. Utiliser le Maréchal.La fonction de copie ou d'une autre mémoire, fonction de copie pour copier les bits d'image à partir de la première image Bitmap à la deuxième Image.
5. Du Bitmap.UnlockBits() la méthode pour débloquer les objets Bitmap.
   L'Utilisation De Bitmap.Dispose() de disposer de la première Image.

Ici est une mise en œuvre de la Non-Indexé la création de l'Image, fondée sur l'article et cette réponse https://stackoverflow.com/a/7972963/2387010 Votre meilleur pari est de créer un pixel-réplique parfaite de l'image, si YMMV (avec certains types d'images, il peut être plus qu'une image, ou vous pouvez copier les données de palette). Mais pour la plupart des images, cela fonctionne:

Private Shared Function SafeImageFromFile(path As String) As Bitmap
    Dim img As Bitmap = Nothing
    Using fs As New FileStream(path, FileMode.Open, FileAccess.Read)
        Using b As New Bitmap(fs)
            img = New Bitmap(b.Width, b.Height, b.PixelFormat)
            Using g As Graphics = Graphics.FromImage(img)
                g.DrawImage(b, Point.Empty)
                g.Flush()
            End Using
        End Using
    End Using
    Return img
End Function

---

Quelqu'un a indiqué que ce qui est important, c'est que le FileStream est ouvert en mode lecture (FileAccess.Read).

Vrai, mais il fait plus de sens si vous n'utilisez pas Using déclaration et si vous ne relâchez pas le flux, ou en multi-threads contexte: FileAccess.Write est inapproprié, et FileAccess.ReadWrite n'est pas nécessaire, mais ouvrir le flux avec FileAccess.Read mode ne l'empêchera pas d'avoir un IO.Exception si un autre programme (ou la vôtre, en multi-threads contexte) a ouvert le fichier avec un autre mode de FileAccess.Read.

---

Si vous voulez être en mesure pour afficher l'image et en même temps être en mesure d'enregistrer les données dans le fichier, Puisque vous n'avez pas de verrouiller le fichier avec ces méthodes, vous devriez être en mesure de sauver l'image (supprimer/remplacer le fichier précédent) à l'aide de la Image.Save méthode.

OriginalL'auteur Chris

Cela fonctionne sans problème, a couru 4189 images 3400x2200 (deux fois) sans problème, cela déplace le filestream à l'extérieur de la fonction et de la ré-utilise. Im de la fermeture du fichier à libérer le verrou d'écriture. Im pointant un picturebox à cette image dans une boucle pour mon test.

Private fsIMG As FileStream
Private Function SafeImageFromFile(FilePath As String) As Image
    'Ref:  http://stackoverflow.com/questions/18250848/how-to-prevent-the-image-fromfile-method-to-lock-the-file
    Dim img As Bitmap = Nothing
    fsIMG = New FileStream(FilePath, FileMode.Open, FileAccess.Read)
    Using b As New Bitmap(fsIMG)
        img = New Bitmap(b.Width, b.Height, b.PixelFormat)
        Using g As Graphics = Graphics.FromImage(img)
            g.DrawImage(b, Point.Empty)
            g.Flush()
        End Using
    End Using
    fsIMG.Close()
    Return img
End Function

OriginalL'auteur Alan

J'ai rencontré la même situation et a utilisé ce code:

' Create memory stream from file
Dim ms As New MemoryStream()
' Open image file
Using fs As New FileStream(.FileName, FileMode.Open, FileAccess.Read)
    ' Save to memory stream
    fs.CopyTo(ms)
End Using

' Create image from the file's copy in memory
Dim img = Image.FromStream(ms)

Je n'ai pas disposer de flux de mémoire, car elle permet d'enregistrer l'image plus tard, en utilisant exactement le même codage que le fichier d'origine, à l'aide de ce code:

img.Save(someOtherStream, img.RawFormat)

OriginalL'auteur Jean-Xavier Bardant