Comment puis-je extraire les valeurs après = dans mon string avec Perl?

J'ai une chaîne comme celle-ci

field1=1 field2=2 field3=abc

Je veux de sortie ce que 

2,1,abc

Aucune idée de comment je peux aller à ce sujet? Je peux écrire un petit C ou Java programme pour ce faire, d'essayer, je vais essayer de trouver un moyen simple de le faire en Perl.

  • Avez-vous vraiment voulu swap 1 et 2 au-dessus?
  • Est-ce que avez à faire avec les chaînes de requête HTTP? Si c'est un rond-point de la question à se poser la question, ou si vous pouvez traiter avec les esperluettes ou des points-virgules séparant les champs, puis vous pouvez utiliser l'une des nombreuses CGI modules sur CPAN.
InformationsquelleAutor kal | 2009-07-10
  1. 5
    #!/usr/bin/perl

use strict;
use warnings;

# Input string
my $string = "field1=1 field2=2 field3=abc";
# Split string into a list of "key=value" strings
my @pairs = split(/\s+/,$string);
# Convert pair strings into hash
my %hash = map { split(/=/, $_, 2) } @pairs;
# Output hash
printf "%s,%s,%s\n", $hash{field2}, $hash{field1}, $hash{field3};   # => 2,1,abc
# Output hash, alternate method
print join(",", @hash{qw(field2 field1 field3)}), "\n";
    • +1 pour ne pas recourir à la regex marteau. Cependant: split(/\s+/,$string) est aussi plus simplement exprimé en split(' ',$string)
    • Vrai, tant qu'il y a des espaces.
    InformationsquelleAutor Lars Haugseth
  2. 6
    use strict;
use warnings;

my $string = 'field1=1 field2=2 field3=abc';
my @values = ($string =~ m/=(\S+)/g);
print join(',', @values), "\n";
    • Cette fonction génère les champs dans le mauvais ordre. Mineur pinaille: il ne fonctionnera pas si l'une des valeurs contiennent un signe égal.
    InformationsquelleAutor Michael Carman
  3. 2

    Utilisation m//g dans un contexte de liste:

    #!/usr/bin/perl

use strict;
use warnings;

my $x = "field1=1 field2=2 field3=abc";

if ( my @matches = $x =~ /(?:field[1-3]=(\S+))/g ) {
    print join(',', @matches), "\n";
}

__END__

    De sortie:

    C:\Temp> klm
1,2,abc
    InformationsquelleAutor Sinan Ünür
  4. 2
     $_='field1=1 field2=2 field3=abc';
 $,=',';
 say /=(\S+)/g

    Let's play Perl golf 😀

    • C'est bon 🙂
    • Si nous allons jouer au golf... perl -E "$_='field1=1 field2=2 field3=abc';$,=',';say /=(\S+)/g"
    InformationsquelleAutor jeje
  5. 1
    my $str = 'field1=1 field2=2 field3=abc';
print(join(',', map { (split('=', $_))[1] } split(' ', $str)));
    InformationsquelleAutor zakovyrya
  6. 1

    Il ya plusieurs façons que vous pouvez faire:

    • Regex match
    my $s = "field1=1 field2=2 field3=abc";
$s =~ /field1=(\w*) field2=(\w*) field3=(\w*)$/; //pick out each field
print $1,$2,$3;'
    12abc
    • Fractionner la chaîne de match
    my $s = "field1=1 field2=2 field3=abc"; 
my @arr = split //, $s; print @arr,"\n"; //make an array of name=value pairs
my @vals = map { @pairs = split /=/, $_; $pairs[1] } @arr;  //get the values only from each pair
print @vals'
    field1=1field2=2field3=abc
12abc
    • Split et les mettre dans une table de hachage (je pense que c'est le plus utile)
    my $s = "field1=1 field2=2 field3=abc"; 
my @arr = split //, $s;  
my %pairs = map { split=/, $_; } @arr; 
print $pairs{field1}, $pairs{field2}, $pairs{field3}
    12abc
    InformationsquelleAutor naumcho
  7. 0

    En supposant que votre commande a été une faute de frappe:

    
#!/usr/bin/perl
use strict; use warnings;

my $str='a=1 b=2 c=abc';
my @v;
while ($str =~ /=(\S+)/g) {
    push @v, $1;
}
print join (',', @v);
    • Il n'y a pas besoin de boucle. Vous pouvez prendre tous les matchs à la fois en utilisant m//g dans un contexte de liste.
    InformationsquelleAutor Marius Kjeldahl
  8. 0

    Perl est certainement le bon outil pour cela.

    
#! /usr/bin/perl

$str = "field1=1 field2=2 field3=abc";
$str =~ /field1=(\S+)\ field2=(\S+)\ field3=(\S+)/;
print "$1,$2,$3", "\n";
    • et regexp n'est pas 🙂
    InformationsquelleAutor Dima
  9. 0
    my $a = "field1=1 field2=2 field3=abc";
my @f = split /\s*\w+=/, $a;
shift(@f);
print join(",", @f), "\n";
    InformationsquelleAutor Alex Pavlov
  10. 0
    $string="field1=1 field2=2 field3=abc";
@s=split /\s+/,$string;
$temp=$s[1];$s[1]=$s[0];$s[0]=$temp;
foreach (@s){s/.*=//; push(@a,$_ );}
print join(",",@a);
    InformationsquelleAutor ghostdog74
  11. 0

    Si vous avez réellement besoin à la fois les clés et les valeurs. Je voudrais les mettre dans une table de hachage. Vous pourriez tout simplement la capture des deux côtés de la "=", et de le mettre directement dans la table de hachage.

    use strict;
use warnings;

my $str = 'field1=1 field2=2 field3=abc';

my %fields = $str =~ / (\S+) \s* = \s* (\S+) /xg;

use YAML;
print Dump \%fields
    --- 
champ1: 1 
champ2: 2 
champ3: abc

    Pour de plus amples informations, veuillez lire perldoc perlre.

    Si vous êtes juste un débutant, vous voudrez peut-être lire perldoc perlretut.

    InformationsquelleAutor Brad Gilbert