Comment puis-je auto-élever mon fichier batch, de sorte qu'il demande de l'UAC des droits d'administrateur, si nécessaire?

Je veux que mon fichier de commandes pour exécuter uniquement élevées. Si pas élevé, la possibilité pour l'utilisateur de relancer lot élevé.

Je suis en train d'écrire un fichier de commandes pour définir une variable système, copiez les deux fichiers dans un Fichiers de Programme emplacement, et de commencer un programme d'installation du pilote. Si un Windows 7/Windows utilisateur de Vista (Contrôle de compte d'utilisateur permis, et même si ils sont un admin local) s'exécute sans un clic droit et en sélectionnant "Exécuter en tant qu'Administrateur", ils seront "Accès Refusé" copier les deux fichiers et d'écriture de la variable système.

Je voudrais utiliser une commande pour redémarrer automatiquement le lot élevée si l'utilisateur est en fait un administrateur. Sinon, si ils ne sont pas un administrateur, je veux leur dire qu'ils ont besoin des privilèges d'administrateur pour exécuter le fichier de commandes. Je suis en utilisant xcopy pour copier les fichiers et REG ADD d'écrire la variable système. Je suis l'aide de ces commandes pour faire face à d'éventuelles Windows XP machines. J'ai trouvé les mêmes questions sur ce sujet, mais rien qui traite de la relance d'un fichier de commandes élevé.

  • Découvrez ce que j'ai posté - vous n'avez besoin d'aucun outil externe, le script vérifie automatiquement les droits d'admin et de l'auto-élève lui-même si nécessaire.
  • Veuillez prendre en considération si Matt réponse serait la cochées un? Semble donc, pour moi.
  • double possible de Comment demander un accès Administrateur à l'intérieur d'un fichier de commandes
  • Veuillez considérer la Windows 10 conseils dans la section des commentaires de la script batch j'ai posté.
  • Cmd: @powershell Start-Process cmd -Verb runas. À partir de Powershell il suffit de déposer @powershell. Cela commence cmd avec des droits élevés.
  • Ou essayez pure façon dont windows à l'aide de schtasks: stackoverflow.com/questions/19098101/...

InformationsquelleAutor PDixon724 | 2011-08-12
  1. 19

    Vous pouvez avoir l'appel du script lui-même avec psexec's -h option pour exécuter élevée.

    Je ne suis pas sûr de savoir comment vous permettrait de détecter si il est déjà en cours d'exécution élevé ou pas... peut-être re-essayer avec élévation de la prems seulement si il y a une erreur d'Accès Refusé?

    Ou, vous pouvez simplement avoir les commandes pour la xcopy et reg.exe toujours être exécuté avec psexec -h, mais il serait gênant pour l'utilisateur final si ils ont besoin pour entrer son mot de passe à chaque fois (ou d'insécurité si vous avez inclus le mot de passe dans le script)...

    • Merci pour la réponse. Malheureusement, je ne pense pas que je peux utiliser quoi que ce soit à l'extérieur de stock Windows Vista/7 outils, car ce sera de sortir pour les clients à l'extérieur de mon bureau. Je ne pense pas que je peux légalement distribuer PSExec.
    • Ouais, je pense que vous avez raison à ce sujet-même si PSExec est maintenant un outil de Microsoft (depuis qu'ils ont racheté le Sysinternals les gars!) le CLUF n'interdire la diffusion 🙁
    • Je pense que mes options sont assez limitées. Si je savais comment le code en VB, je pouvais faire un exe avec un admin manifeste, mais je ne sais même pas par où commencer. Je crois que je vais l'avertir au début du traitement à exécuter en tant qu'administrateur si ils exécutent Windows Vista/7. Merci à tous.
    • Un autre outil de la 3e partie qui peut être librement redistribuables et facile à intégrer et à apprendre, c'est AutoIt; cette page montre comment le script demande des privilèges élevés.
    • Grâce ewall. Il semble que j'ai peut redistribuer AutoIt. Je vais aller dans cette voie. Merci encore pour l'aide!
    • psexec -h ne fonctionne pas: 'ne Pouvait pas installer PSEXESVC service: l'Accès est refusé.'. Vous devez avoir les droits d'administrateur pour exécuter psexec.

    InformationsquelleAutor ewall
  2. 302

    Il est un moyen facile, sans avoir à utiliser un outil externe - il fonctionne très bien avec Windows 7, 8, 8.1 et 10 et est rétro-compatible aussi (Windows XP n'ont pas de contrôle de compte d'utilisateur, ainsi, l'élévation n'est pas nécessaire - dans ce cas, le script continue simplement).

    Découvrez ce code (j'ai été inspiré par le code par NIronwolf posté dans le fil Fichier de commandes - "Accès Refusé" Sur Windows 7?), mais je me suis amélioré dans ma version il n'y a pas de répertoire créé et supprimé pour vérifier les privilèges d'administrateur):

    ::::::::::::::::::::::::::::::::::::::::::::
:: Elevate.cmd - Version 4
:: Automatically check & get admin rights
:: see "https://stackoverflow.com/a/12264592/1016343" for description
::::::::::::::::::::::::::::::::::::::::::::
@echo off
CLS
ECHO.
ECHO =============================
ECHO Running Admin shell
ECHO =============================
:init
setlocal DisableDelayedExpansion
set cmdInvoke=1
set winSysFolder=System32
set "batchPath=%~0"
for %%k in (%0) do set batchName=%%~nk
set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
setlocal EnableDelayedExpansion
:checkPrivileges
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )
:getPrivileges
if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
ECHO.
ECHO **************************************
ECHO Invoking UAC for Privilege Escalation
ECHO **************************************
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
ECHO args = "ELEV " >> "%vbsGetPrivileges%"
ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
ECHO Next >> "%vbsGetPrivileges%"
if '%cmdInvoke%'=='1' goto InvokeCmd 
ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
goto ExecElevation
:InvokeCmd
ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"
:ExecElevation
"%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
exit /B
:gotPrivileges
setlocal & cd /d %~dp0
if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)
::::::::::::::::::::::::::::
::START
::::::::::::::::::::::::::::
REM Run shell as admin (example) - put here code as you like
ECHO %batchName% Arguments: P1=%1 P2=%2 P3=%3 P4=%4 P5=%5 P6=%6 P7=%7 P8=%8 P9=%9
cmd /k

    Le script prend avantage du fait que NET FILE nécessite des privilèges d'administrateur et retourne errorlevel 1 si vous ne l'avez pas. L'élévation est réalisé en créant un script qui re-lance le fichier de commandes pour obtenir des privilèges. Cela permet à Windows de présenter la boîte de dialogue contrôle de compte d'utilisateur et vous demande pour le compte d'administrateur et le mot de passe.

    Je l'ai testé avec Windows 7, 8, 8.1, 10 et Windows XP, il fonctionne très bien pour tous.
    L'avantage est, après le point de départ, vous pouvez placer tout ce qui nécessite des privilèges d'administrateur système, par exemple, si vous avez l'intention de ré-installer et ré-exécuter un service Windows à des fins de débogage (suppose que mypackage.msi est un service package d'installation):

    msiexec /passive /x mypackage.msi
