Comment puis-je convertir cette chaîne XML dans Delphi 2009?

C'est l'information que la chaîne XML est.

<?xml version="1.0" encoding="UTF-8"?>
<string xmlns="http://tempuri.org/">
<statusInfo><vendorClaimID>BRADY12478018AETNA</vendorClaimID>
<statusID>0</statusID><statusDescription>Unvalidated</statusDescription>
</statusInfo></string>

Mais c'est la façon dont il se.. Vous devrez faire défiler vers la droite pour voir toutes les.

'<?xml version="1.0" encoding="utf-8"?>'#$D#$A'<string xmlns="http://tempuri.org/">&lt;statusInfo&gt;&lt;vendorClaimID&gt;BRADY12478018AETNA&lt;/vendorClaimID&gt;&lt;statusID&gt;0&lt;/statusID&gt;&lt;statusDescription&gt;Unvalidated&lt;/statusDescription&gt;&lt;/statusInfo&gt;</string>'

J'ai chargé la chaîne dans un XMLDoc, mais ne savent pas comment y accéder facilement à partir d'ici..

var
doc: IXMLDocument;


doc := LoadXMLData(xmlString);

Merci!

N'est-ce pas de sens ou est cette chaîne de même quelque chose qui peut être analysé?
Faites une modification de la chaîne xml, espérons-le, il est plus facile de comprendre maintenant.
Merci pour votre aide.. Bien que je suis arriver dans cette chaîne de réponse à un appel de service web. Peut-être que ce peu d'info à partir de la documentation du service web aidera.. "la Réception de la Réponse Dans la plupart des cas, la réponse à chaque appel de service web est retourné comme XML ou texte mis en forme. Par exemple, l'URL ci-dessus serait de retour: <?xml version="1.0" encoding="utf-8"?> <string xmlns="tempuri.org/... les Avantages Fund</Name><ApexPayerID>13162</ApexPayerID></Payer>< ... </string>""
C'est le format qu'est-ce que ma chaîne d'origine ressemblait, mais après l'avoir écrit dans un fichier xml et en saisissant le texte, il ressemble plus à ce que vous voyez dans ma révision en cours.

InformationsquelleAutor Trevor | 2012-05-22

Vous pouvez utiliser XPath pour extraire les valeurs des nœuds

Vérifier cet échantillon

{$APPTYPE CONSOLE}

{$R *.res}

uses
  MSXML,
  SysUtils,
  ActiveX,
  ComObj;


Const

XMLStr=
'<?xml version="1.0" encoding="UTF-8"?> '+
'<string xmlns="http://tempuri.org/">'+
' <statusInfo>'+
'  <vendorClaimID>BRADY12478018AETNA</vendorClaimID> '+
'  <statusID>0</statusID><statusDescription>Unvalidated</statusDescription> '+
' </statusInfo>'+
'</string> ';

procedure Test;
Var
  XMLDOMDocument  : IXMLDOMDocument;
  XMLDOMNode      : IXMLDOMNode;
begin
  XMLDOMDocument:=CoDOMDocument.Create;
  XMLDOMDocument.loadXML(XmlStr);
  XMLDOMNode := XMLDOMDocument.selectSingleNode('//string/statusInfo/vendorClaimID');
  if XMLDOMNode<>nil then
    Writeln(Format('vendorClaimID %s',[String(XMLDOMNode.Text)]));

  XMLDOMNode := XMLDOMDocument.selectSingleNode('//string/statusInfo/statusID');
  if XMLDOMNode<>nil then
    Writeln(Format('statusID %s',[String(XMLDOMNode.Text)]));

  XMLDOMNode := XMLDOMDocument.selectSingleNode('//string/statusInfo/statusDescription');
  if XMLDOMNode<>nil then
    Writeln(Format('statusDescription %s',[String(XMLDOMNode.Text)]));
end;


begin
 try
    CoInitialize(nil);
    try
      Test;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

