Comment puis-je ajouter des lignes en haut et en bas d'un fichier en Perl?

De perlfaq5's réponse à Comment puis-je modifier, supprimer ou insérer une ligne dans un fichier, ou d'ajouter au début du fichier?

---

Comment puis-je modifier, supprimer ou insérer une ligne dans un fichier, ou d'ajouter au début du fichier?

(contribution de brian d foy)

L'idée de base de l'insertion, la modification ou la suppression d'une ligne d'un fichier texte implique la lecture et l'impression du fichier à l'endroit que vous voulez faire le changement, le changement, puis de la lecture et de l'impression, le reste du fichier. Perl n'est pas de fournir un accès aléatoire aux lignes (surtout depuis l'entrée d'enregistrement séparateur, $/, est sujette au changement), bien que des modules tels que le Tie::File peut faux.

Un programme en Perl pour faire ces tâches prend la forme de base de l'ouverture d'un fichier, d'impression de ses lignes, puis de la fermeture du fichier:

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

while( <$in> )
    {
    print $out $_;
    }

close $out;

À l'intérieur de cette forme de base, ajouter les pièces que vous avez besoin d'insérer, de modifier ou de supprimer des lignes.

À ajouter des lignes au début, l'impression de ces lignes avant d'entrer dans la boucle qui imprime les lignes existantes.

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n"; # <--- HERE'S THE MAGIC

while( <$in> )
    {
    print $out $_;
    }

close $out;

De changer les lignes, insérer le code à modifier les lignes à l'intérieur de la boucle while. Dans ce cas, le code est tous mis en minuscule versions de "perl" et majuscules. Le phénomène se produit pour chaque ligne, alors assurez-vous que vous êtes censé faire que sur chaque ligne!

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n";

while( <$in> )
    {
    s/\b(perl)\b/Perl/g;
    print $out $_;
    }

close $out;

Changer seulement une ligne en particulier, la ligne de saisie du numéro, $., est utile. D'abord de lire et d'imprimer les lignes jusqu'à celui que vous voulez modifier. Ensuite, lisez la seule ligne que vous voulez modifier, de le modifier, et de l'imprimer. Après cela, lire le reste de l'lignes et imprimer ces:

while( <$in> )   # print the lines before the change
    {
    print $out $_;
    last if $. == 4; # line number before change
    }

my $line = <$in>;
$line =~ s/\b(perl)\b/Perl/g;
print $out $line;

while( <$in> )   # print the rest of the lines
    {
    print $out $_;
    }

À sauter des lignes, utilisez la boucle de contrôle. La prochaine dans cet exemple, ignore les lignes de commentaires, et le dernier s'arrête tous les traitements une fois qu'elle rencontre soit FIN ou DONNÉES.

while( <$in> )
    {
    next if /^\s+#/;             # skip comment lines
    last if /^__(END|DATA)__$/;  # stop at end of code marker
    print $out $_;
    }

Faire le même genre de chose pour supprimer une ligne en cliquant sur suivant pour sauter les lignes que vous ne voulez pas afficher dans la sortie. Cet exemple saute à chaque cinquième ligne:

while( <$in> )
    {
    next unless $. % 5;
    print $out $_;
    }

Si, pour une raison étrange, vous voulez vraiment voir l'ensemble du dossier à la fois plutôt que de les traiter ligne par ligne, vous pouvez slurp (aussi longtemps que vous pouvez équiper toute chose dans la mémoire!):

open my $in,  '<',  $file      or die "Can't read old file: $!"
open my $out, '>', "$file.new" or die "Can't write new file: $!";

my @lines = do { local $/; <$in> }; # slurp!

    # do your magic here

print $out @lines;

Des Modules tels que des Fichiers::Slurp et Tie::File pouvons aussi vous aider. Si vous le pouvez, toutefois, éviter de lire l'ensemble du dossier à la fois. Perl ne vous donnera pas de mémoire pour le système d'exploitation jusqu'à ce que le processus se termine.

