Comment puis-je obtenir le jour, le mois et l'année à partir d'un Windows cmd.exe script?

Une variante de script qui fonctionne paramètres régionaux de façon indépendante. Le mettre dans un fichier texte .cmd extension et de l'exécuter.

::: Begin set date

for /f "tokens=1-4 delims=/-. " %%i in ('date /t') do (call :set_date %%i %%j %%k %%l)
goto :end_set_date

:set_date
if "%1:~0,1%" gtr "9" shift
for /f "skip=1 tokens=2-4 delims=(-)" %%m in ('echo,^|date') do (set %%m=%1&set %%n=%2&set %%o=%3)
goto :eof

:end_set_date
::: End set date

echo day in 'DD' format is %dd%; month in 'MM' format is %mm%; year in 'YYYY' format is %yy%

Les variables %dd%, %mm% et %aa% gardera le jour ("DD" format), le mois ("MM") et l'année ("AAAA" format) respectivement.

Le lot suivant de code renvoie les composants de la date actuelle dans un jeu de paramètres régionaux manière indépendante et magasins le jour, le mois et l'année dans les variables CurrDay, CurrMonth et CurrYear, respectivement:

for /F "skip=1 delims=" %%F in ('
    wmic PATH Win32_LocalTime GET Day^,Month^,Year /FORMAT:TABLE
') do (
    for /F "tokens=1-3" %%L in ("%%F") do (
        set CurrDay=0%%L
        set CurrMonth=0%%M
        set CurrYear=%%N
    )
)
set CurrDay=%CurrDay:~-2%
set CurrMonth=%CurrMonth:~-2%
echo Current day  :  %CurrDay%
echo Current month:  %CurrMonth%
echo Current year :%CurrYear%

Il y a deux imbriqués for /F boucles pour contourner un problème avec le wmic de commande, dont la sortie est au format unicode; à l'aide d'une seule boucle résultats supplémentaires dans transport-retour caractères qui les impacts de la bonne extension variable.

Depuis le premier jour et le mois peut également être constitué d'un seul chiffre seulement, j'ai ajouté un zéro 0 dans la boucle de construire. Par la suite, les valeurs sont taillées pour toujours composé de deux chiffres.

LANGUE DE L'INDÉPENDANCE:

L'Andrei Coscodan solution est dépendant d'une langue, donc une façon d'essayer de le résoudre est de réserver toutes les balises pour chaque champ: année, mois et jour sur les langues cibles. Envisager Portugais et en anglais, d'après l'analyse final défini comme:

set Year=%yy%%aa%
set Month=%mm%
set Day=%dd%

Recherchez le paramètre de l'année, j'ai utilisé les balises de l'anglais et du portugais, il a travaillé pour moi, au Brésil, où nous avons ces deux langues les plus courantes dans les installations de Windows. J'espère que cela fonctionnera aussi pour certaines langues avec origine latine comme le français, l'espagnol, et ainsi de suite.

Bien, le script intégral pourrait être:

@echo off
setlocal enabledelayedexpansion

:: Extract date fields - language dependent
for /f "tokens=1-4 delims=/-. " %%i in ('date /t') do (
        set v1=%%i& set v2=%%j& set v3=%%k
        if "%%i:~0,1%%" gtr "9" (set v1=%%j& set v2=%%k& set v3=%%l)

        for /f "skip=1 tokens=2-4 delims=(-)" %%m in ('echo.^|date') do (
            set %%m=!v1!& set %%n=!v2!& set %%o=!v3!
    )
)

:: Final set for language independency (English and Portuguese - maybe works for Spanish and French)
set year=%yy%%aa%
set month=%mm%
set day=%dd%


:: Testing
echo Year:[%year%] - month:[%month%] - day:[%day%]

endlocal
pause

J'espère que cela aide quelqu'un qui traitent de différentes langues.

Cette variante fonctionne pour toutes les localisations:

