Comment puis-je générer une liste séparée par des virgules avec XSLT/XPath?

Compte tenu de ces données XML:

<root> 
<item>d'apple</item> 
<item>orange</item> 
<item>banane</item> 
</root>

Je peux utiliser cette XSLT balisage:

... 
<xsl:for-each select="root/item"> 
<xsl:value-of select="."/>, 
</xsl:for-each> 
...

pour obtenir ce résultat:

pomme, orange, banane,

mais comment puis-je produire une liste où la dernière virgule n'est pas présent? Je suppose qu'il peut être fait de faire quelque chose le long des lignes de:

... 
<xsl:for-each select="root/item"> 
<xsl:value-of select="."/> 
<xsl:if test="...">,</xsl:si> 
</xsl:for-each> 
...

mais ce qui devrait le test d'expression?

J'ai besoin de quelques façon de déterminer combien de temps la liste est et où je suis actuellement dans la liste, ou, à défaut, si je suis en train de traiter le dernier élément dans la liste (ce qui signifie que je ne se soucient pas combien de temps il est ou de ce que la position actuelle est).

InformationsquelleAutor Anders Sandvig | 2009-03-20

25

Prendre un coup d'oeil à la position(), count() et last() fonctions; par exemple, test="position() < last()".
- C'est exactement ce que je cherchais, merci! Où est le truc comme il est documenté de toute façon? Le XPath spec?
- Jetez un oeil à w3schools.com/xpath ils ont un couple de grands aperçus de base de la syntaxe xpath et de capacités.
- J'ai cette ligne: <xsl:value-of select="@Courses"/> qui affiche tous les CSV, mais il n'a pas l'air trop convivial. Est-il possible de la place de la virgule, séparez-les par une nouvelle ligne pour chaque valeur?
- Veuillez créer une nouvelle question pour que.
InformationsquelleAutor Willie Wheeler
53

C'est un joli modèle commun:
```
<xsl:for-each select="*">
   <xsl:value-of select="."/>
   <xsl:if test="position() != last()">
      <xsl:text>,</xsl:text>
   </xsl:if>
</xsl:for-each>
```
- J'ai mis à jour ma réponse pour refléter votre commentaire à lui 🙂
- Cette échoue si l'une des valeurs que vous avez à parcourir sont vides. Cela aura pour résultat de fuite - ou double-virgules.
- Je ne dirais pas que le défaut, mais plutôt un manque if not empty 🙂
- Pour le "si", j'ai utilisé: <xsl:if test="following-sibling::*" xml:space="preserve">, </xsl:si>
InformationsquelleAutor Robert Rossney
11

Pour une transformation XSLT 2.0 option, vous pouvez utiliser le separator attribut sur xsl:value-of.

Ce xsl:value-of:
```
<xsl:value-of select="/root/item" separator=", "/>
```
d'obtenir ce résultat:
```
apple, orange, banana
```
Vous pouvez également utiliser plus que juste une virgule comme séparateur. Par exemple, ceci:
```
<xsl:text>'</xsl:text>
<xsl:value-of select="/root/item" separator="', '"/>
<xsl:text>'</xsl:text>
```
Serait de produire le résultat suivant:
```
'apple', 'orange', 'banana'
```
Un autre XSLT 2.0 option est string-join()...
```
<xsl:value-of select="string-join(/*/item,', ')"/>
```
InformationsquelleAutor Daniel Haley
9
```
<xsl:if test="following-sibling::*">,</xsl:if>
```
ou (peut-être plus efficace, mais vous auriez à tester):
```
<xsl:for-each select="*[1]">
   <xsl:value-of select="."/>
   <xsl:for-each select="following-sibling::*">
       <xsl:value-of select="concat(',',.)"/>
   </xsl:for-each>
</xsl:for-each>
```
- Pourriez-vous donner des précisions sur ce que ce test est en train de faire?
- le quelque chose:: indique un axe - dans ce cas, la suite-frère de l'axe. Il existe différents axes suivants-frère de l'axe est ces nœuds ayant le même parent qui suivent le nœud courant dans l'ordre du document. Cela vérifie l'existence de ces nœuds. Si il n'y a pas tout, nous sommes le dernier.
- Ce qui fonctionne, mais "position()=last()" n'a pas à construire un node-set, puis le tester. Le processeur XSLT peut ne pas être assez intelligent pour savoir qu'il n'est pas besoin de compiler une liste de chaque nœud suivant, et si il le fait, que fait un (gros) O(n^2) opération.
- (Bien sûr, je voulais dire "position() != last()". Le diable est dans les détails.)
- Je vais poster une alternative, alors ;-p
- Quels seraient les avantages/inconvénients de ce type par rapport à la @RobertRossney version?
InformationsquelleAutor Marc Gravell
7

