Comment puis-je exclure des noms de fichiers à partir d'un MS DOS dir liste?

@echo off
setlocal EnableDelayedExpansion
rem Add more names separated with slashes here:
set exclude=/autoexec/
for %%a in (*.bat) do (
   if "!exclude:/%%~Na/=!" equ "%exclude%" (
      echo %%~Na
   )
)

MODIFIER: Quelques explications ajouté

Traitement des fichiers de commandes est lent, donc vous devez utiliser des techniques qui permet à un fichier de commandes pour exécuter plus rapidement. Par exemple:

• Essayez d'utiliser le minimum de lignes de commandes pour atteindre un certain résultat. Essayez d'éviter les commandes externes (*.les fichiers exe) comme find, findstr, fc, etc. spécialement si ils travaillent sur de petites quantités de données; utiliser if de commande à la place.
• Utilisation for %%a in (*.bat)... au lieu de for /F %%a in ('dir /B *.bat').... La seconde méthode nécessite d'exécuter cmd.exe et de stocker les résultats dans un fichier avant de for commande peut traiter ses lignes.
• Éviter les tuyaux et l'utilisation des redirections à la place. Un tuyau d'exiger l'exécution de deux exemplaires de cmd.exe pour traiter la commande de chaque côté de la conduite.
• Un moyen simple pour vérifier si une variable contient une chaîne de caractères est d'essayer de supprimer la chaîne à partir de la variable: si le résultat est différents que la chaîne existe dans la variable: if "!variable:%string%=!" neq "%variable%" echo The string is in the variable.
• Méthode précédente peut également être utilisé pour vérifier si une variable d'une personne d'une liste de valeurs: set list=one two three, if "!list:%variable%=!" neq "%list%" echo The variable have one value from the list. Si les valeurs de la liste peut contenir des espaces, ils doivent être séparés par un délimiteur.

MODIFIER: Nouvelle version ajoute que répondre à de nouveaux commentaires

La façon la plus simple pour mettre en pause une page à la fois est d'utiliser more filtre de cette façon:

theBatchFile | more

Toutefois, le programme doit réorganiser la production, afin de montrer dans les colonnes. La nouvelle version ci-dessous d'atteindre ces deux choses, de sorte qu'il ne nécessite pas de more filtre; il vous suffit de définir le nombre de colonnes et de lignes par page.

@echo off
setlocal EnableDelayedExpansion
rem Add more names separated with slashes here:
set exclude=/autoexec/
rem Set the first two next variables as desired:
set /A columns=5, rows=41,   wide=(80-columns)/columns, col=0, row=0
rem Create filling spaces to align columns
set spaces=
for /L %%a in (1,1,%wide%) do set spaces= !spaces!
set line=
for %%a in (*.bat) do (
   if "!exclude:/%%~Na/=!" equ "%exclude%" (
      rem If this column is less than the limit...
      set /A col+=1
      if !col! lss %columns% (
         rem ... add it to current line
         set name=%%~Na%spaces%
         set "line=!line!!name:~0,%wide%! "
      ) else (
         rem ... show current line and reset it
         set name=%%~Na
         echo !line!!name:~0,%wide%!
         set line=
         set /a col=0, row+=1
         rem If this row is equal to the limit...
         if !row! equ %rows% (
            rem ...do a pause and reset row
            pause
            set row=0
         )
      )
   )
)
rem Show last line, if any
if defined line echo %line%

Antonio

OriginalL'auteur Aacini

DIR "*.bat" /B /P | find /v "autoexec" | for %i in (*.bat) do @echo %~ni

OriginalL'auteur Hernán