msiexec /passive /i mypackage.msi
net start myservice

    Sans ce privilège élévation de script, contrôle de compte d'utilisateur vous demande trois fois pour votre compte d'utilisateur administrateur et le mot de passe - maintenant vous êtes demandé qu'une seule fois au début, et seulement si nécessaire.

    Si votre script ne doit afficher un message d'erreur et la sortie s'il n'y a pas de privilèges d'administrateur au lieu de auto-élévatrices, c'est encore plus simple: Vous pouvez atteindre cet objectif en ajoutant ce qui suit au début de votre script:

    @ECHO OFF & CLS & ECHO.
NET FILE 1>NUL 2>NUL & IF ERRORLEVEL 1 (ECHO You must right-click and select &
ECHO "RUN AS ADMINISTRATOR"  to run this batch. Exiting... & ECHO. &
PAUSE & EXIT /D)
REM ... proceed here with admin rights ...

    De cette façon, l'utilisateur doit cliquer avec le bouton droit et sélectionnez "Exécuter en tant qu'administrateur". Le script va procéder après la REM déclaration s'il détecte des droits d'administrateur, sinon la sortie avec une erreur. Si vous n'avez pas besoin de l' PAUSE, suffit de le retirer.
    Important: NET FILE [...] EXIT /D) doit être sur la même ligne. Il est affiché ici en plusieurs lignes pour une meilleure lisibilité!

    Sur certaines machines, j'ai rencontré des problèmes qui sont résolus dans la nouvelle version ci-dessus déjà. L'un était dû à différents devis double manipulation, et l'autre problème était dû au fait que l'UAC est désactivé (niveau le plus bas) sur un Windows 7 de la machine, d'où le script s'appelle elle-même, encore et encore.

    J'ai fixé cette maintenant en enlevant les guillemets dans le chemin d'accès et le rajouter plus tard, et j'ai ajouté un paramètre supplémentaire qui est ajouté lorsque le script re-lance avec des droits élevés.

    Supprimer les guillemets doubles par le texte suivant (les détails sont ici):

    setlocal DisableDelayedExpansion