@echo off
FOR /F "skip=1 tokens=1-6" %%A IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    if "%%B" NEQ "" (
        SET /A FDATE=%%F*10000+%%D*100+%%A
    )
)
@echo on
echo date=%FDATE%
echo year=%FDATE:~2,2%
echo month=%FDATE:~4,2%

Extraire le Jour, le Mois et l'Année

Le plus voté de la fonction et de la accepté de une ne fonctionnent PAS de la locale de façon indépendante à partir de la DATE de commande est soumise à la localisation de trop. Par exemple (accepté): Dans l'anglais, vous avez AAAA pour l'année et en Hollande, il est JJJJ. Donc, c'est un no-go. Le script suivant prend les utilisateurs de la localisation de la base de registre, qui est indépendant des paramètres régionaux.

@echo off

::: Begin set date
setlocal EnableExtensions EnableDelayedExpansion

:: Determine short date format (independent from localization) from registry
for /f "skip=1 tokens=3-5 delims=- " %%L in ( '2^>nul reg query "HKCU\Control Panel\International" /v "sShortDate"' ) do ( 

    :: Since we can have multiple (short) date formats we only use the first char from the format in a new variable
    set "_L=%%L" && set "_L=!_L:~0,1!" && set "_M=%%M" && set "_M=!_M:~0,1!" && set "_N=%%N" && set "_N=!_N:~0,1!"

    :: Now assign the date values to the new vars
    for /f "tokens=2-4 delims=/-. " %%D in ( "%date%" ) do ( set "!_L!=%%D" && set "!_M!=%%E" && set "!_N!=%%F" )
)


:: Print the values as is
echo.
echo This is the original date string --^> %date%
echo These are the splitted values    --^> Day: %d%, Month:%m%, Year: %y%.
echo.

endlocal

Extraire uniquement l'Année

Pour un script que j'ai écrit, je voulais seulement à l'extrait de l'année (indépendant des paramètres régionaux) alors je suis venu avec cette oneliner que je ne pouvais pas trouver une solution. Il utilise le 'DATE' var, plusieurs séparateurs et vérifie un certain nombre de plus de 31. Qui, alors, sera l'année en cours. Il est faible sur les ressources, contrairement à certaines autres solutions.

@echo off

setlocal EnableExtensions

for /f " tokens=2-4 delims=-./" %%D in ( "%date%" ) do ( if %%D gtr 31 ( set "_YEAR=%%D" ) else ( if %%E gtr 31 ( set "_YEAR=%%E" ) else ( if %%F gtr 31 ( set "_YEAR=%%F" ) ) ) )

echo And the year is... %_YEAR%.
echo.

endlocal

• Pour une ligne!

---

Essayez de l'utiliser pour faire des boucles avec 2 séparateurs (égal + dot): =.:

@for /f "tokens=2delims==." %i in ('wmic OS Get localdatetime /value ^|findstr /r [0-9]')do @cmd/v/c "set _date=%i &&echo/year: !_date:~0,4!&&echo/month:   !_date:~4,2!&&echo/ day:   !_date:~6,2!"

Résultats ligne de commande:

---

 year: 2019
month:   06
  day:   12

• Fonctionne dans n'importe quelle langue/région et aussi, aucun des paramètres de l'utilisateur en sortie de mise en page.

---

Pour fichier bat:

---

@for /f "tokens=2delims==." %%i in ('wmic OS Get localdatetime /value ^|findstr /r [0-9]')do @cmd/v/c "set _date=%%i &&echo/year: !_date:~0,4!&&echo/month:   !_date:~4,2!&&echo/ day:   !_date:~6,2!"

---

Vous pouvez utiliser simple variable syntaxe, voici un exemple:

@echo off
set month=%date:~0,2%
set day=%date:~3,2%
set year=%date:~6,4%
echo The current month is %month%
echo The current day is %day%
echo The current year is %year%
pause >nul

Une autre option est le for commande, nouveau voici mon exemple:

@echo off
for /f "delims=/tokens=1-3" %%a in ("%date%") do (
set month=%%a
set day=%%b
set year=%%c
)
echo The current month is %month%
echo The current day is %day%
echo The current year is %year%
pause >nul