Vous pouvez utiliser XPath avec IXMLDocument si son fournisseur interne du moteur est réglé de MSXML.
Grand c'est de travailler avec la chaîne que vous avez fournis. Avez-vous une idée de ce que je peux faire, quand la chaîne (réponse), je reçois ressemble à ceci? '<?xml version="1.0" encoding="utf-8"?>'#$D#$A'<string xmlns="<statusInfo><vendorClaimID>BRADY12478018AETNA</vendorClaimID><statusID>0</statusID><statusDescription>Unvalidated</statusDescription></statusInfo>tempuri.org/...>' que '#$D#$A' semble être le jeter hors, et j'ai de la difficulté à s'en débarrasser.
L'ensemble de la chaîne ne s'affiche pas après l' ... mais j'espère que vous obtenez ce qui se passe. J'ai également ajouté à ma question principale. Merci
Ok, alors vous devez décoder tout d'abord vous XML, essayez d'utiliser le HTTPDecode fonction de la HTTPApp unité et ensuite d'analyser la chaîne de résultat avec la méthode ci-dessus ou à l'aide de l'Remy de réponse.
J'ai essayé le HTTPDecode fonction, mais Il n'a toujours pas lu la chaîne correctement une fois que je le charge il ne peut pas trouver l'un des nœuds. 🙁
Désolé, la fonction est HTMLDecode.
Ahh, oui HTMLDecode qui fait sens, c'était mon problème tout le temps, je juste ne le savais pas quand j'ai posé la question. Merci!

InformationsquelleAutor RRUZ

Chaque nœud dans le fichier XML sera représenté comme un IXMLNode dans le IXMLDocument, dans la même hiérarchie qu'ils apparaissent dans le fichier XML. Il serait utile si vous regardez d'abord le XML avec les nœuds en retrait de sorte que vous pouvez voir la hiérarchie plus clairement:

<?xml version="1.0" encoding="UTF-8"?> 
<string xmlns="http://tempuri.org/"> 
  <statusInfo>
    <vendorClaimID>BRADY12478018AETNA</vendorClaimID> 
    <statusID>0</statusID>
    <statusDescription>Unvalidated</statusDescription> 
  </statusInfo>
</string>

Un vous de comprendre la hiérarchie, vous pouvez écrire du code pour elle:

var 
  doc: IXMLDocument;
  statusInfo: IXMLNode;
  vendorClaimID: String;
  statusID: Integer;
  statusDescription: String;
begin 
  doc := LoadXMLData(xmlString);
  statusInfo := doc.DocumentElement.ChildNodes['statusInfo'];
  vendorClaimID := statusInfo.ChildNodes['vendorClaimID'].Text;
  statusID := StrToInt(statusInfo.ChildNodes['statusID'].Text);
  statusDescription := statusInfo.ChildNodes['statusDescription'].Text; 
end;

Sinon:

var 
  doc: IXMLDocument;
  statusInfo: IXMLNode;
  vendorClaimID: String;
  statusID: Integer;
  statusDescription: String;
begin 
  doc := LoadXMLData(xmlString);
  statusInfo := doc.DocumentElement.ChildNodes['statusInfo'];
  vendorClaimID := VarToStr(statusInfo.ChildValues['vendorClaimID']);
  statusID := StrToInt(VarToStr(statusInfo.ChildValues['statusID']));
  statusDescription := VarToStr(statusInfo.ChildValues['statusDescription']); 
end;

Si vous utilisez Delphi Liaison de Données XML assistant, il va générer des interfaces qui parse le XML pour vous:

var 
  doc: IXMLDocument;
  statusInfo: IXMLstatusInfoType;
  vendorClaimID: String;
  statusID: Integer;
  statusDescription: String;
begin 
  doc := LoadXMLData(xmlString);
  statusInfo := Getstring(doc).statusInfo;
  vendorClaimID := statusInfo.vendorClaimID;
  statusID := statusInfo.statusID;
  statusDescription := statusInfo.statusDescription; 
end;

Merci pour l'aide, Ma chaîne xml a été codé en html, donc rien ne fonctionnait.

InformationsquelleAutor Remy Lebeau

Vous devez vous connecter pour publier un commentaire.