Comment puis-je obtenir l'adresse MAC d'une carte réseau à l'aide de Delphi?

Comme par titre - quelqu'un peut-il m'aider?

OriginalL'auteur Charles Faiga | 2009-02-23

  1. 16

    Obtenir le JEDI conversion de Microsoft IP Helper Bibliothèque de la Projet JEDI API en-Tête de la Bibliothèque - le fichier est IPHlpAPI.zip. Décompresser les fichiers, vous avez besoin IpTypes.pas et IpHlpApi.pas. Ensuite, vous pouvez utiliser quelque chose comme ceci:

    procedure TForm1.Button1Click(Sender: TObject);
var
  NumInterfaces: Cardinal;
  AdapterInfo: array of TIpAdapterInfo;
  OutBufLen: ULONG;
  i: integer;
begin
  GetNumberOfInterfaces(NumInterfaces);
  SetLength(AdapterInfo, NumInterfaces);
  OutBufLen := NumInterfaces * SizeOf(TIpAdapterInfo);
  GetAdaptersInfo(@AdapterInfo[0], OutBufLen);

  Memo1.Lines.Clear;
  for i := 0 to NumInterfaces - 1 do begin
    Memo1.Lines.Add(Format('%.2x:%.2x:%.2x:%.2x:%.2x:%.2x',
      [AdapterInfo[i].Address[0], AdapterInfo[i].Address[1],
       AdapterInfo[i].Address[2], AdapterInfo[i].Address[3],
       AdapterInfo[i].Address[4], AdapterInfo[i].Address[5]]));
  end;
end;

    (Toute erreur de manipulation omis, vous devez l'ajouter, bien sûr.)

    Je l'ai utilisé et pour moi, il donne tous les MAC adresse 00:00:00:00:00:00 . Que pourrais-je fait de mal? J'ai utilisé OutBufLen Cardinal au lieu de ULONG comme mentionné ici.
    Il n'y a pas de vérification des erreurs de toute sorte, et c'est peut-être juste rempli par des zéros (non initialisée) de la mémoire après l'échec d'un appel d'API. Essayez d'ajouter une case pour le résultat de GetAdaptersInfo(). Aussi, essayez d'exécuter la présente en tant qu'administrateur.
    IPHlpAPI.zip n'est plus disponible. Où pourrais-je le trouver?
    utilisez cette url: github.com/project-jedi/website/tree/master/delphi-jedi.org/www/...

    OriginalL'auteur mghie

  2. 1

    La GetAdaptersAddresses fonction est le moyen privilégié pour obtenir des cartes d'information depuis 2001 avec Windows XP.

    La carte de l'information est retournée dans la IP_ADAPTER_ADDRESSES structure par le AdapterAddresses paramètre.

    La GetAdaptersAddresses fonction peut extraire de l'information pour IPv4 et IPv6 adresses.

    La méthode recommandée pour l'appel de la GetAdaptersAddresses fonction est à pré-allouer un 15 KO de travail du tampon pointé par le AdapterAddresses paramètre. Sur les ordinateurs, cela réduit considérablement les chances que les GetAdaptersAddresses fonction renvoie ERROR_BUFFER_OVERFLOW, qui aurait besoin d'appeler GetAdaptersAddresses fonction plusieurs fois.

    procedure TForm1.Button1Click(Sender: TObject);
const
AF_UNSPEC = 0;
GAA_FLAG_INCLUDE_ALL_INTERFACES = $100;
WORKING_BUFFER_SIZE = 15000;
MAX_TRIES = 3;
var
pAddresses,
pCurrAddresses: PIpAdapterAddresses;
dwRetVal,
outBufLen: Cardinal;
i: Integer;
macAddress: string;
begin
Memo1.Lines.Clear;
outBufLen := WORKING_BUFFER_SIZE;
pAddresses := nil;
i := 0;
repeat
if Assigned(pAddresses) then
FreeMem(pAddresses);
GetMem(pAddresses, outBufLen);
if not Assigned(pAddresses) then
raise Exception.Create('Memory allocation failed for IP_ADAPTER_ADDRESSES struct');
dwRetVal := GetAdaptersAddresses(AF_UNSPEC, GAA_FLAG_INCLUDE_ALL_INTERFACES, nil, pAddresses, @outBufLen);
Inc(i);
until (dwRetVal <> ERROR_BUFFER_OVERFLOW) or (i = MAX_TRIES);
try
if NO_ERROR <> dwRetVal then begin
if ERROR_NO_DATA = dwRetVal then begin
MessageDlg('No addresses were found for the requested parameters', mtInformation, [mbOK], 0);
Exit;
end
else
raise Exception.Create(SysErrorMessage(dwRetVal));
end;
pCurrAddresses := pAddresses;
while Assigned(pCurrAddresses) do begin
if pCurrAddresses^.PhysicalAddressLength > 0 then begin
Memo1.Lines.Add(pCurrAddresses^.FriendlyName);
macAddress := '';
for i := 0 to pCurrAddresses^.PhysicalAddressLength - 1 do begin
if i > 0 then
macAddress := macAddress + ':';
macAddress := macAddress + Format('%.2X', [pCurrAddresses^.PhysicalAddress[i]]);
end;
Memo1.Lines.Add(macAddress);
Memo1.Lines.Add('');
end;
pCurrAddresses := pCurrAddresses^.Next;
end;
finally
if Assigned(pAddresses) then
FreeMem(pAddresses);
end;
end;

    OriginalL'auteur fantaghirocco

  3. -3

    sans savoir presque rien à propos de delphi, comment sur l'exécution de %system32%\ipconfig.exe /tous et l'analyse de la sortie?

    La sortie peut être localisé afin de l'analyse, il faudrait tester sur différentes versions de Windows (de l'Afghanistan au Zimbabwe
    Pire approche possible, en plus de la localisation de la sortie peut changer entre les versions de Windows, en plus de l'IPv6, en sus des cartes réseau et il n'y a pas d'erreur de manipulation.

    OriginalL'auteur Aleksandar Ivanisevic