comment puis-je exprimer le terme si x est un entier dans la langue de VBA?

If IsNumeric(x) Then 'it will check if x is a number

Si vous voulez vérifier le type, vous pouvez utiliser

If TypeName(x) = "Integer" Then

OriginalL'auteur shahkalpesh

Cela dépend si vous voulez dire que les données de type "Integer", ou Entier dans le sens de: "Un nombre sans décimale." Si tu voulais parler de cette dernière, puis un petit test manuel suffira (voir le premier exemple); si vous parliez de l'ancien puis il y a trois façons de regarder les types de données avec tous les avantages et les inconvénients:

1. VarType vais vous dire la variante du sous-type (voir l'exemple). C'est assez rapide car c'est une juste une lecture de la mémoire d'un enum, mais ne peut être utilisé sur des variantes et ne vous diront pas le type d'objet spécifique. En outre, la variante du sous-type est souvent attribuée automatiquement (généralement tendance à taper avec le plus petit adapté de type de données). Mais il peut être difficile (voir l'exemple).
2. TypeName est la plus flexible et robuste. Il peut vous dire précis types de classe et de la Variante de sous-types. Il a un léger inconvénient de test nécessite une comparaison de chaînes de caractères, donc il n'y a qu'un infime des performances. Il ne sera pas perceptible à moins qu'il y est peu de sérieux de la répétition. Aussi, si vous avez deux Objets de même nom dans votre projet (par Exemple Word.Gamme et Excel.La gamme), TypeName ne pouvez pas faire la différence (il sera de retour "de la Gamme" pour les deux).
3. Enfin, il y a l'opérateur TypeOf (qui ne sera pas vous aider ici). L'opérateur TypeOf ne peux pas tester pour les primitives (exemple: Integer, Long, String, etc.) mais on peut dire que le type d'objet (par exemple. Excel.Gamme vs Mot.La gamme). L'opérateur TypeOf renvoie une erreur si l'objet n'est rien, donc vous devez toujours prétest de l'objet "N'Est Rien", mais étant un opérateur plutôt que dans une fonction, il est beaucoup plus rapide que TypeName (même avec le test).

Public Sub ExampleManual()
    Dim d As Double
    d = 1
    If Fix(d) = d Then
        MsgBox "Integer"
    End If
End Sub

Public Sub ExampleTypeName()
    Dim x As Integer
    MsgBox TypeName(x)
End Sub

Public Sub ExampleTypeOf()
    Dim x As Excel.Range
    Set x = Selection
    ''//Using TypeOf on Objects set to Nothing will throw an error.
    If Not x Is Nothing Then
        If TypeOf x Is Excel.Range Then
            MsgBox "Range"
        End If
    End If
End Sub

Public Sub ExampleVarType()
    Dim x As Variant
    ''//These are all different types:
    x = "1"
    x = 1
    x = 1&
    x = 1#
    Select Case VarType(x)
        Case vbEmpty
        Case vbNull
        Case vbInteger
        Case vbLong
        Case vbSingle
        Case vbDouble
        Case vbCurrency
        Case vbDate
        Case vbString
        Case vbObject
        Case vbError
        Case vbBoolean
        Case vbVariant
        Case vbDataObject
        Case vbDecimal
        Case vbByte
        Case vbUserDefinedType
        Case vbArray
        Case Else
    End Select
End Sub

OriginalL'auteur Oorang