Comment puis-je lire les 64 bits du Registre des valeurs à partir de VBScript running comme une msi après son installation?

J'ai besoin de lire l'emplacement de la Temporaire ASP.NET dossier de Fichiers à partir de VBScript dans le cadre d'un post-tâche d'installation dans un programme d'installation créé à l'aide de Visual Studio 2008 projet de déploiement.

J'ai pensé que je ferais quelque chose comme ceci:

Set oShell = CreateObject("Wscript.Shell")
strPath = oShell.RegRead("HKLM\SOFTWARE\Microsoft\ASP.NET.0.50727.0\Path")

et puis concaténer strPath avec "\Temporary ASP.NET les Fichiers" et être fait avec elle.

Sur un système x64, cependant, j'obtiens la valeur de la WOW6432Node (HKLM\SOFTWARE\Wow6432Node\Microsoft\ASP.NET\2.0.50727.0), qui me donne la version 32 bits de cadre (chemin C:\Windows\Microsoft.NET\Framework\v2.0.50727), mais sur un système x64, je veux en fait le chemin d'accès 64 bits, c'est à dire C:\Windows\Microsoft.NET\Framework64\v2.0.50727.

Je comprends que cela arrive à cause de la .vbs fichier est exécuté en utilisant les 32 bits de l'hôte de script en raison du processus parent (l'installateur) 32-bits.

Comment puis-je exécuter le script à l'aide de la version 64 bits de l'hôte de script - ou - comment puis-je lire les valeurs de 64 bits, même si le script est exécuté à l'aide de la 32 bits de l'hôte de script?

OriginalL'auteur Joergen Bech | 2009-08-04

  1. 9

    Pas sûr au sujet du lancement de la version 64 bits de l'hôte de script version, mais vous devriez être en mesure d'accéder à la version 64 bits du registre à partir de la 32 bits de l'hôte de script à l'aide de WMI StdRegProv classe, comme ceci:

    Const HKEY_LOCAL_MACHINE = &H80000002
sPath = ReadRegStr (HKEY_LOCAL_MACHINE, "SOFTWARE\Microsoft\ASP.NET.0.50727.0", "Path", 64)
WScript.Echo sPath

' Reads a REG_SZ value from the local computer's registry using WMI.
' Parameters:
'   RootKey - The registry hive (see http://msdn.microsoft.com/en-us/library/aa390788(VS.85).aspx for a list of possible values).
'   Key - The key that contains the desired value.
'   Value - The value that you want to get.
'   RegType - The registry bitness: 32 or 64.
'
Function ReadRegStr (RootKey, Key, Value, RegType)
    Dim oCtx, oLocator, oReg, oInParams, oOutParams

    Set oCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
    oCtx.Add "__ProviderArchitecture", RegType

    Set oLocator = CreateObject("Wbemscripting.SWbemLocator")
    Set oReg = oLocator.ConnectServer("", "root\default", "", "", , , , oCtx).Get("StdRegProv")

    Set oInParams = oReg.Methods_("GetStringValue").InParameters
    oInParams.hDefKey = RootKey
    oInParams.sSubKeyName = Key
    oInParams.sValueName = Value

    Set oOutParams = oReg.ExecMethod_("GetStringValue", oInParams, , oCtx)

    ReadRegStr = oOutParams.sValue
End Function

    NB: je suis sous 32-bit OS en ce moment, ne peut donc pas vérifier que cet exemple fonctionne. Méfiez-vous des bugs 🙂

    Voir aussi la Demandant de Données WMI sur une Plate-forme 64 bits article MSDN pour plus d'info sur le sujet.

    Comment tu fais, mais à vérifier uniquement une clé, n'est pas une valeur?? (Ex: voir si "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0" existe, mais pas la valeur de "Path"
    Vous devez appeler EnumKey au lieu de GetStringValue (avec les paramètres appropriés) et de vérifier si oOutParams.ReturnValue est de 0. Aussi, voir les réponses à cette question: Vérifiez si la clé de registre existe.
    Sinon, vous pouvez interroger la valeur standard oReg.GetStringValue , "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0", , stdv et de vérifier ensuite IsNull(stdv). Technique inspirée de Les scripteurs

    OriginalL'auteur Helen

  2. 0

    Je pense que quelque chose comme cela, mais je n'ai pas trié comment traiter les valeurs de sortie.

    strComputer = "."
Const HKLM = &h80000002
Set objCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
objCtx.Add "__ProviderArchitecture", 64
objCtx.Add "__RequiredArchitecture", TRUE
Set objLocator = CreateObject("Wbemscripting.SWbemLocator")
Set objServices = objLocator.ConnectServer("","root\default","","",,,,objCtx)
Set objStdRegProv = objServices.Get("StdRegProv") 

' Use ExecMethod to call the GetStringValue method
Set Inparams = objStdRegProv.Methods_("EnumValues").Inparameters
Inparams.Hdefkey = HKLM
Inparams.Ssubkeyname = "SOFTWARE\Microsoft\Microsoft SQL Server\Instance Names\SQL\"
'Inparams.Svaluename = "Logging"
set Outparams = objStdRegProv.ExecMethod_("EnumValues", Inparams,,objCtx)

'Show output parameters object and the registry value HKLM\SOFTWARE\
WScript.Echo Outparams.GetObjectText_
WScript.Echo "WMI Logging is set to  " & Outparams.SValue

    OriginalL'auteur Eathen Rentz

  3. 0

    À l'aide de Microsoft documenté de l'approache, Helen réponse est tout à fait correcte.

    Cependant, selon mes propres tests, il s'avère que, il suffit d'indiquer le __ProviderArchitecture contexte drapeau uniquement au moment de la connexion à la StdRegProv prestataire est établi.

    Cela rend les choses beaucoup plus simple que seule la mise en place le prestataire doit être encapsulé dans une fonction distincte, sinon, on peut l'utilisation de l'API.

    set reg64 = MakeRegLocator(64)
reg64.GetStringValue , "SOFTWARE\Microsoft\ASP.NET.0.50727.0", "Path", path

WScript.Echo path

' Establish a connection to the local 32 or 64 bit registry hive as requested.
' Parameters:
'   RegType - The registry bitness: 32 or 64.
function MakeRegLocator(bitness)
    set ctx = CreateObject("WbemScripting.SWbemNamedValueSet")
    ctx.Add "__ProviderArchitecture", bitness

    set locator = CreateObject("Wbemscripting.SWbemLocator")
    set services = locator.ConnectServer("", "root\default", "", "", , , , ctx)
    set reg = services.Get("StdRegProv")

    set MakeRegLocator = reg
end function

    OriginalL'auteur klaus triendl

  4. -1

    Veuillez Vérifier:

    Set oShell = CreateObject("Wscript.Shell")
    strPath = oShell.RegRead("HKLM64\SOFTWARE\Microsoft\ASP.NET\2.0.50727.0\Path")

    https://www.autoitscript.com/autoit3/docs/functions/RegRead.htm

    Script AutoIt n'est pas VBScript, les fonctions ne sont pas les mêmes

    OriginalL'auteur Pawan Kumar