Comment puis-je exécuter un script VBScript en mode 32 bits sur une machine 64 bits?

J'ai un fichier texte qui se termine par .vbs que j'ai écrit la suivante:

Set Conn = CreateObject("ADODB.Connection")
Conn.Provider = "Microsoft.ACE.OLEDB.12.0"
Conn.Properties("Data Source") = "C:\dummy.accdb"
Conn.Properties("Jet OLEDB:Database Password") = "pass"
Conn.Open
Conn.Close
Set Conn = Nothing

Quand j'execute ce sur un Windows 32 bits machine sur laquelle il tourne et se termine sans aucune notion (prévu).
Quand j'execute ce sur un Windows 64 bits machine, il obtient l'erreur

Fournisseur ne peut pas être trouvé. Il peut ne pas être installé correctement.

Mais il est installé. Je pense que la racine du problème est que le fournisseur est un fournisseur 32 bits, autant que je sache, il n'existe pas en version 64 bits.

Si je lance le script VBScript par l'intermédiaire de IIS sur ma machine 64 bits (comme un fichier ASP) je peux choisir qui il doit s'exécuter en mode 32 bits. Il est alors possible de trouver le fournisseur.

Comment puis-je faire trouver le fournisseur sur Windows 64 bits? Puis-je dire CScript (qui exécute le .vbs fichier texte) pour exécuter en mode 32 bits en quelque sorte?

Veuillez noter que même en utilisant 32 bits Cscript pas tous les fournisseurs de base de données va fonctionner. Si le fournisseur est un pilote (exemple: SQLite) il ne fonctionne pas. Vous devez installer le 64 bits SQLite pilotes sur Windows 64 bits au lieu de cela, de sorte que le fournisseur de travail dans cscript 64-bits et 32-bits cscript sur 64 bits).
Les Pilotes ODBC ne sont pas des Fournisseurs OLEDB à tous. Elles sont normalement utilisées avec ADO via la cale Fournisseur de MSDASQL qui est le Fournisseur par défaut pour la compatibilité. Bien sûr, si vous apporter encore plus obsolète la Dsn Système, dans les mélanger les choses se corse en raison de registre problèmes de visibilité.

InformationsquelleAutor Peter | 2010-05-10

66

suivre http://support.microsoft.com/kb/896456

Pour démarrer une invite de commandes 32 bits, procédez comme suit:
```
* Click Start, click Run, type %windir%\SysWoW64\cmd.exe, and then click OK.
```
Puis tapez
```
cscript vbscriptfile.vbs
```
- Merci beaucoup, ça a fonctionné. 🙂 Ne sait pas SysWoW64 contenait une invite de commandes 32 bits, pourquoi est-il appelé "SysWoW64" de toute façon?
- WoW pour Windows sur Windows. C'est une couche de compatibilité qui permet 64-bit de Windows loi sur la 32 bits de Windows de sorte qu'il peut exécuter des programmes 32 bits.
- Très utile et intéressant, je ne savais pas que. Toujours agréable de se rapprocher de la compréhension du fonctionnement interne de Windows, merci beaucoup.
- Peut-on appliquer cette trcik pour VBScript en vertu du code HTML?
- Vous pouvez le faire également en une seule étape. Exécuter %windir%\SysWoW64\cscript vbscriptfile.vbs
- mon dieu, monsieur, je vous remercie!
InformationsquelleAutor volody

