Comment puis-je émettre un HTTP GET à partir de VBA Excel pour Mac

Faire plus de recherche, je suis tombé sur Robert Chevalier de commentaire sur cette question VBA fonction Shell dans Office 2011 pour Mac et construit un HTTPGet fonction à l'aide de son execShell la fonction à appeler curl. Je l'ai testé sur un Mac exécutant Mac OS X 10.8.3 (Mountain Lion) avec Excel 2011 pour Mac. Voici le code VBA:

Option Explicit
' execShell() function courtesy of Robert Knight via StackOverflow
' https://stackoverflow.com/questions/6136798/vba-shell-function-in-office-2011-for-mac
Private Declare Function popen Lib "libc.dylib" (ByVal command As String, ByVal mode As String) As Long
Private Declare Function pclose Lib "libc.dylib" (ByVal file As Long) As Long
Private Declare Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As Long, ByVal items As Long, ByVal stream As Long) As Long
Private Declare Function feof Lib "libc.dylib" (ByVal file As Long) As Long
Function execShell(command As String, Optional ByRef exitCode As Long) As String
Dim file As Long
file = popen(command, "r")
If file = 0 Then
Exit Function
End If
While feof(file) = 0
Dim chunk As String
Dim read As Long
chunk = Space(50)
read = fread(chunk, 1, Len(chunk) - 1, file)
If read > 0 Then
chunk = Left$(chunk, read)
execShell = execShell & chunk
End If
Wend
exitCode = pclose(file)
End Function
Function HTTPGet(sUrl As String, sQuery As String) As String
Dim sCmd As String
Dim sResult As String
Dim lExitCode As Long
sCmd = "curl --get -d """ & sQuery & """" & " " & sUrl
sResult = execShell(sCmd, lExitCode)
' ToDo check lExitCode
HTTPGet = sResult
End Function    

Pour l'utiliser, copiez le code ci-dessus, ouvrir l'éditeur VBA dans Excel 2011 pour Mac. Si vous n'avez pas un module, cliquez sur Insertion->Module. Collez le code dans le fichier module. Quitter l'éditeur VBA (trèfle-Q).

Voici un exemple d'utilisation de prévisions météorologiques service web (http://openweathermap.org/wiki/API/JSON_API)

La cellule A1 sera réservé pour le nom de la ville.

Dans la cellule A2, entrez l'URL de la chaîne: http://api.openweathermap.org/data/2.1/forecast/city

Dans la cellule A3 qui permettra de construire la chaîne de requête, entrez: ="q=" & A1

Dans la cellule A4, entrez: =HTTPGet(A2, A3)

Maintenant, tapez un nom de ville dans la cellule A1, par exemple London, la cellule A4 vous montrer la réponse JSON contenant les prévisions météo pour Londres. Modifier la valeur de A1 à partir de London à Moscow -- A4 modifier le format JSON prévisions pour la ville de Moscou.

De toute évidence, à l'aide de VBA, vous pouvez analyser et de reformater les données JSON et le placer où il faut dans votre feuille de calcul.

Aucune réclamation pour des performances ou de l'évolutivité, mais pour un simple one-shot accès à un service web à partir d'Excel pour Mac 2011, ce qui semble faire l'affaire et répondait à la nécessité, pour laquelle j'ai posté ma question initiale. YMMV!

OriginalL'auteur John Stephens

Une autre option (mise à jour en conséquence si votre curl n'est pas situé dans /opt/local/bin/curl):

VBA:

Public Function getUrlContents(url) As String
Dim command As String
command = "do shell script ""/path_to/getUrl.sh " + url + """"
getUrlContents = VBA.MacScript(command)
End Function

/path_to/getUrl.sh:

#!/bin/sh
if [ -z "$1" ]
then
echo "missing url argument"
else
/opt/local/bin/curl "$1"
fi

Noter que vous devrez vous assurer que getUrl.sh est exécutable:

chmod u+x getUrl.sh

OriginalL'auteur mwag