Comment puis-je passer des arguments à un fichier batch?

Voici comment je l'ai fait:

@fake-command /u %1 /p %2

Voici ce que la commande ressemble à ceci:

test.cmd admin P@55w0rd > test-log.txt

La %1 s'applique pour le premier paramètre, le %2 (et c'est ici la partie la plus délicate) s'applique à la seconde. Vous pouvez avoir jusqu'à 9 paramètres transmis de cette façon.

Accès par lot des paramètres peut être simple avec %1, %2, ... %9 ou aussi %*,

mais uniquement si le contenu est simple.

Il n'y a pas de moyen simple pour des complexes de contenu comme "&"^&, car il n'est pas possible d'accéder à %1 sans produire une erreur.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

Les lignes étendre à

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

Et chaque ligne ne parvient pas, comme l'un des & est à l'extérieur des guillemets.

Il peut être résolu avec la lecture d'un fichier temporaire un fait remarquer version du paramètre.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

L'astuce est de permettre echo on et d'élargir l' %1 après un rem déclaration (fonctionne aussi avec %2 .. %*).

Donc, même "&"& pourrait être l'écho, sans obtenir une erreur, comme il est fait remarquer.

Mais pour être en mesure de rediriger la sortie de la echo on, vous avez besoin des deux pour les-boucles.

Les caractères supplémentaires * # sont utilisés pour être en sécurité contre des contenus comme /? (montrerait l'aide pour REM).

Ou un accent circonflexe ^ à la fin de ligne peut travailler comme multiligne personnage, même après une rem.

Puis la lecture de la rem paramètre de sortie à partir du fichier, mais avec précaution.

La FOR /F devrait travailler avec l'expansion retardée off, le reste du contenu avec des "!" serait détruit.

Après le retrait de caractères supplémentaires dans param1, vous l'avez.

Et à utiliser param1 de manière sûre, de permettre l'expansion retardée.

Il n'est pas nécessaire de compliquer. C'est simplement la commande %1 %2 paramètres, par exemple,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

La "pause" affiche ce que le fichier batch a fait et vous attend pour frapper la touche. Enregistrer xx.bat dans le dossier Windows.

Pour l'utiliser, tapez, par exemple:

xx c:\f\*.* f:\sites

Ce fichier de commandes prend soin de tous les paramètres nécessaires, comme la copie uniquement les fichiers, qui sont plus récents, etc. Je l'ai utilisé depuis avant Windows. Si vous aimez voir les noms des fichiers, car ils sont en cours de copie, de laisser le Q paramètre.

Un ami a me poser des questions sur ce sujet récemment, donc je pensais que je poste la façon dont je traite les arguments de ligne de commande dans des fichiers batch.

Cette technique a un peu de surcharge comme vous allez le voir, mais il rend mes fichiers de commandes très facile à comprendre et rapide à mettre en œuvre. Ainsi que de soutenir les structures suivantes:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

Le jist de c'est d'avoir la :init, :parse, et :main fonctions.

Exemple d'utilisation

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

modèle.chauve-souris

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

Cette boucle sur le lot paramètres ( % * ), soit ils sont cotés ou non, puis echos chaque paramètre.

À se référer à un ensemble de variables en ligne de commande, vous devez utiliser %a% ainsi, par exemple:

set a=100 
echo %a%  
rem output = 100 

Remarque: Cela fonctionne pour Windows 7 pro.

Inspiré par un réponse ailleurs par @Jon, j'ai conçu un algorithme plus général pour l'extraction des paramètres nommés, les valeurs facultatives, et les commutateurs.

Disons que nous voulons mettre en œuvre un utilitaire foobar. Il nécessite une commande initiale. C'est un paramètre facultatif --foo qui prend un facultatif valeur (qui ne peut pas être un autre paramètre, bien sûr); si la valeur est manquante par défaut default. Il dispose également d'un paramètre facultatif --bar qui prend un nécessaire valeur. Enfin, il peut prendre un drapeau --baz sans valeur autorisée. Oh, et ces paramètres peuvent venir dans n'importe quel ordre.

En d'autres termes, il ressemble à ceci:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

Voici une solution:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

• Utilisation SETLOCAL de sorte que les variables n'échappent pas à l'appel de l'environnement.
• N'oubliez pas d'initialiser les variables SET FOO=, etc. dans le cas où quelqu'un définies dans l'appel de l'environnement.
• Utilisation %~1 pour supprimer les guillemets.
• Utilisation IF "%ARG%" == "" et pas IF [%ARG%] == [] parce que [ et ] ne pas jouer à tout avec les valeurs se terminant dans un espace.
• Même si vous SHIFT à l'intérieur d'un IF bloc, le courant args comme %~1 n'obtenez pas mis à jour car ils sont déterminés lors de la IF est analysée. Vous pouvez utiliser %~1 et %~2 à l'intérieur de la IF bloc, mais il serait source de confusion parce que vous aviez un SHIFT. Vous pourriez mettre le SHIFT à la fin du bloc pour plus de clarté, mais qui risquent de se perdre et/ou de confondre les gens ainsi. Afin de "capturer" %~1 et %~1 à l'extérieur du bloc semble le mieux.
• Vous ne voulez pas utiliser un paramètre à la place d'un autre paramètre est facultatif valeur, donc vous devez vérifier IF NOT "%ARG:~0,2%" == "--".
• Attention seulement à SHIFT lorsque vous utilisation l'un des paramètres.
• Le code en double SET FOO=%DEFAULT_FOO% est regrettable, mais l'autre solution serait d'ajouter un IF "%FOO%" == "" SET FOO=%DEFAULT_FOO% à l'extérieur de la IF NOT "%ARG%" == "" bloc. Cependant, parce que c'est encore à l'intérieur de la IF "%PARAM%" == "--foo" bloc, le %FOO% valeur aurait été évalués et mis en place avant vous jamais entré dans le bloc, de sorte que vous ne serait jamais à détecter que les deux la --foo paramètre était présent et aussi que le %FOO% valeur est manquante.
• Noter que ECHO Missing bar value. 1>&2 envoie le message d'erreur vers stderr.
• Voulez une ligne vide dans un fichier de commandes Windows? Tu dois utiliser ECHO: ou l'une des variantes.

Pour utiliser le bouclage obtenir tous les arguments et dans le plus pur lot:

@echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

Votre code est prêt à faire quelque chose avec le numéro d'argument là où il faut, comme...

 @echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift 

 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt