Comment puis-je analyser les dates et les convertir fuseaux horaires en Perl?

J'ai utilisé le localtime fonction en Perl pour obtenir la date et l'heure actuelles, mais besoin d'analyser dans les dates. J'ai un GMT date dans le format suivant: "20090103 12:00" je tiens à analyser dans un objet date, je peux travailler avec et puis convertir le GMT, heure/date dans mon fuseau horaire actuel qui est actuellement en Heure normale de l'est. Donc, je voudrais convertir "20090103 12:00" à "20090103 7:00" aucune info sur comment faire ce serait grandement apprécié.

InformationsquelleAutor Jared | 2009-01-04
  1. 48

    Parce que le Perl construit en date de la manipulation des interfaces sont un peu maladroit, et vous vous retrouvez à passer une demi-douzaine de variables, la meilleure façon est d'utiliser DateTime ou Heure: À La Pièce. DateTime est la chantent, dansent Perl objet date, et vous aurez probablement souhaitez éventuellement utiliser, mais le Temps: la Pièce est plus simple et parfaitement adaptée à cette tâche, a l'avantage de l'expédition avec 5.10 et la technique de base est le même pour les deux.

    Voici la simple, flexible en utilisant le Temps: à la Pièce et strptime.

    #!/usr/bin/perl

use 5.10.0;

use strict;
use warnings;

use Time::Piece;

# Read the date from the command line.
my $date = shift;

# Parse the date using strptime(), which uses strftime() formats.
my $time = Time::Piece->strptime($date, "%Y%m%d %H:%M");

# Here it is, parsed but still in GMT.
say $time->datetime;

# Create a localtime object for the same timestamp.
$time = localtime($time->epoch);

# And here it is localized.
say $time->datetime;

    Et voici l'en-main, pour le contraste.

    Puisque le format est fixe, une expression régulière fera l'amende juste, mais si le changement de format, vous aurez à modifier la regex.

    my($year, $mon, $day, $hour, $min) = 
    $date =~ /^(\d{4}) (\d{2}) (\d{2})\ (\d{2}):(\d{2})$/x;

    Puis de le convertir à l'époque Unix temps (secondes depuis le 1er janvier 1970)

    use Time::Local;
# Note that all the internal Perl date handling functions take month
# from 0 and the year starting at 1900.  Blame C (or blame Larry for
# parroting C).
my $time = timegm(0, $min, $hour, $day, $mon - 1, $year - 1900);

    Et puis retour à votre heure locale.

    (undef, $min, $hour, $day, $mon, $year) = localtime($time);

my $local_date = sprintf "%d%02d%02d %02d:%02d\n",
    $year + 1900, $mon + 1, $day, $hour, $min;
    • Même en roulant propre, on peut use POSIX qw(strftime) sur Unix et les systèmes Windows à partir d'au moins Perl 5.6.0 de l'avant. Qui permet au final de "rouler" pour devenir à la fois plus court et plus facile à gérer: my $local_date = strftime "%Y%m%d %H:%M\n", localtime($time);.
    • $temps->localtime->tzoffset AFAICT retourne l'offset pour l'heure, pas le temps donné.
    • Oui, et c'est ok sauf à vouloir s'inquiéter historique des modifications de fuseau horaire, dont je ne suis certainement pas. L'heure d'été peut être important.
    • Il semble DateTime module n'a pas de date de l'analyse, dans son répertoire. Voici la citation de pod: This module does not parse dates! Instead, take a look at the various DateTime::Format::* modules on CPAN
    • Oui, cela fait partie de sa conception. Plutôt que de l'expédition avec une myriade de formateurs ils sont des plugins. Voir Formateurs et Stringification dans les docs. L'inconvénient est de type DateTime n'est pas à même de fournir la plus simple mise en forme de la boîte. L'avantage de la il ya beaucoup de formateurs.
    • Vous avez manqué le point ysth a été levée. Il n'a rien à voir avec les changements historiques. ysth souligné le décalage est différent de dates différentes. À new york, c'est -5 pour les dates en hiver et -4 pour les dates en hiver. Votre code a appliqué le mauvais offset parce qu'il a utilisé le décalage de la date actuelle à la place du décalage de la date en cours de modification. Preuve. Fixe.
    • Fixe. . .

    InformationsquelleAutor Schwern
  2. 21

    Voici un exemple, en utilisant DateTime et ses strptime module de format.

    use DateTime;
use DateTime::Format::Strptime;

my $val = "20090103 12:00";

my $format = new DateTime::Format::Strptime(
                pattern => '%Y%m%d %H:%M',
                time_zone => 'GMT',
                );

my $date = $format->parse_datetime($val);

print $date->strftime("%Y%m%d %H:%M %Z")."\n";

$date->set_time_zone("America/New_York");  # or "local"

print $date->strftime("%Y%m%d %H:%M %Z")."\n";

$ perl dates.pl
20090103 12:00 UTC
20090103 07:00 EST

    Si vous aviez voulu analyser localtime, voici comment vous pouvez le faire 🙂 

    use DateTime;

my @time = (localtime);

my $date = DateTime->new(year => $time[5]+1900, month => $time[4]+1,
                day => $time[3], hour => $time[2], minute => $time[1],
                second => $time[0], time_zone => "America/New_York");

print $date->strftime("%F %r %Z")."\n";

$date->set_time_zone("Europe/Prague");

print $date->strftime("%F %r %Z")."\n";
    • Et ce qui est mal à cela?
    • Vous êtes absent de l'analyse de la partie.
    • Oh, c'est vrai. J'ai commis l'erreur de supposer qu'il voulait utiliser localtime de sortie.
    InformationsquelleAutor Vinko Vrsalovic
  3. 5

    C'est ce que je ferais ...

    #!/usr/bin/perl
use Date::Parse;
use POSIX;

$orig = "20090103 12:00";

print strftime("%Y%m%d %R", localtime(str2time($orig, 'GMT')));

    Vous pouvez également utiliser Time::ParseDate et parsedate() au lieu de Date::Parse et str2time(). Notez que le standard de facto de l'atm. semble être DateTime (mais vous ne le souhaitez pas utiliser la syntaxe OO juste pour convertir un timestamp).

    • Celui-ci est FTW.
    InformationsquelleAutor mjy
  4. 4

    Faites votre choix:

    Il ya un zillion d'autres, sans doute, mais ils sont probablement les prétendants.

    • Date::Calc eu un peu d'activité en 2009.
    • Mais je ne pense pas que l'activité avait eu lieu le 4 janvier 2009, lorsque j'ai écrit ce commentaire. Toutefois, il est bon de savoir qu'il est maintenu. Bonne stabilité de modules n'ont pas nécessairement besoin de beaucoup de travail que Perl progresse.
    InformationsquelleAutor Jonathan Leffler
  5. -2
    use strict;
use warnings;
my ($sec,$min,$hour,$day,$month,$year)=localtime();
$year+=1900;
$month+=1;
$today_time = sprintf("%02d-%02d-%04d %02d:%02d:%02d",$day,$month,$year,$hour,$min,$sec);
print $today_time;
    • Ce code affiche seulement l'heure locale actuelle. Il ne répond pas à la question.
    InformationsquelleAutor saiprathapreddy.obula