Comment puis-je faire une boucle par un sous-ensemble de feuilles de calcul?

Je sais comment faire une boucle sur toutes les feuilles de calcul dans un classeur, et comment quitter une fois que j'atteins un "drapeau" de la feuille de calcul:

For Each ThisWorkSheet In Worksheets
   If ThisWorkSheet.Name = "FlagEnd" Then Exit For
   MsgBox "This worksheet name is: " & ThisWorkSheet.Name
Next

Cependant je ne peux pas obtenir de la boucle pour commencer sur une "start-drapeau" de la feuille de calcul (ou encore mieux sur la feuille de calcul à droite après le début du pavillon de la feuille de calcul. Par exemple, le pavillon de début/fin les feuilles de calcul sont au milieu d'un tas d'autres feuilles de calcul, ainsi, au début ou à la fin de la traversée n'est pas réalisable.

Il pourrait y avoir des centaines de feuilles de calcul avant que "FlagStart de la fiche", donc j'ai vraiment besoin pour démarrer sur le droit de la feuille.

Essayé:

Set ThisWorkSheet = Sheets("FlagNew")

For Each Sheets("FlagNew") In Worksheets

Idées?

Solution:
Mathias était très proche, mais dendarii a été le petit pas de plus avec la fin de l'index. J'ai effectivement trouvé ma solution finale sur mon propre, mais je voulais donner du crédit. C'était ma solution finale:

Private Sub CommandButtonLoopThruFlaggedSheets_Click()
    ' determine current bounds
    Dim StartIndex, EndIndex, LoopIndex As Integer
    StartIndex = Sheets("FlagNew").Index + 1
    EndIndex = Sheets("FlagEnd").Index - 1

    For LoopIndex = StartIndex To EndIndex
        MsgBox "this worksheet is: " & Sheets(LoopIndex).Name
        ' code here
    Next LoopIndex
End Sub

Kirk, vous ne pouvez pas être conscient de cela, mais si vous déclarez des 3 variables sur la même ligne avec un seul type à la fin, la dernière variable prend réellement ce type, les autres terminent comme des variantes. Si vous allez avoir toutes vos déclarations sur une ligne, vous devez spécifier "Dim StartIndex Entier, EndIndex Entier, LoopIndex Entier".
Doh, gravé moi-même avec les raccourcis de nouveau! Merci je n'étais pas au courant de cela, je vais le changer.

OriginalL'auteur Kirk Hings | 2009-10-19

2

Si ce n'est pas particulièrement changeant classeur (c'est à dire les feuilles de calcul ne sont pas ajoutés et supprimés de tous les temps), vous pouvez stocker les noms des feuilles de calcul dans une plage sur une feuille masquée et boucle à travers eux par leur nom.

Cependant, il semble comme ils sont stockés de manière consécutive dans le classeur ainsi, en s'appuyant sur Mathias solution, vous pouvez utiliser une fonction pour renvoyer les indices de début et de fin des feuilles de calcul et ensuite faire une boucle par:
```
Public Function GetStartIndex() As Integer
    On Error Resume Next
    GetStartIndex = ThisWorkbook.Worksheets("MyStartingWorksheet").Index + 1
End Function

Public Function GetEndIndex() As Integer
    On Error Resume Next
    GetEndIndex = ThisWorkbook.Worksheets("MyEndingWorksheet").Index - 1
End Function

Sub LoopThrough()

    Dim wks As Worksheet
    Dim i As Integer
    Dim iStart As Integer
    Dim iEnd As Integer

    iStart = GetStartIndex()
    iEnd = GetEndIndex()

    If iStart > 0 And iEnd > 0 And iEnd > iStart Then
        For i = iStart To iEnd
            Set wks = ThisWorkbook.Worksheets(i)
            MsgBox wks.Name
        Next i
    End If

End Sub
```
Mathias était très proche, mais cela a été le petit pas de plus avec la fin de l'index. J'ai effectivement trouvé ma solution finale sur mon propre, mais je voulais donner le crédit ici. Private Sub CommandButtonLoopThruFlaggedSheets_click() ' déterminer les limites actuelles Dim StartIndex, EndIndex, LoopIndex int StartIndex = Sheets("FlagNew").Index + 1 EndIndex = Sheets("FlagEnd").Index - 1 Pour LoopIndex = StartIndex À EndIndex MsgBox "cette feuille de calcul est:" & Feuilles(LoopIndex).Nom de code " ici, à Côté LoopIndex End Sub
(solution éditée dans la question initiale avec le code de mise en forme)
Je vois que vous avez mis en place une bonne fonction. Je voudrais suggérer quelques choses bien. Je vous suggère de prendre le nom de la feuille pour lequel vous souhaitez trouver l'index, comme un argument dans la fonction. En ne prenant aucune arguments, vous avez fait la fonction statique; vous pourriez aussi bien pu écrire ces deux lignes dans votre main sous. Ensuite, utilisez les feuilles de la collection pour obtenir l'index, parce que, le code peut ne pas fonctionner comme vous l'attendez, lorsque le classeur contient des feuilles de graphique.

