Comment puis-je exécuter un QTP test à partir de la ligne de commande?

Il est vrai qu'avec QuickTest Pro, vous ne pouvez pas directement l'exécution d'un test en appelant C:\Program Files (x86)\HP\QuickTest Professional\bin\QTPro.exe "C:\Some Test\"

Tout espoir n'est pas perdu, cependant. Il y a une façon de créer un petit fichier VBS qui peut exécuter n'importe quel QTP test lorsque que VBS fichier est appelée. C'est beaucoup mieux que de créer un simple fichier batch pour chaque test.

'*******************************************************************
'RunThisTest
'by Michael Innes
'November 2012

testResourcePath = "C:\Test Logs and Results\"

'Getting the test path
Dim objArgs
Set objArgs = wscript.Arguments
testPath = objArgs(0)

'Determining that the test does exist
Dim objFSO
Set objFSO = CreateObject("Scripting.FileSystemObject")
DoesFolderExist = objFSO.FolderExists(testPath)
Set objFSO = Nothing

If DoesFolderExist Then
    Dim qtApp 'Declare the Application object variable
    Dim qtTest 'Declare a Test object variable
    Set qtApp = CreateObject("QuickTest.Application") 'Create the Application object
    qtApp.Launch 'Start QuickTest
    qtApp.Visible = True 'Make the QuickTest application visible
    qtApp.Open testPath, False 'Open the test in read-only mode
    Set qtTest = qtApp.Test

    'Set qtResultsOpt = CreateObject("QuickTest.RunResultsOptions") ' Create the Run Results Options object
    'qtResultsOpt.ResultsLocation = testResourcePath ' Specify the location to save the test results.
    'qtTest.Run qtResultsOpt,True 'Run the test and wait until end of the test run

    qtTest.Run 'Run the test
    qtTest.Close 'Close the test
    qtApp.Quit
Else
    'Couldn't find the test folder. That's bad. Guess we'll have to report on how we couldn't find the test.
    'Insert reporting mechanism here.
End If

D'utiliser le code ci-dessus, exécuter une commande comme ceci: cscript.exe "C:\RunThisTest.vbs" "L:\Test Path\The Test Itself\"

OriginalL'auteur