Un simple XPath 1.0 one-liner:

concat(., substring(',', 2 - (position() != last())))

Mettre dans cette transformation:
```
<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

    <xsl:template match="/*">
      <xsl:for-each select="*">
        <xsl:value-of select=
         "concat(., substring(',', 2 - (position() != last())))"
         />
      </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>
```
et de l'appliquer au document XML:
```
<root>
    <item>apple</item>
    <item>orange</item>
    <item>banana</item>
</root>
```
pour obtenir le résultat voulu:

apple,orange,banana

EDIT:

Voici un commentaire de Robert Rossney à cette réponse:

C'est assez opaque code pour un homme
pour lire. Il nécessite de connaître deux
la non-évidence de choses sur XSLT: 1) quelles sont les
la fonction substring si son
l'indice est hors de la plage et 2) que
les valeurs logiques peuvent être implicitement
converti aux valeurs numériques.

et voici ma réponse:

Les gars, n'ayant pas peur d'apprendre quelque chose de nouveau. En fait, c'est tout Débordement de la Pile est d'environ, n'est-ce pas? 🙂
- C'est assez opaque code pour un être humain de lire. Il nécessite de connaître deux choses moins évidentes sur XSLT: 1) quelle est la fonction substring si son indice est hors de la plage et 2) que les valeurs logiques peuvent être implicitement converti en valeurs numériques.
- Robert-Rossney Sûr, une partie de sa valeur est exactement dans ce!
InformationsquelleAutor Dimitre Novatchev
7

Robert a donné la classis not(position() = last()) réponse. Cela vous oblige à traiter l'intégralité du nœud actuel de la liste pour obtenir la taille du contexte, et en grande documents d'entrée de ce qui pourrait faire la conversion consomment plus de mémoire. Donc, j'ai l'habitude d'inverser le test pour être la première chose
```
<xsl:for-each select="*">
  <xsl:if test="not(position() = 1)>, </xsl:if>
  <xsl:value-of select="."/>   
</xsl:for-each>
```
- Je suis en train de penser à pourquoi vous ne voulez pas le faire, et ne pas venir avec une raison.
- position()!=last() ne fonctionnera pas si vous souhaitez exclure certains éléments de la séquence. Par exemple, qu'arriverait-il si a une liste comme ceci: <liste> <d'apple>délicieux</apple> <banane>dole</banane> <orange>navel</orange> </liste> avec le template <template match="orange"/> exclure les oranges.
- si vous ne pouvez pas omettre les oranges dans l'instruction select, puis des solutions à la position() ne fonctionnera pas. Cependant, dans ces questions, il n'y a pas de modèle de base de exlucedes, donc ça ne s'applique pas ici.
- Un processeur peut être en mesure d'optimiser un position()=last() test utiliser une seule étape d'anticipation, mais la solution de mettre un séparateur avant chaque élément, à l'exception de la première est certainement préférable, parce que (a) il ne comporte aucune anticipation à tous, et (b) il évite toute confiance sur les smart optimisation.
InformationsquelleAutor jelovirt

C'est la façon dont je l'ai eu à travailler pour moi.
J'ai testé ce à l'encontre de votre liste:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />

<xsl:template match="root">
    <xsl:call-template name="comma-join"><xsl:with-param name="list" select="item"/></xsl:call-template>
</xsl:template>

<xsl:template name="comma-join">
    <xsl:param name="list" />
    <xsl:for-each select="$list">
        <xsl:value-of select="." />
        <xsl:if test="position() != last()">
            <xsl:text>, </xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template> 
</xsl:stylesheet>

InformationsquelleAutor Louise Rogow Howard

Vous devez vous connecter pour publier un commentaire.