set "batchPath=%~0"
setlocal EnableDelayedExpansion

    Vous pouvez ensuite accéder au chemin d'accès en utilisant !batchPath!. Il ne contient pas de guillemets, de sorte qu'il est sûr de dire "!batchPath!" plus tard dans le script.

    La ligne

    if '%1'=='ELEV' (shift & goto gotPrivileges)

    vérifie si le script a déjà été appelé par le VBScript script pour but d'élever les droits, donc en évitant les interminables récurrences. Il supprime le paramètre à l'aide de shift.

    Mise à jour:

    • Pour éviter d'avoir à s'inscrire à la .vbs extension dans Windows 10, j'ai remplacé la ligne

      "%temp%\OEgetPrivileges.vbs"

      par l'

      "%SystemRoot%\System32\WScript.exe" "%temp%\OEgetPrivileges.vbs"

      dans le script ci-dessus; aussi ajouté cd /d %~dp0 comme suggéré par Stephen (réponse distincte) et par Tomáš Zato (commentaire) pour paramétrer le répertoire de script par défaut.

    • Maintenant, le script honneurs paramètres de ligne de commande passé pour elle. Grâce à jxmallet, TanisDLJ et Peter Mortensen pour des observations et des inspirations.

    • Selon Artjom B. l'astuce, je l'ai analysée et ont remplacé SHIFT par SHIFT /1, qui conserve le nom de fichier pour le %0 paramètre

    • Ajouté del "%temp%\OEgetPrivileges_%batchName%.vbs" à la :gotPrivileges section pour nettoyer (comme mlt suggéré). Ajouté %batchName% d'éviter les impacts si vous exécutez différents lots en parallèle. Notez que vous devez utiliser for pour être en mesure de profiter de l'avancée de la chaîne de fonctions, telles que %%~nk, qui extrait juste le nom de fichier.

    • Optimisé la structure de script, des améliorations (ajouté variable vbsGetPrivileges qui est maintenant référencé partout, ce qui permet de changer le chemin d'accès ou le nom du fichier facilement, seulement supprimer .vbs fichier si le lot devait être élevée)

    • Dans certains cas, une autre syntaxe d'appel a été nécessaire pour l'élévation. Si le script ne fonctionne pas, vérifiez les paramètres suivants:

      set cmdInvoke=0

      set winSysFolder=System32

      Soit modifier le 1er paramètre set cmdInvoke=1 et de vérifier si déjà cela résout le problème. Il va ajouter cmd.exe pour le script d'exécution de l'élévation.

      Ou essayer de changer le 2e paramètre de winSysFolder=Sysnative, cela peut aider (mais il est dans la plupart des cas n'est pas nécessaire) sur les systèmes 64 bits. (ADBailey a signalé ce). "Sysnative" n'est requis pour lancer les applications 64 bits 32 bits hôte de script (par exemple, Visual Studio processus de construction, ou d'un script invocation à partir d'une autre application 32 bits).

    • Pour la rendre plus claire la façon dont les paramètres sont interprétés, je suis affichant désormais comme P1=value1 P2=value2 ... P9=value9. Ceci est particulièrement utile si vous avez besoin de joindre les paramètres comme des chemins dans les guillemets, par exemple "C:\Program Files".

    Liens utiles:

    • Super réponse, bien que cela m'étonne légèrement de ce que vous avez à faire tout ça pour faire quelque chose qui est clairement nécessaire dans certains cas.
    • En effet, une commande telle que l'ÉLEVER, il manque clairement dans le Windows langue de lot.
    • C'est peut-être plus facile avec powershell qui semble être approuvés script lanaguge pour des choses plus complexes, mais je n'ai jamais pris la peine de l'apprendre pour l'instant 🙁
    • La syntaxe de powershell est complètement différent (verbe-nom de la syntaxe), mais il vous permet d'appeler .NET assemblées facilement. Mais il est un peu plus difficile à manipuler (signature des scripts, etc).
    • Serait-il fonctionner dans Windows Server 2012 ?
    • Je n'ai pas testé avec Windows Server 2012, explicitement, mais il fonctionne avec Windows 7 et 8, donc j'ai tendance à dire oui. Cependant, afin d'être sûr que vous devriez tester ça avant de l'utiliser. Mais sur un Serveur, vous êtes généralement d'exécuter des scripts sans interaction de l'utilisateur et, par conséquent, serait l'annexe de l'exécuter avec les bon droits de l'utilisateur et n'aurait pas besoin de contrôle de compte d'utilisateur de confirmation, car elle permettrait d'arrêter l'exécution de votre tâche planifiée jusqu'à ce qu'un admin types dans l'identification de l'utilisateur.
    • Mon powershell méthode: stackoverflow.com/a/25756858/821878 Pas aussi beau que d'une "ÉLÉVATION" de commande, mais il ne nécessite pas une temporaire****.vbs.
    • Ce qui est valable pour toutes les solutions proposées ici: ne fonctionne pas lorsque le script a des espaces dans son nom et vous l'appeler à partir de l'invite de commande
    • Je ne doute pas de pourquoi vous aimeriez avoir des espaces dans le nom - essayez d'utiliser le trait de soulignement (_) à la place des espaces ou d'utiliser des guillemets (") autour de chemin+nom du fichier de commandes.
    • J'ai déjà renommé l'ancien fichier bat, mais merci pour l'info de toute façon
    • Vous pouvez ajouter des cd %~dp0 avant de votre propre code. Sinon, vous trouverez que votre répertoire de travail est quelque chose comme C:\Windows\System32. Imaginez que votre script accidentellement change quelque chose y...
    • Zato: Oui, c'est correct. Notez que Stephen a déjà l'a suggéré. jetez un oeil à l'extrait de code qu'il a fourni.
    • Cela ne semble pas fonctionner avec Windows 10. Il fait bien son travail à l'intérieur de 7 et 8/8.1, mais pas 10. Il semble accrocher quelque part, après la ligne 9.
    • J'ai vérifié. Il fonctionne avec WIndows 10 en tant que bien, mais vous n'avez probablement pas remarqué que les Fenêtres de dialogue qui apparaît pour la première fois en disant: "Comment faire pour ouvrir ce fichier?" - sélectionnez "Microsoft Windows Script Host", tickmark "Toujours utiliser cette Application pour l'ouvrir .vbs fichiers" et cliquez sur OK. La prochaine fois (et de tous les temps) le lot fonctionne très bien comme il l'a fait dans Win7/8.
    • La boîte de dialogue mentionné précédemment fait la même chose que si vous tapez ftype VBSFile="%SystemRoot%\System32\WScript.exe" "%1" %* et puis assoc .vbs=VBSFile dans un admin fenêtre de la console. Il enregistre la .vbs extension de l'utiliser avec Windows Script Host - apparemment Windows 10 n'a pas cette association tout est plus par défaut, de sorte que vous avez à le faire qu'une fois.
    • Une autre façon pour les Windows 10 utilisateurs - si vous ne voulez pas modifier la valeur par défaut de l'enregistrement de la .vbs extensions comme mentionné ci - dessus, alors vous pouvez remplacer la ligne "%temp%\OEgetPrivileges.vbs" dans le script par "%SystemRoot%\System32\WScript.exe" "%temp%\OEgetPrivileges.vbs", qui ont également travaillé très bien pour moi.
    • L' .vbs extension a son association correcte. Wow, c'est étrange. J'ai frappé la touche retour après la neuvième ligne de tirages et il a fonctionné très bien. Je me demande ce que j'ai dit "oui"? Peut-être qu'il n'avait pas WSH après tout
    • Avez-vous essayé la version mise à jour du script que j'ai fourni hier? Il devrait fonctionner indépendamment de l' .vbs extension de l'enregistrement.
    • Venez d'ajouter le code modifié, fonctionne très bien!
    • Salut! Je suis la boîte de dialogue "Ce fichier n'ont pas de programme associé pour effectuer cette action" à venir à partir de la ligne où OEgetPrivileges.vbs est exécutée. Je n'ai pas modifié le script. Le vbs est créé et il est exécuté via WScript. Des idées? À L'Aide De Windows 7.
    • Je viens de tester le script de mise à jour avec Windows 7/64 bits, et sur mon PC il fonctionne très bien. Vérifier si %SystemRoot%\System32\WScript.exe est installé sur votre machine, puis vérifier mes conseils que j'ai donné plus tôt pour VitaminYes (au sujet de l'inscription via ftype et assoc). Vous devrez peut-être installer/activer Windows Scripting Host, ce qui serait inhabituel parce qu'il sort de la boîte, dans Windows 7 normalement.
    • J'ai trouvé que le message n'est pas de l'exécution du script vb, mais de l'exécution du fichier de commandes via le contrôle de compte d'utilisateur à partir de l'intérieur du script vbs. Il vient de cette ligne: UAC.ShellExecute "C:\Users\Me\Documents\script.bat", "ELEV", "", "runas", 1. Aussi, j'ai de drôles de Windows apparemment, parce que NET FILE ne donne pas une exception(oui, j'ai vérifié, je ne suis pas admin. J'ai dû modifier la case utiliser mkdir interdites répertoire.
    • Le script doit être enregistré comme .cmd, par exemple elevate.cmd. Il se peut également que votre installation de Windows ont des problèmes et a besoin d'un rafraîchissement (nouvelle installation) - j'ai testé le lot sur plusieurs Pc et trouvé aucune erreur comme vous l'avez décrit. Essayez-la sur un collègue PC pour le savoir. Je ne peux pas donner de prise en charge sur votre installation de Windows.
    • Matt: le problème était avec La stratégie de groupe(ou peu importe, je ne suis pas un expert windows) sur la machine. L'exécutant sur windows propre fonctionne.
    • Merci de me laisser savoir. Oui, il est possible que certaines fonctions sont bloquées par des stratégies sur un PC. Un PC propre ou installation VM est toujours une bonne idée pour la comparaison. @NeplatnyUdaj
    • Pouvez-vous vérifier s'il y a une part de vérité derrière cette rejeté edition sur votre réponse?
    • B.: Oui, il y a un problème, mais un peu différent. Ne pas retirer la SHIFT est la solution, mais en ajoutant un /1 paramètre à la SHIFT de commande (voir la liste à jour). Il devrait fonctionner correctement maintenant. Merci pour avoir porté à mon attention!
    • Est-il un moyen de nettoyage %TEMP% et supprimer OEgetPrivileges.vbs lors de la résiliation?
    • J'ai pensé à ça aussi, il y a plusieurs problèmes: le premier est que le fichier est verrouillé jusqu'à ce que le lot se termine, une autre est que si vous commencez un deuxième admin lot, il va interférer à moins de créer un unique temp nom. Oui c'est possible, mais complique les choses. @tlm
    • Puisque nous avons déjà des privilèges d'administrateur à un certain point, peut-être, il pourrait utile d'envisager l'ajout d'un registre RunOnce entrée en HKCU de la ruche pour supprimer le script sur la prochaine ouverture de session.
    • J'ai ajouté un nettoyage pour le script, il a été plus facile que prévu. Merci pour l'astuce!
    • est-il un moyen de ne pas avoir une fenêtre d'invite à demander de l'UAC de continuer ou d'annuler? Plan pour exécuter cette uDeploy ou shell qui doit s'exécuter en mode silencieux sans aucune demande et de l'interaction exigence.
    • Oui - ce que "invite de commande" est à venir à partir de Windows directement. Dans le panneau de configuration Windows, tapez "contrôle de compte d'utilisateur" dans le champ de recherche et appuyez sur entrée. Ouvrez ensuite "Modifier les paramètres de Contrôle de Compte d'Utilisateur" en double-cliquant dessus et en confirmant avec un compte administrateur. Une boîte de dialogue s'ouvre dans laquelle vous pouvez faire glisser un curseur sur "ne Jamais m'avertir". Confirmer avec "OK", redémarrez votre PC et de la boîte de dialogue devrait s'en aller si vous êtes connecté avec un privilégié (admin) compte. Mais notez que ce n'est pas un paramètre recommandé parce qu'il diminue la sécurité.
    • Hey, merci pour les scripts, il fonctionne très bien si je lance un fichier bat(disons A. chauve-souris) avec les codes. Mais quand j'ai essayer d'inclure A. bat B. chauve-souris et d'exécuter B. bat, puis le contrôle de compte d'utilisateur vous invite mais toujours pas obtenir d'administration de droit dans ce cas. Je suis à l'aide de "l'appel A. bat" pour inclure les scripts.
    • Les droits d'Admin n'existent que dans le contexte de l'élévation de script. Si je comprends bien, il faut les droits d'admin dans B.bat, mais que vous souhaitez utiliser A.bat juste pour élever B.bat. Si c'est le cas, appelez B.bat après la ::Start section de A.bat (c'est à dire faire le chemin inverse).
    • Merci pour les commentaires. Oui, j'ai besoin le droit d'administration de B. bat et je veux que l'utilisateur double-cliquez pour exécuter B. bat au premier abord. Dans B. chauve-souris, elle comprend l'A. chauve-souris qui a vos codes pleinement. Voici mes codes de la B. bat: <code>appel A. bat :: alors appeler mes codes personnalisés</code> Donc, juste comme A. chauve-souris est une bibliothèque et je veux B. bat l'air simple. Mais cela ne fonctionne pas pour moi.
    • Dans ce cas, le seul moyen que je vois est d'inclure l'élévation de script dans B. chauve-souris, et le code que vous avez écrit doit être ajoutée. Ou vous pouvez le placer à l'élévation de la B. chauve-souris et d'appeler la bibliothèque et de votre code à partir de là, avec deux appels, c'est à dire appel A. chauve-souris et C. chauve-souris (la simple code) de B. chauve-souris.
    • Merci Matt! Peut-être que c'est juste comme vous l'avez dit, il sort seulement dans le contexte de l'élévation de script. Je peut comprendre d'autres solution de contournement pour ce. Merci encore.
    • Si un paramètre contient des espaces, il obtient craché dans des variables, donc f.e. "te st" sera uniquement accessible par %1 et %2. Aucune idée sur comment résoudre ce problème?
    • tant pis, j'ai utilisé stackoverflow.com/a/30590134/3706972 qui est de travailler avec les espaces dans les paramètres.
    • Selon mes tests, les guillemets doubles sont passés à travers, par exemple, si vous spécifiez Elevate.cmd "1st param" "2nd param" "3rd param" ils sont transmis de cette façon, lors de l'élévation comme %1 ... %3. Si vous omettez les guillemets, ils sont interprétés comme 1st param 2nd param 3rd param, qui est %1 ... %6 à la place.
    • Merci pour cette! J'ai eu quelques difficulté à l'utiliser pour lancer une application 64 bits à partir d'un hôte 32 bits (partie d'un script de construction; Windows est une redirection vers "Program Files" pour "Program Files (x86)"). Pour le résoudre, j'ai remplacé %SystemRoot%\System32\WScript.exe avec %SystemRoot%\Sysnative\WScript.exe pour forcer l'utilisation de 64 bits WScript.
    • Vous êtes les bienvenus. Cependant, je me demandais à propos de "Sysnative" sur mon 64 bits de Windows il y a seulement C:\Windows\System32 et C:\Windows\SysWow64, mais pas C:\Windows\Sysnative. Dans les deux chemins d'accès, vous pouvez trouver Wscript.exe.
    • Ah, SysNative n'est pas un "vrai" directory, juste une caractéristique de la Redirecteur de Système de Fichier que Windows utilise pour les applications 32 bits sur 64 bits de Windows. Dans de tels cas, les demandes de c:\Windows\System32 êtes redirigé vers c:\Windows\SysWow64, tout en demandant c:\Windows\Sysnative est une manière de dire "oui, je suis d'une application 32 bits qui est consciente de l'OS 64 bits et je veux vraiment le bon System32". Vous pouvez faire un essai en cours d'exécution c:\Windows\SysWow64\cmd.exe (32-bit) et la liste des répertoires.
    • P. S. une permutation directe à Sysnative est seulement si votre (Élever.cmd) le script est toujours en cours d'exécution dans un hôte 32 bits: 64 bits de l'hôte, Sysnative ne sera pas trouvé. Si vous voulez qu'il soit flexible, soit (comme j'ai fait), vous devez ajouter un rapide "s'il existe un" état de basculer entre les Sysnative et System32. C'est une niche problème et peut-être trop pointilleux pour modifier votre fourni de réponse, mais j'ai pensé que l'information serait utile si quelqu'un d'autre a couru vers elle.
    • Merci pour l'explication, très utile! Je pense que le moyen le plus pratique est de sauver une version 64 bits de l'élévation du script, comme Elevate64.cmd pour la version 64 bits, et Elevate.cmd pour la version 32 bits. La raison en est que ce script aurait plus de dépendances à 64 bits de code et de nombreux CAS de compliquer les choses ...
    • J'ai fourni une nouvelle version du script, qui inclut un paramètre pour System32 ... cela devrait rendre la vie plus facile pour vous. Aussi, j'ai remarqué que sur certains systèmes, une 2ème modification n'est nécessaire, voir la mise à jour section dans la réponse.
    • Un excellent travail. Personnellement, j'ai fini par divergentes à partir de votre script (un peu à la fin pour répondre à mes besoins spécifiques et à faire, dans mon cas, vraiment besoin d'un script qui peut élever une nouvelle application 64 bits lors de l'exécuter à partir d'une version 32 bits ou 64 bits de l'hôte, mais je suis sûr que la plus grande souplesse d'aider les autres à sortir. Pas d'obligation, mais votre réponse à la question si elle a déclaré explicitement que "Sysnative" est seulement pour le lancement des applications 64 bits 32 bits hôte de script (par exemple, Visual Studio processus de construction, ou d'un script invocation à partir d'une autre application 32 bits).
    • Merci, j'ai ajouté votre explication de la réponse.
    • Le Elevate.cmd script se termine avec cmd /k. Cela ne crée un nouveau processus de shell et d'y rester?
    • Oui, c'est le but - pour afficher la console d'administration après l'élévation (pour la démonstration). Si vous n'avez pas besoin d'une console d'administration (simplement parce que vous voulez exécuter votre script élevée) supprimer cmd /k.
    • Quel est le but de pushd . cela semble pas très utile sans un correspondant popd. Il a également la cd /D à bord, ainsi que je comprends l'explication ici: Pushd - changer de répertoire/dossier | Windows CMD | SS64.com ...et mes observations personnelles
    • définit le répertoire courant vers le répertoire de script. Le /d paramètre est nécessaire pour s'assurer que le lecteur est également modifiées en cas de besoin, non seulement le chemin. La commande pushd . peut éventuellement être retiré, il était là depuis le début du développement. Si vous (ou quelqu'un qui a déjà enlevé et l'a testé) peut confirmer, je peux le supprimer.
    • Oui, je connais déjà la /d option pour cd, mais depuis que je suis en utilisant une combinaison de pushd (ce qui implicitement ne cd /d -- c'est en fait le but du paramètre) et popd, je n'ai pas besoin de l'appoint cd /d. Dans votre cas, ici, je suggère seulement de supprimer les inutiles & pushd .
    • Merci pour l'astuce, j'ai optimisé le script et a retiré le pushd.
    • Vous êtes les bienvenus, mais... Comment exactement avez-vous "optimiser" un 0 dans un 1? -- Je suis un peu confus. (BTW: il y a aussi une faute de frappe à gauche de mon dernier montage que j'ai fixé maintenant.)
    • Droite 🙂 , qui n'a rien à voir avec cela. Lire les commentaires dans ma réponse (à propos de "syntaxe d'appel"), là, j'ai expliqué le paramètre. Il fonctionne mieux sur mes machines avec la valeur 1, donc j'ai changé le paramètre. Certains pourraient utiliser 0 sur leur PC en fonction de leur environnement d'entreprise.
    • Je vois, merci pour l'explication plus détaillée.
    • Pourquoi "exit /B" nécessaire? Si j'exécute le lot à partir de l'invite de commande, il semble qu'il ne continue pas à ":gotPrivileges" jusqu'à ce que je REM la ligne. Lors du démarrage du lot à partir de l'explorateur, double-clic simple, il fonctionne très bien avec le "exit /B" est activé.
    • Pour obtenir des privilèges élevés, le script batch doit s'appeler elle-même (un sous-programme ne serait pas suffisante pour le contrôle de compte d'utilisateur pour être déclenchée). La commande Exit /b assure que seuls les appelés instance sort correctement après l'élévation mécanisme est appelé.

    InformationsquelleAutor Matt
  3. 32

    Comme jcoder et Matt mentionné, PowerShell, il est facile, et il pourrait même être intégré dans le script de commandes sans créer un nouveau script.

    J'ai modifié Matt script:

    :checkPrivileges 
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges 
) else ( powershell "saps -filepath %0 -verb runas" >nul 2>&1)
exit /b

    Il n'y a pas besoin de la :getPrivileges étiquette.

    • Vous avez raison, si PowerShell est installé, vous pouvez l'utiliser pour exécuter le fichier de commandes avec élévation (merci pour l'extrait de code!). Et oui, l'étiquette n'est pas nécessaire. Merci pour les conseils, ça vaut un +1 ... 🙂
    • Lorsqu'il est appelé à partir de cmd Powershell.exe n'a pas de verbe runas option. Il n'existe pas si vous êtes déjà en PowerShell.
    • J'aime vraiment cette solution fonctionne très bien pour moi. Sur Windows 8.1 je n'ai besoin de l' :gotPrivileges étiquette pour que cela fonctionne.
    • Je suis de frapper un problème si ce fichier de commandes à distance sur un chemin d'accès UNC.
    InformationsquelleAutor Ir Relevant
  4. 27

    Je suis à l'aide de Matt excellente réponse, mais je vois une différence entre mon Windows 7 et Windows 8 de systèmes d'lors de l'exécution élevée de scripts.

    Une fois que le script est élevée sur Windows 8, le répertoire courant est réglé à C:\Windows\system32. Heureusement, il est facile de contourner ce problème en changeant le répertoire courant pour le chemin d'accès du script courant:

    cd /d %~dp0

    Remarque: Utilisez cd /d à assurez-vous que la lettre de lecteur est également modifiée.

    Pour tester cela, vous pouvez copier ce qui suit dans un script. Exécuter normalement sur les deux versions pour voir le même résultat. Exécuter en tant qu'Admin et voir la différence dans Windows 8:

    @echo off
