Comment puis-je configurer un “tableau en escalier” en VBA?

J'ai une salle de classe pleine d'enfants, qui ont de la liste de leurs jouets préférés pour une affectation. Certains enfants seulement la liste 1 jouet alors que d'autres la liste des plus.

Comment puis-je créer un tableau en escalier telle que les Enfants(x)(y)...où x est le nombre d'enfants dans ma classe, et y est la liste des jouets qu'ils la liste de leurs favoris?

InformationsquelleAutor phan | 2012-02-24
  1. 29

    "Tableau en escalier" est de l'argot pour tableau de tableaux. VBAVariant type de données peut contenir à peu près tout*, y compris un tableau. Afin de vous faire un tableau de type Variant, et d'attribuer à chacun de ses éléments d'un tableau de longueur arbitraire (c'est à dire pas tous d'entre eux ont même longueur).

    Voici un exemple:

    Dim nStudents As Long
Dim iStudent As Long
Dim toys() As Variant
Dim nToys As Long
Dim thisStudentsToys() As Variant

nStudents = 5 ' or whatever

ReDim toys(1 To nStudents) ' this will be your jagged array

For iStudent = 1 To nStudents
    'give a random number of toys to this student (e.g. up to 10)
    nToys = Int((10 * Rnd) + 1)
    ReDim thisStudentsToys(1 To nToys)

    'code goes here to fill thisStudentsToys()
    'with their actual toys

    toys(iStudent) = thisStudentsToys
Next iStudent

' toys array is now jagged.

' To get student #3's toy #7:
MsgBox toys(3)(7)
'will throw an error if student #3 has less than 7 toys

    * Une exception notable de types définis par l'utilisateur. Les variantes ne peut pas contenir de ces.

    • Lorsque vous ReDim la thisStudentsToys, est-il essentiellement un nouvel emplacement de mémoire créé? Je pensais que les tableaux en VBA sont des références. Je veux juste vérifier: Sur la deuxième itération de la boucle for, la réécriture de l' thisStudentsToys tableau ne modifie pas le premier indice de toys? S'il vous plaît laissez-moi savoir si je ne fais pas moi-même clair. Merci
    InformationsquelleAutor Jean-François Corbett
  2. 5

    Vous pouvez utiliser une collection de collections

    Public Sub Test()

    Dim list As New Collection
    Dim i As Integer, j As Integer
    Dim item As Collection
    For i = 1 To 10
        Set item = New Collection
        For j = 1 To i
            item.Add "Kid" & CStr(i) & "Toy" & CStr(j)
        Next j
        list.Add item
    Next i

    Debug.Print "Kid 4, Toy 2 = " & list(4)(2)
End Sub

    Les sorties qui Kid 4, Toy 2 = Kid4Toy2

    • Comment est une collection de collections, dont je ne suis pas familier avec, différentes à partir d'un tableau de tableaux ou d'un tableau en escalier?
    • Vous pouvez ajouter et supprimer des éléments d'une collection, mais pas de tableaux. Vous pouvez également accéder à des éléments avec une touche en plus à un indice en cas de besoin. Peut-être que vous utilisez les enfants nom ou l'ID comme clé de la collection.
    InformationsquelleAutor ja72
  3. 3

    Jean-François a souligné que chaque élément peut être un tableau de longueur variable. Je voudrais ajouter que chaque élément peut également être d'autres types et n'a pas besoin d'être des tableaux. Par exemple:

    Dim c as New Collection
Dim a(1 to 5) as Variant

c.Add "a","a"
c.Add "b","b"
a(1) = 5
a(2) = Array(2,3,4)
set a(3) = c
a(4) = "abcd"
a(5) = Range("A1:A4").Value

    Les différents éléments d'enfant peut alors être référencé en fonction du type implicites de chacun:

    un(2)(1) = 3

    un(3)(1) = "a"

    un(5)(2,1) = tout ce qui est dans la cellule A2.

    InformationsquelleAutor Excel Developers
  4. 2

    Vous pouvez également concaténer la liste des jouets par exemple un tuyau de la chaîne séparée, puis utiliser Split pour activer la chaîne dans un tableau en cas de besoin:

    Sub UntangleTheString()

Dim sToys As String
Dim aToys() As String
Dim x As Long

sToys = "baseball|doll|yoyo"

aToys = Split(sToys, "|")

For x = LBound(aToys) To UBound(aToys)
    Debug.Print aToys(x)
Next

End Sub
    InformationsquelleAutor Steve Rindsberg
  5. 2

    Vous n'avez pas nécessairement besoin d'un tableau en escalier pour gérer votre scénario comme un tableau 2D (r, c) fera aussi l'affaire. Une ligne pour chaque enfant et une colonne pour chacun d'eux. Les dimensions du tableau sera (nombre d'enfants, MAX nombre de cadeaux) et il va juste dire que certains slots sera vide ou 0 (en fonction de votre type de données). Mais, au moins, de cette façon, vous n'aurez pas besoin de redimensionner le tableau chaque fois que vous ajoutez un cadeau pour un enfant.

    InformationsquelleAutor John Parker