Comment puis-je obtenir une modification du fichier, la date dans un format JJMMAA en Perl?

Quelle est la meilleure façon d'obtenir une modification du fichier, la date dans un format JJMMAA en Perl?

(à l'Origine de la question était "Comment le faire sans le module DateTime". J'ai supprimé cette restriction afin de faire de la question plus générale.)

  • L'utilisation de la Date::module de Format de.
  • J'ai trouvé la réponse que je voulais, et a retiré le "pas de module DateTime" restriction, afin de rendre la question plus générique.
  • ...qui change de la question.
InformationsquelleAutor Igor Oks | 2009-12-03
  1. 17

    Si c'est la seule date de mise en forme j'ai besoin de faire et on n'a pas besoin d'un jour de fonctionnalités pour autre chose, je viens d'utiliser POSIX (qui vient avec Perl):

    use POSIX;

my $file = "/etc/passwd";

my $date = POSIX::strftime( 
             "%d%m%y", 
             localtime( 
                 ( stat $file )[9]
                 )
             );

    Oublier -M si vous n'utilisez pas de temps relatif. Aller directement à stat pour obtenir de l'époque.

    • Stat() ne semble pas fonctionner sur d'Activestate Perl 5.24 sur Windows Server 2012. Comment aurais-je obtenir une date de fichier pour un fichier sur un Serveur Windows?
    • Regardez à travers le Win32:: modules pour ceux qui connaissent les systèmes de fichiers de Windows.
    • Merci. J'ai déjà fait une recherche sur DuckDuckGo, le Activestate forum de la communauté, et regarda CPAN à Win32::Fichier. Certains modules n'ont pas été mis à jour à 10 ans. Mais je n'ai pas trouvé ce dont j'avais besoin encore.
    InformationsquelleAutor brian d foy
  2. 11

    Voir Heure: À La Pièce pour objet de syntaxe orientée. Il est également livré avec Perl par défaut dans les versions 5.10 et suivant.
    Généralement, au bout d'un certain moment, vous avez besoin de plus de fonctionnalités. En utilisant le Temps: la Pièce n'importer quoi que ce soit à côté de localtime et gmtime. Et vous pouvez demander de ne pas importer de quelque chose de trop en disant tout simplement use Time::Piece ();.

    use Time::Piece;
localtime((stat $filename)[9])->ymd;                # 2000-02-29
localtime((stat $filename)[9])->ymd('');                 # 20000229
localtime((stat $filename)[9])->dmy("");#is what you wanted



$perl -MTime::Piece -e 'print localtime(time)->dmy("")'
    • Et c'est de base dans la version 5.10, qui est peut-être utile (étant donné que les modules peuvent être un problème ici).
    InformationsquelleAutor Беров
  3. 4

    Ici est assez simple méthode à l'aide de POSIX (qui est un module de base) et localtime pour éviter de tourner avec les détails de ce stat retours (voir Gde réponse pourquoi c'est une douleur):

    use POSIX qw/strftime/;

my @records;

opendir my $dh, '.' or die "Can't open current directory for reading: $!";

while (my $item = readdir $dh) {
    next unless -f $item && $item !~ m/^\./;
    push @records, [$item, (stat $item)[9]];
}

for my $record (@records) {
    print "File: $record->[0]\n";
    print "Mtime: " . strftime("%d%m%Y", localtime $record->[1]), "\n";
}
    InformationsquelleAutor Telemachus
  4. 4

    Mise à JOUR: Notez que cette réponse a été à la question initiale, qui a expressément exclu l'utilisation de DateTime modules.

    Pour obtenir de l'heure de modification

    my $mtime = (stat $filename)[9];

    Renvoie le dernier de modifier le temps en secondes depuis l'epoch.

    Alors, pour traduire à jour des composants, l'utilisation localtime -

    my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime($mtime);

    Noter que localtime renvoie 0 pour Jan, 1 pour la Feb, etc, et $année est le nombre d'années depuis 1900, de sorte 109 -> 2009.

    Puis vers la sortie dans le format JJMMAA -

    print substr('0'.$mday,-2), substr('0'.($mon+1),-2), substr($year+1900,-2);

    De sorte qu'il est plus facile - et moins sujettes à l'erreur - pour utiliser simplement Date: Format si vous le pouvez.

    • POSIX::strftime('%m%d%y', $mtime) est également plus facile et moins sujette aux erreurs
    InformationsquelleAutor Ed Guiness
  5. 1
    use Date::Format;
print time2str("%d%m%y", (stat $filename)[9]);
    • Si les modules sont actuellement autorisés à le faire?
    • N'est pas pris en charge ou n'est pas installé?
    InformationsquelleAutor Igor Oks