Comment puis-je lire les 2 dernières lignes d'un fichier dans le script de commandes

J'ai un programme Java qui ajoute de nouvelles versions de l'information dans les deux dernières lignes d'un fichier.
Comment puis-je les ai lus dans le fichier batch?

Ce code ne vous ont jusqu'à présent?
je n'ai rien..
Si vous avez accès au Kit de Ressources de Windows, je n'hésiterais pas à utiliser les tail pour ce faire.

OriginalL'auteur Joshi | 2014-12-11

  1. 4

    Ce segment de code faire l'affaire...

    for /F "delims=" %%a in (someFile.txt) do (
   set "lastButOne=!lastLine!"
   set "lastLine=%%a"
)
echo %lastButOne%
echo %lastLine%

    MODIFIER: la QUEUE Complète.Chauve-souris ajouté

    Cette méthode peut être modifié dans le but d'obtenir un plus grand nombre de lignes, qui peut être spécifiée par un paramètre. Le fichier ci-dessous est queue.chauve-souris:

    @echo off
setlocal EnableDelayedExpansion

rem Tail command in pure Batch: Tail.bat filename numOfLines
rem Antonio Perez Ayala

for /F "delims=" %%a in (%1) do (
   set /A i=%2, j=%2-1
   for /L %%j in (!j!,-1,1) do (
      set "lastLine[!i!]=!lastLine[%%j]!
      set /A i-=1
   )
   set "lastLine[1]=%%a"
)
for /L %%i in (%2,-1,1) do if defined lastLine[%%i] echo !lastLine[%%i]!

    2ÈME EDITION: Nouvelle version de la QUEUE.Chauve-souris ajouté

    La version ci-dessous est plus efficace:

    @echo off
setlocal EnableDelayedExpansion

rem Tail command in pure Batch, version 2: Tail.bat filename numOfLines
rem Antonio Perez Ayala

set /A firstTail=1, lastTail=0
for /F "delims=" %%a in (%1) do (
   set /A lastTail+=1, lines=lastTail-firstTail+1
   set "lastLine[!lastTail!]=%%a"
   if !lines! gtr %2 (
      set "lastLine[!firstTail!]="
      set /A firstTail+=1
   )
)
for /L %%i in (%firstTail%,1,%lastTail%) do echo !lastLine[%%i]!
    Belle façon sans complication ou de fichier temp. Serait plus difficile avec plus de lignes à l'écho.
    Pas vraiment. Voir la modifier...
    Je pense que le mal de tête est à venir... 😉
    Ou deux! Voir la deuxième édition... ;-)

    OriginalL'auteur Aacini

  2. 2

    Cela va résoudre le problème, où someFile.txt est le fichier où vous voulez le lire sur les lignes à partir de:

    for /f %%i in ('find /v /c "" ^< someFile.txt') do set /a lines=%%i
echo %lines%
set /a startLine=%lines% - 2
more /e +%startLine% someFile.txt > temp.txt
set vidx=0
for /F "tokens=*" %%A in (temp.txt) do (
    SET /A vidx=!vidx! + 1
    set localVar!vidx!=%%A
)
echo %localVar1%
echo %localVar2%
del temp.txt

    OriginalL'auteur Joshi

  3. 1
    ::change the values bellow with a relevant ones.
set "file=C:\some.file"
set "last_lines=2"


for /f %%a in ('findstr /R /N "^" "%file%" ^| find /C ":"') do @set lines=%%a
set /a m=lines-last_line
more +%m% "%file%"

    Directement à partir de la ligne de commande:

    C:\>set "file=C:\some.file"
C:\>set "last_lines=5"
C:\>(for /f %a in ('findstr /R /N "^" "%file%" ^| find /C ":"') do @set lines=%a)&@set /a m=lines-last_lines&call more +%m% "%file%"

    OriginalL'auteur npocmaka