Comment puis-je déclencher une macro à exécuter après un nouveau mail est reçu dans Outlook?

Je suis en train d'écrire une macro qui crée des billets sur une base de données basée sur les alertes reçues à partir d'un serveur Nagios comme un e-mail. Cependant, je ne peux pas laisser la macro à exécuter dans une boucle infinie lors de la vérification pour les mails, car il est juste trop de ressources lourd et rend mon bureau accrocher. J'ai besoin de trouver un moyen de déclencher la macro uniquement lorsqu'un nouveau message est reçu.

J'ai cherché quelque chose le long des lignes de NewMail événements sur le site web MSDN, mais je ne peux pas trouver quelque chose de cohérent. Quelqu'un peut-il me montrer un peu de code d'exemple pour montrer comment déclencher des macros de nouveaux messages d'événements?

InformationsquelleAutor Gautam Mainkar | 2012-06-29
  1. 53

    Ce code permettra d'ajouter un écouteur d'événement à la locale par défaut de la Boîte de réception, puis de prendre une certaine action sur les e-mails entrants. Vous avez besoin d'ajouter que l'action dans le code ci-dessous.

    Private WithEvents Items As Outlook.Items 
Private Sub Application_Startup() 
  Dim olApp As Outlook.Application 
  Dim objNS As Outlook.NameSpace 
  Set olApp = Outlook.Application 
  Set objNS = olApp.GetNamespace("MAPI") 
  ' default local Inbox
  Set Items = objNS.GetDefaultFolder(olFolderInbox).Items 
End Sub
Private Sub Items_ItemAdd(ByVal item As Object) 

  On Error Goto ErrorHandler 
  Dim Msg As Outlook.MailItem 
  If TypeName(item) = "MailItem" Then
    Set Msg = item 
    ' ******************
    ' do something here
    ' ******************
  End If
ProgramExit: 
  Exit Sub
ErrorHandler: 
  MsgBox Err.Number & " - " & Err.Description 
  Resume ProgramExit 
End Sub

    Après avoir collé le code dans ThisOutlookSession module, vous devez redémarrer Outlook.

    • Ne fonctionne pas pour moi dans Outlook Professionnel Plus 2010
    • Mon mauvais, avait macros désactivées. Peu idiot qu'il n'y a pas d'autre niveau de sécurité des macros pour ce scénario si.
    • Où est Items_ItemAdd appelé?
    • Travaillé avec Outlook 2016
    • Fonctionne pour le premier couple de mails pendant le premier couple de minutes, puis s'arrête soudainement déclenché. Aucune idée pourquoi?
    InformationsquelleAutor JimmyPena
  2. 8

    Essayer quelque chose comme cela à l'intérieur de ThisOutlookSession:

    Private Sub Application_NewMail()
    Call Your_main_macro
End Sub

    Mon outlook vba juste mis le feu quand j'ai reçu un e-mail et n'avait que des événements d'application ouverte.

    Edit: je viens de tester un hello world msg box et il a couru après avoir été appelé dans le application_newmail événement lorsqu'un e-mail a été reçu.

    • J'ai peur qu'elle ne semble pas fonctionner. J'ai essayé d'exécuter la macro et ensuite l'envoyer moi un mail, mais je ne pouvais pas obtenir ma macro à exécuter jusqu'à ce que j'ai réinitialisé le tout. Que pensez-vous que le problème pourrait être?
    • Où avez-vous avez le code dans ma réponse? Je l'ai mis en ThisOutlookSession et à gauche. Pas besoin pour exécuter la macro, il va déclencher lorsqu'un message est reçu.
    • Je l'avais collé dans ThisOutlookSession trop, mais c'est me donner beaucoup de problèmes durant la course. Je ne peux même pas pointer vers la racine du problème, mes sous ne vient totalement aléatoire choses...
    • Ne fonctionne pas pour moi dans Outlook Professionnel Plus 2010
    • Si vous collez quelque chose comme cela dans le "faire quelque chose ici" de la section: Call Your_main_macro, j'ai trouvé que la macro doit être stocké dans le même module, ThisOutlookSession. Si elle était dans un autre module, j'ai une erreur. J'ai dû redémarrer Outlook pour que les changements prennent effet.
    InformationsquelleAutor Alistair Weir