OriginalL'auteur dendarii
2

Je crois que si vous utilisez "foreach" vous n'avez aucun contrôle sur la feuille de départ. D'ailleurs, je ne suis même pas sûr de vous garantir l'ordre dans lequel l'itération aura lieu.

Je pense que ce que vous devez faire est d'abord, obtenir l'index de la feuille qui vous intéressent (obtenir la feuille en nom, et d'obtenir son index), puis effectuer une itération à l'aide d'une boucle for, sur l'index des plaques commençant le drapeau à la feuille d'index.

[Edit: j'ai piraté par un exemple rapide]
```
Sub Iterate()

Dim book As Workbook
Dim flagIndex As Integer
Dim flagSheet As Worksheet

Set book = ActiveWorkbook
Set flagSheet = book.Worksheets("Sheet3")
flagIndex = flagSheet.Index

Dim sheetIndex As Integer
Dim currentSheet As Worksheet

For sheetIndex = flagIndex To book.Worksheets.Count
    Set currentSheet = book.Worksheets(sheetIndex)
Next

End Sub
```
Vous êtes correct. Les feuilles de calcul sont une collection de la feuille. Vous ne savez pas où il est.

OriginalL'auteur Mathias
1

Comment?
```
For Each ThisWorkSheet In Worksheets  
    If ThisWorkSheet.Name = "FlagStart" Then output = true 
    If ThisWorkSheet.Name = "FlagEnd" Then Exit For   
    If output = true Then MsgBox "This worksheet name is: " & ThisWorkSheet.Name
Next
```
Ce code peut ne pas être tout à fait juste. Je vais écrire dans l'éditeur de ne pas VBA, mais vous obtenez l'idée.

J'aurais dû en parler j'ai pensé à ça, mais ce n'est pas assez efficace. Il pourrait y avoir des centaines de feuilles de calcul en face de la FlagStart feuille de calcul. J'aurais vraiment préféré la feuille de calcul. Merci bien!
Bois - optimisation prématurée va vous mordre! Je vous conseille d'obtenir une solution de travail d'abord, puis de chercher des moyens de l'optimiser. Aussi, je serais inquiet d'avoir des centaines de feuilles. Est Excel le meilleur outil?
les bons points, en fait, je suis l'optimisation de la solution qu'ils utilisent déjà. actuellement, ils copier coller un tas de ce genre de choses et nous essayons de l'automatiser pour eux. je suppose que je exagérée à des centaines, mais il peut y avoir des dizaines de feuilles, et, malheureusement, ils varient en nombre et les noms de feuilles. je suis en train d'essayer ces solutions dès maintenant. j'ai frappé à l'aide de l'index, hier, après la publication de ce problème.

OriginalL'auteur Ade Miller
0

Faire les fiches que vous itérer sur ont un nom commun format?

Ex)
```
Sheets(0).name > "Reports"
Sheets(1).name > "Start Here"
Sheets(2).name > "emp.0001"
Sheets(3).name > "emp.0002"
Sheets(4).name > "emp.0003"
Sheets(5).name > "emp.0004"
Sheets(6).name > "End Here"
```
Si oui, dans votre pour chaque boucle, il suffit de faire une Left(ThisWorkSheet.name, 4) = "emp" pour vérifier si c'est une feuille que vous souhaitez référencer.

OriginalL'auteur JakeTheSnake

En VBA Excel 2013 si vous avez des feuilles de calcul que vous souhaitez mettre à jour entre les onglets "Blankfirst" et "Blanklast" cela fonctionne.

Utiliser le code ci-dessous pour tester ramène à votre onglet noms et puis replacer la manipulation de code à la place de MsgBox wks.Name partie.

Sub Macro2()

    On Error Resume Next
    GetStartIndex = ThisWorkbook.Worksheets("Blankfirst").Index + 1

    On Error Resume Next
    GetEndIndex = ThisWorkbook.Worksheets("Blanklast").Index - 1

    Dim wks As Worksheet
    Dim i As Integer
    Dim iStart As Integer
    Dim iEnd As Integer

    iStart = GetStartIndex
    iEnd = GetEndIndex


    If iStart > 0 And iEnd > 0 And iEnd > iStart Then
        For i = iStart To iEnd
            Set wks = ThisWorkbook.Worksheets(i)
            MsgBox wks.Name
        Next i
    End If

End Sub

OriginalL'auteur Samir

-1

 Public Sub ITERATE_WORKSHEETS()  
   On Error Resume Next    
   Dim x As Long  
         For x = 0 To 100  
              MsgBox Worksheets(x).Name  
         Next x   
   On Error GoTo 0  
   MsgBox "all done"  
 End Sub

Ne pas poster juste le code, veuillez fournir une explication.

OriginalL'auteur Rob

Vous devez vous connecter pour publier un commentaire.