Vous pouvez également utiliser Perl one-liners de modifier un fichier en place. Les modifications suivantes à tous les 'Fred' à 'Barney' dans inFile.txt en écrasant le fichier avec le nouveau contenu. Avec le commutateur-p, Perl enroule une boucle while autour du code que vous spécifiez avec-e, et je tourne sur la modification sur place. La ligne actuelle est dans $. Avec -p, Perl imprime automatiquement la valeur de $ à la fin de la boucle. Voir perlrun pour plus de détails.

perl -pi -e 's/Fred/Barney/' inFile.txt

De faire une sauvegarde de inFile.txt, donnez -je une extension de fichier à ajouter:

perl -pi.bak -e 's/Fred/Barney/' inFile.txt

De changer seulement la cinquième ligne, vous pouvez ajouter un test de vérification de $., la ligne de saisie, puis seulement effectuer l'opération lorsque le test passe:

perl -pi -e 's/Fred/Barney/if $. == 5' inFile.txt

Pour ajouter des lignes avant une certaine ligne, vous pouvez ajouter une ligne (ou des lignes!) avant de Perl imprime $_:

perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt

Vous pouvez même ajouter une ligne au début d'un fichier, depuis la ligne courante imprime à la fin de la boucle:

perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt

Pour insérer une ligne après on déjà dans le fichier, utilisez le commutateur-n. C'est comme -p sauf qu'il n'a pas print $_ à la fin de la boucle, de sorte que vous avez à faire vous-même. Dans ce cas, print $_ abord, puis imprimer la ligne que vous souhaitez ajouter.

perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt

À supprimer les lignes, d'imprimer uniquement ceux que vous souhaitez.

perl -ni -e 'print unless /d/' inFile.txt

    ... or ...

perl -pi -e 'next unless /d/' inFile.txt

OriginalL'auteur brian d foy

Utilisation Tie::File qui vous donne accès à des lignes d'un fichier du disque par l'intermédiaire d'un Perl tableau. Il est livré avec la distribution standard.

Exemple à partir de la documentation:

use Tie::File;

tie @array, 'Tie::File', filename or die ...;
$array[13] = 'blah';     # line 13 of the file is now 'blah'
print $array[42];        # display line 42 of the file

$n_recs = @array;        # how many records are in the file?
$#array -= 2;            # chop two records off the end

for (@array) {
    s/PERL/Perl/g;         # Replace PERL with Perl everywhere in the file
}

# These are just like regular push, pop, unshift, shift, and splice
# Except that they modify the file in the way you would expect
push @array, new recs...;
my $r1 = pop @array;
unshift @array, new recs...;
my $r2 = shift @array;
@old_recs = splice @array, 3, 7, new recs...;

untie @array;            # all finished

OriginalL'auteur zakovyrya

Il y a de nombreuses façons que vous pouvez le faire, par exemple avec un simple script shell la façon @Pax mentionné. Vous pouvez également remplacer votre tableau et une boucle avec un join():

open(DATA, "</usr/old") || die "cant open old\n"; #file to which line has to be added
my $body=join("", <DATA>);
open (FILE, ">/usr/new") || die "cant open new\n"; #file after stuff has been added
print FILE "9   431\n";
print(FILE $body);
print FILE "(3,((((1,4),(7,6)),(2,8)),5),9)";
close(FILE);

OriginalL'auteur sunny256

vous pouvez le faire

open(FILE,">", $file) or die "cannot open $file: $!";
print FILE "add line to top\n";
while (<FILE>) { print $_ ."\n";}
close(FILE);
print FILE "add line to bottom\n";

sur la ligne de commande

perl myscript.pl > newfile

OriginalL'auteur ghostdog74

Comme Pax dit, il n'est pas intégré dans la façon de le faire. Mais si vous voulez le faire avec une seule ligne de commande perl à partir de votre shell, vous pouvez utiliser:

perl -ple 'print "Top line" if $. == 1; if (eof) { print "$_\nBottom line";  exit; }' yourfile.txt > newfile.txt

OriginalL'auteur Nikhil