Comment puis-je échapper à la méta-caractères lorsque je interpoler une variable Perl opérateur de match?

La bonne réponse est - ne pas utiliser les expressions régulières. Je ne dis pas que les expressions régulières sont mauvais, mais les utiliser pour (ce qui est égal à) un simple contrôle d'égalité, c'est du matraquage.

Utilisation: grep { lc($_) eq lc($word) } @arr et d'être heureux.

OriginalL'auteur

De perlfaq6's réponse à Comment puis-je rechercher une expression régulière dans une variable?:

---

Nous n'avons pas à coder en dur des motifs dans le match de l'opérateur (ou n'importe quoi d'autre qui fonctionne avec des expressions régulières). Nous pouvons mettre le modèle dans une variable pour l'utiliser plus tard.

L'opérateur de match est un guillemet double contexte, de sorte que vous pouvez interpoler votre variable comme une double chaîne de caractères entre guillemets. Dans ce cas, vous avez lu l'expression régulière comme la saisie de l'utilisateur et de les stocker dans $regex. Une fois que vous avez le rythme dans $regex, vous utilisez cette variable dans l'opérateur de match.

chomp( my $regex = <STDIN> );

if( $string =~ m/$regex/ ) { ... }

Toute expression régulière caractères spéciaux $regex sont toujours spécial, et le modèle doit encore être valide ou Perl va se plaindre. Par exemple, dans ce modèle il y a un impair parenthèse.

my $regex = "Unmatched ( paren";

"Two parens to bind them all" =~ m/$regex/;

Lorsque Perl compile l'expression régulière, il traite de la parenthèse comme le début d'une mémoire de match. Quand il ne trouve pas la parenthèse fermante, il se plaint:

Unmatched ( in regex; marked by <-- HERE in m/Unmatched ( <-- HERE  paren/ at script line 3.

Vous pouvez contourner ce problème de plusieurs façons, selon notre situation. Tout d'abord, si vous ne voulez pas avoir des caractères dans la chaîne de l'être, vous pourrez vous évader avec quotemeta avant d'utiliser la chaîne de caractères.

chomp( my $regex = <STDIN> );
$regex = quotemeta( $regex );

if( $string =~ m/$regex/ ) { ... }

Vous pouvez également le faire directement dans le match de l'opérateur à l'aide de l' \Q \E séquences. L' \Q indique à Perl par où commencer échapper les caractères spéciaux, et \E lui indique où à l'arrêt (voir perlop pour plus de détails).

chomp( my $regex = <STDIN> );

if( $string =~ m/\Q$regex\E/ ) { ... }

Alternativement, vous pouvez utiliser les qr//, l'expression régulière citation de l'opérateur (voir perlop pour plus de détails). Il cite, et peut-être compile le modèle, et vous pouvez appliquer une expression régulière drapeaux pour le modèle.

chomp( my $input = <STDIN> );

my $regex = qr/$input/is;

$string =~ m/$regex/  # same as m/$input/is;

Vous pouvez également intercepter des erreurs en les enveloppant d'un eval bloc autour de l'ensemble de la chose.

chomp( my $input = <STDIN> );

eval {
    if( $string =~ m/\Q$input\E/ ) { ... }
    };
warn $@ if $@;

Ou...

my $regex = eval { qr/$input/is };
if( defined $regex ) {
    $string =~ m/$regex/;
    }
else {
    warn $@;
    }

OriginalL'auteur brian d foy

Je ne pense pas que vous voulez un regex dans ce cas, puisque vous n'êtes pas correspondant à un motif. Vous êtes à la recherche d'un littéral de chaîne de caractères que vous connaissez déjà. Construire une table de hachage avec les valeurs de match et l'utiliser pour filtrer @arr:

 open my $fh, '<', $filename or die "...";
 my %hash = map { chomp; lc($_), 1 } <$fh>;

 foreach my $item ( @arr ) 
      {
      next unless exists $hash{ lc($item) };
      print "I matched [$item]\n";
      }

OriginalL'auteur brian d foy