' C:\Windows\System32\WScript.exe = WScript.exe
Dim ScriptHost : ScriptHost = Mid(WScript.FullName, InStrRev(WScript.FullName, "\") + 1, Len(WScript.FullName))

Dim oWs : Set oWs = CreateObject("WScript.Shell")
Dim oProcEnv : Set oProcEnv = oWs.Environment("Process")

' Am I running 64-bit version of WScript.exe/Cscript.exe? So, call script again in x86 script host and then exit.
If InStr(LCase(WScript.FullName), LCase(oProcEnv("windir") & "\System32\")) And oProcEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
    ' rebuild arguments
    If Not WScript.Arguments.Count = 0 Then
        Dim sArg, Arg
        sArg = ""
        For Each Arg In Wscript.Arguments
              sArg = sArg & " " & """" & Arg & """"
        Next
    End If

    Dim sCmd : sCmd = """" &  oProcEnv("windir") & "\SysWOW64\" & ScriptHost & """" & " """ & WScript.ScriptFullName & """" & sArg
    WScript.Echo "Call " & sCmd
    oWs.Run sCmd
    WScript.Quit
End If

Ajouter une petite explication svp
Le ci-dessus fonctionne très bien. Il suffit d'ajouter votre script en bas de celui-ci (après la Fin Si) et il sera exécuté sur une version 64 bits de l'OS même, car il fonctionne sur un OS 32 bits, et de le faire de manière transparente. Mes remerciements.
C'est une pépite. L'envelopper dans un VerifyArchitecture sous, mélanger le sous au bas de votre script et de l'appeler sur la première ligne. Mérite une façon de plus d'amour que c'est devenu!

InformationsquelleAutor Vozzie

14

Si vous avez le contrôle sur l'exécution de la commande cscript exécutable puis exécutez le X:\windows\syswow64\cscript.exe version 32bit mise en œuvre.
- Merci beaucoup, ça a fonctionné. 🙂
InformationsquelleAutor tyranid

   ' ***************
' *** 64bit check
' ***************
' check to see if we are on 64bit OS -> re-run this script with 32bit cscript
Function RestartWithCScript32(extraargs)
Dim strCMD, iCount
strCMD = r32wShell.ExpandEnvironmentStrings("%SYSTEMROOT%") & "\SysWOW64\cscript.exe"
If NOT r32fso.FileExists(strCMD) Then strCMD = "cscript.exe" ' This may not work if we can't find the SysWOW64 Version
strCMD = strCMD & Chr(32) & Wscript.ScriptFullName & Chr(32)
If Wscript.Arguments.Count > 0 Then
For iCount = 0 To WScript.Arguments.Count - 1
if Instr(Wscript.Arguments(iCount), " ") = 0 Then ' add unspaced args
strCMD = strCMD & " " & Wscript.Arguments(iCount) & " "
Else
If Instr("/-\", Left(Wscript.Arguments(iCount), 1)) > 0 Then ' quote spaced args
If InStr(WScript.Arguments(iCount),"=") > 0 Then
strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") + 1) & """ "
ElseIf Instr(WScript.Arguments(iCount),":") > 0 Then
strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") + 1) & """ "
Else
strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
End If
Else
strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
End If
End If
Next
End If
r32wShell.Run strCMD & " " & extraargs, 0, False
End Function
Dim r32wShell, r32env1, r32env2, r32iCount
Dim r32fso
SET r32fso = CreateObject("Scripting.FileSystemObject")
Set r32wShell = WScript.CreateObject("WScript.Shell")
r32env1 = r32wShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%")
If r32env1 <> "x86" Then ' not running in x86 mode
For r32iCount = 0 To WScript.Arguments.Count - 1
r32env2 = r32env2 & WScript.Arguments(r32iCount) & VbCrLf
Next
If InStr(r32env2,"restart32") = 0 Then RestartWithCScript32 "restart32" Else MsgBox "Cannot find 32bit version of cscript.exe or unknown OS type " & r32env1
Set r32wShell = Nothing
WScript.Quit
End If
Set r32wShell = Nothing
Set r32fso = Nothing
' *******************
' *** END 64bit check
' *******************

Placez le code ci-dessus au début de votre script, et, postérieurement, le code s'exécute en mode 32 bits avec accès à la 32bit pilotes ODBC. Source.

Wow, le ci-dessus fonctionne très bien, et c'est magique!

InformationsquelleAutor user2759843

2

Nous pouvons force vbscript toujours fonctionner avec 32 bit de mode en changeant de "system32" de "sysWOW64" la valeur par défaut de la clé "Computer\HKLM\SOFTWARE]\Classes\VBSFile\Shell\Open\Command"
- Ce n'est pas correct du tout. Je vois sous MS Windows 7 64 bits suivant "%SystemRoot%\System32\WScript.exe" "%1" %* à la place de la valeur pour Command.
- (@ Académie de Programmeur): Juste pour clarifier 2,5 ans plus tard... Changer la clé de registre sur un ordinateur 64 bits de "System32" de "SysWow64" va en effet conduire VBScript pour exécuter GUI scripts en 32 bits. Il est exact que la clé de registre par défaut des points d'System32\WScript.exe qui est le 64-bit binaire. Merci Ronie Faire pour la contribution.
- Je pense que c'est dangereux, car alors tous VBS script sera exécuté en 32 bits. Peut-être pas votre intention.
InformationsquelleAutor Ronie Do
1

Autre méthode à exécuter 32 bits scripts sur une machine 64 bits:
%windir%\syswow64\cscript.exe vbscriptfile.vbs

InformationsquelleAutor Divyanand M S

Dans le script de lancement, vous pouvez le forcer, il permet de garder le même scénario et le même lanceur pour à la fois l'architecture

:: For 32 bits architecture, this line is sufficent (32bits is the only cscript available)
set CSCRIPT="cscript.exe"
:: Detect windows 64bits and use the expected cscript (SysWOW64 contains 32bits executable)
if exist "C:\Windows\SysWOW64\cscript.exe" set CSCRIPT="C:\Windows\SysWOW64\cscript.exe"
%CSCRIPT% yourscript.vbs

InformationsquelleAutor Guilhem Hoffmann

Vous devez vous connecter pour publier un commentaire.