echo Current path is %cd%
echo Changing directory to the path of the current script
cd %~dp0
echo Current path is %cd%
pause
    • Bonne idée, Stephen. Ainsi, le script doit se terminer par cd %~dp0 à conserver son chemin d'accès actuel (je suppose que cela fonctionne dans Win7 ainsi, de sorte que la même commande peut être utilisée bien que seulement nécessaire pour Win8+). +1 pour cet!
    • De cette remarque a également été requis sur mon système Windows 7.
    • ou utiliser pushd %~dp0 plutôt... pourquoi? parce que popd
    InformationsquelleAutor Stephen Klancher
  5. 24

    Je faire de cette façon:

    NET SESSION
IF %ERRORLEVEL% NEQ 0 GOTO ELEVATE
GOTO ADMINTASKS
:ELEVATE
CD /d %~dp0
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute('%~nx0', '', '', 'runas', 1);close();"
EXIT
:ADMINTASKS
(Do whatever you need to do here)
EXIT

    De cette façon, c'est simple et utiliser windows uniquement les commandes par défaut.
    C'est génial si vous avez besoin de redistribuer les vous fichier de commandes.

    CD /d %~dp0 Définit le répertoire courant les fichiers du répertoire courant (si ce n'est déjà fait, quel que soit le disque le fichier est en cours, grâce à la /d option).

    %~nx0 Retourne le nom de fichier avec l'extension (Si vous n'incluez pas l'extension et il y a un exe avec le même nom sur le dossier, il va appeler le exe).

    Il ya tellement de nombreuses réponses sur ce post, je ne sais même pas si ma réponse va être vu.

    De toute façon, je trouve cela plus simple que les autres solutions proposées sur les autres réponses, j'espère que cela aide quelqu'un.

    • cd %~dp0 ne fonctionnera pas sur les lecteurs Réseau, utilisez pushd %~dp0 à la place.
    • J'aime beaucoup la simplicité de cette réponse. Et enfin une raison d'utiliser Jscript!
    • La magie! Je vous remercie beaucoup.
    • Connaissez-vous le /d option de la CD commande? (BTW: vous avez un savoureux piano photo dans votre profil)
    • Vous pouvez trouver de la documentation sur le CD de commande ici (ainsi que d'autres commandes): technet.microsoft.com/en-us/library/bb490875.aspx La /d commande modifie le lecteur actuel (ou chemin d'accès complet) avec qui vous travaillez. C'est à peu près la même chose que ne pas explicitement à l'aide de /d apparemment.
    • Je sais déjà cela, je veux juste souligner Stavm un commentaire. Vous avez un "courant" répertoire de travail sur chaque disque: le cd commande ne permet pas de changer le lecteur (même si vous l'avez explicitement inclure le lecteur au début du chemin), tandis que la saisie de la lettre de lecteur plus côlon t-il. L'option /d comprend cette modification de la commande courante.
    • Oh ok. C'est que vous l'avez mentionné, la photo de mon profil, j'ai pensé que vous me demandiez haha
    • Peut-être l'ajout de la /d interrupteur serait faire de votre réponse applicable également pour les scripts lancés à partir de clés usb et tous les disques autres que le lecteur système. (concernant l'image de profil: je suis en train de jouer du piano et de la recherche à ce clavier est plus amusant que de regarder sur mon clavier d'ordinateur.)
    • J'ai tapé un énorme répondre seulement à réaliser je mal compris vous... j'ai eu ce que tu veux dire maintenant. Je vais le modifier pour inclure le /d. Merci pal 🙂 (P. S.: le Pianiste ici aussi!)
    • J'ai essayé Stavm commentaire, et pushd n'aide pas beaucoup. Ce n'est le remplacement de la MSHTA ligne du fichier de commandes (que j'ai placé entre pushd %~dp0% et popd) avec ces 3 lignes: SET DPZERO=%~dp0% et SET NXZERO=%~nx0% et (le reste de ce, jusqu'à la guillemet, est une longue ligne) MSHTA "javascript: var oShellApp = new ActiveXObject('Shell.Application'); var oWSH = new ActiveXObject('WScript.Shell'); oShellApp.ShellExecute('CMD', '/C ' + oWSH.Environment("Process")("DPZERO") + oWSH.Environment("Process")("NXZERO"), '', 'runas', 1);close();"
    • (Mon précédent commentaire, probablement, ne fonctionne que pour les chemins sans espaces. Sinon, les guillemets s'échapper est probablement nécessaire.)
    • Cela fonctionne très bien, mais il pourrait être une bonne idée de déplacer le cd commande pour le début (cela permet de s'assurer que le chemin d'accès est également disponible à l'élévation du script - sinon, l'élévation de script ne s'exécute à partir system32). Vous devez également rediriger la commande net à nul, pour le cacher de sortie: net session >nul 2>&1
    • Drôle, mais Windows Defender détecte comme un cheval de troie et le place en quarantaine sur le lancement...

    InformationsquelleAutor Matheus Rocha
  6. 22

    Matt a une grande réponse, mais il élimine tous les arguments passés au script. Voici ma modification qui garde arguments. J'ai également incorporé Etienne correctif pour le problème de répertoire dans Windows 8.

    @ECHO OFF
setlocal EnableDelayedExpansion
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto START ) else ( goto getPrivileges ) 
:getPrivileges
if '%1'=='ELEV' ( goto START )
set "batchPath=%~f0"
set "batchArgs=ELEV"
::Add quotes to the batch path, if needed
set "script=%0"
set script=%script:"=%
IF '%0'=='!script!' ( GOTO PathQuotesDone )
set "batchPath=""%batchPath%"""
:PathQuotesDone
::Add quotes to the arguments, if needed.
:ArgLoop
IF '%1'=='' ( GOTO EndArgLoop ) else ( GOTO AddArg )
:AddArg
set "arg=%1"
set arg=%arg:"=%
IF '%1'=='!arg!' ( GOTO NoQuotes )
set "batchArgs=%batchArgs% "%1""
GOTO QuotesDone
:NoQuotes
set "batchArgs=%batchArgs% %1"
:QuotesDone
shift
GOTO ArgLoop
:EndArgLoop
::Create and run the vb script to elevate the batch file
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
ECHO UAC.ShellExecute "cmd", "/c ""!batchPath! !batchArgs!""", "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
"%temp%\OEgetPrivileges.vbs" 
exit /B
:START
::Remove the elevation tag and set the correct working directory
IF '%1'=='ELEV' ( shift /1 )
cd /d %~dp0
::Do your adminy thing here...
    • C'est une réponse utile. Toutefois, dans ECHO UAC.ShellExecute.... ligne, "batchArgs!" ne sera pas étendue variable. Utilisation "!batchArgs!". Mon montage a été rejetée, donc j'ai fait un commentaire.
    • bien repéré! Je ne suis pas sûr de savoir pourquoi votre modification a été rejetée, car elle est certainement une faute de frappe et votre correctif fonctionne. Le changement moi-même et l'a testé sur Win 8.1. Maintenant, pour trouver tous les scripts où j'utilise ce code....
    • Le script a éclaté lors de l'utilisation de cité arguments, comme test.bat "a thing" ou "test script.bat" arg1 arg2. Tous les fixes maintenant.
    • J'ai réussi à le casser (en raison de ma faute: exécution de script à partir du lecteur réseau mappé, depuis l'admin et utilisateur normal n'avez pas de même de la cartographie). Encore: est-il un moyen pour voir le résultat? Pour moi, j'ai du trouver le .vbs et modifier le /c /K et puis vu manuellement.
    • Tout bon sur Win 7 SP1 - merci!
    • A travaillé comme un charme! Je vous remercie, monsieur.

    InformationsquelleAutor jxmallett
  7. 17

    - Je utiliser PowerShell pour re-lancer le script élevée si elle ne l'est pas. Mettre ces lignes tout en haut de votre script.

    net file 1>nul 2>nul && goto :run || powershell -ex unrestricted -Command "Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c %~fnx0 %*'"
goto :eof
:run
:: TODO: Put code here that needs elevation

    J'ai copié le net le nom de " méthode de @Matt réponse. Sa réponse est beaucoup mieux documenté et a des messages d'erreur et autres. Celui-ci a l'avantage que PowerShell est déjà installé et disponible sur Windows 7. Aucune temporaire VBScript (*.vbs) des fichiers, et vous n'avez pas à télécharger des outils.

    Cette méthode devrait fonctionner sans aucune configuration ou l'installation, aussi longtemps que votre PowerShell autorisations d'exécution ne sont pas verrouillés.

    • lors de la fourniture d'une liste d'espaces séparés arguments entouré par des guillemets pour obtenir traitées comme un tout, la /c %~fnx0 %*' partie semble laisser à chaque partie, en plus de la première. Par exemple à partir de test.bat "arg1 arg2 arg3" seulement arg1 est passé avant
    • Il semble que peu importe ce que, le Début du Processus supprime tous les guillemets dans la argumentlist..
    • Fonctionne pour moi! Je l'utilise pour netsh int set int %wifiname% Enable/Disable.
    • J'ai eu le même problème que Nicolas Mommaerts ci-dessus. Je ne comprends pas pourquoi cela fonctionne (le meilleur type de correctif), mais fonctionne comme il devrait (notez les guillemets à la fin): net file 1>nul 2>nul && goto :run || powershell -ex unrestricted -Command "Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c ""%~fnx0""""'"
    • Un autre problème (inconvénient) c'est que le script s'interrompt (attend une entrée de l'utilisateur) si le serveur, le service n'est pas en cours d'exécution (je l'ai désactivé pour des raisons). Je usuallly test pour l'administration perms en essayant d'écrire à la HOSTS emplacement du fichier, mais c'est peut-être préférable d'appeler la commande powershell -Verbe runas, au lieu de s'appuyer sur activé services de windows ou de tenter l'écriture des fichiers.
    • pour vos devis correctif. Je peux pas jeter toute la lumière sur pourquoi il fonctionne (il semble correspondent pas à moi!) mais votre version de frappe hors du "%* " de l'original. Intentionnel? C'est sans doute conçu pour relancer le script avec les paramètres sont les mêmes que l'original de l'invocation. Pour les guillemets autour du nom du script (donc il peut contenir des espaces), la suite semble fonctionner: ""%~fnx0"""" %*'". Si il y a des citations dans le autres paramètres, cependant, ils sont encore dépouillé.

    InformationsquelleAutor Ryan Bemrose
  8. 13

    Pour certains programmes, le réglage de la super secret __COMPAT_LAYER variable d'environnement pour RunAsInvoker va travailler.Vérifiez ceci :

    set "__COMPAT_LAYER=RunAsInvoker"
start regedit.exe

    Bien qu'il n'y aura pas de contrôle de compte d'utilisateur de demander à l'utilisateur continuera sans autorisations d'administrateur.

    InformationsquelleAutor npocmaka
  9. 5

    J'ai collé ceci dans le début du script:

    :: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\icacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo args = "" >> "%temp%\getadmin.vbs"
echo For Each strArg in WScript.Arguments >> "%temp%\getadmin.vbs"
echo args = args ^& strArg ^& " "  >> "%temp%\getadmin.vbs"
echo Next >> "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", args, "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" %*
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
:--------------------------------------
    • J'aime l'arg de traitement dans votre script. Mais note cacls est déconseillée dans Windows 7 et versions plus récentes versions de windows.
    • Changer calcs à icalcs fonctionne très bien.
    • Fsutil dirty, c'est encore mieux
    • Savez-vous que la ligne pushd "%CD%" enregistre le répertoire de travail actuel et les modifications du répertoire de travail actuel?
    InformationsquelleAutor TanisDLJ
  10. -4

    Solution suivante est propre et fonctionne parfaitement.

    1. Télécharger Élever fichier zip à partir de https://www.winability.com/download/Elevate.zip

    2. À l'intérieur de zip, vous devriez trouver deux fichiers: Elevate.exe et Elevate64.exe. (Le dernier est un 64 bits natif de la compilation, si vous avez besoin que, bien que l'ordinaire de la version 32 bits, Elevate.exe, devrait fonctionner correctement avec 32 et les versions 64 bits de Windows)

    3. Copier le fichier Elevate.exe dans un dossier où Windows peut toujours le trouver (comme C:/Windows). Ou vous mieux, vous pouvez le copier dans le même dossier où vous avez l'intention de garder votre fichier bat.

    4. De l'utiliser dans un lot de fichier, il suffit de faire précéder la commande que vous souhaitez exécuter en tant qu'administrateur avec l'élévation de commande, comme ceci:

     elevate net start service ...
    • Cette commande ouvre une dialogwindow ce qui demande à l'utilisateur si cette commande ne peut être exécutée. Si vous ne pouvez pas utiliser cette commande dans un fichier batch que doit exécuter SANS interactions de l'utilisateur.
    InformationsquelleAutor Vaibhav Jain