Comment procédez-vous pour l'exécution d'une tâche de l'utilisateur à l'ouverture de session à l'aide de vbs sans les droits d'admin?

Probablement Schtasks.exe - à Partir de la documentation de Microsoft

Permissions for schtasks

    You must have permission to run the command. Any user can schedule
    a task on the local computer, and they can view and change the tasks
    that they scheduled. Members of the Administrators group can schedule,
    view, and change all tasks on the local computer.

Et l'un des paramètres (/sc onlogon) permettent de définir une tâche qui sera exécutée à l'ouverture de session.

Semble être la réponse, MAIS je n'ai pas essayé.

MODIFIER

Depuis schtasks s'est avéré ne pas être la réponse, j'ai pris le code d'origine de Microsoft et de s'adapter au travail (je l'espère, fonctionne pour moi)

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when a user logs on.
'---------------------------------------------------------
' A constant that specifies a logon trigger.
const TriggerTypeLogon = 9
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   
const TASK_LOGON_INTERACTIVE_TOKEN = 3
'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()
'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")
' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 
'********************************************************
' Define information about the task.
' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Task will execute Notepad when a " & _
"specified user logs on."
regInfo.Author = "Author Name"
' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True
'********************************************************
' Create a logon trigger.
Dim triggers
Set triggers = taskDefinition.Triggers
Dim trigger
Set trigger = triggers.Create(TriggerTypeLogon)
' Trigger variables that define when the trigger is active.
Dim startTime, endTime
startTime = "2013-10-22T10:49:02"
endTime = "2013-10-30T10:52:02"
WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime
trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    ' Five minutes
trigger.Id = "LogonTriggerId"
trigger.UserId = "MyDomainOrComputer\testUser"   ' Must be a valid user account   
'***********************************************************
' Create the action for the task to execute.
' Add an action to the task. The action executes notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"
WScript.Echo "Task definition created. About to submit the task..."
'***********************************************************
' Deal with the password problems
taskDefinition.Principal.UserId = "MyDomainOrComputer\testUser"
taskDefinition.Principal.LogonType = TASK_LOGON_INTERACTIVE_TOKEN
'***********************************************************
' Register (create) the task.
const createOrUpdateTask = 6
call rootFolder.RegisterTaskDefinition( _
"Test Logon Trigger", taskDefinition, createOrUpdateTask, _
Empty , Empty, TASK_LOGON_INTERACTIVE_TOKEN)
WScript.Echo "Task submitted."

Changé le RegisterTaskDefinition appel à ne pas transmettre des informations d'identification de la tâche, et configuré del Principal les propriétés de l'objet de la taskDefinition

Tâche enregistrée avec le non d'utilisateur admin, sans invite de mot de passe.

OriginalL'auteur MC ND