Comment puis-je Passer d'une Image à partir de Flash pour ASP.NET?

Dans cet exemple, j'ai créé un fichier Flash avec un bouton sur la scène. Lorsque vous cliquez sur ce bouton, le Flash envoie l'image du bouton à un fichier ASPX qui enregistre en JPEG. Comme vous allez le voir c'est fait par le dessin de la DisplayObject dans un BitmapData objet et en tant que tel, vous pouvez facilement remplacer la référence au bouton avec quoi que ce soit qui hérite de DisplayObject (y compris un clip qui contient la toile pour une application de la peinture, etc).

Je vais vous guider à travers le Flash élément premier et la .NET backend.

Flash

Pour envoyer une image générée comme ce à partir de Flash pour ASP.NET (ou tout autre backend), vous allez avoir besoin d'un couple de la 3e partie des bibliothèques. Nous allons avoir besoin d'un Codeur JPEG (qui Flash n'a pas, mais les dernières versions de Flex le faire) que l'on peut obtenir à partir de l'AS3 Core Lib http://code.google.com/p/as3corelib/. Nous allons également avoir besoin d'un encoder en base64 pour l'envoi des données sur le fil. Je vais utiliser l'un de Flash Dynamique, disponible à l' http://dynamicflash.com/goodies/base64/.

Les télécharger et de les extraire quelque part sensible sur votre disque dur (comme un C:\lib dossier).

J'ai créé un nouveau Flash AS3 fichier et enregistrez-le comme uploader.fla. J'ai ajouté un bouton de composants vers la scène et l'a nommé btnUpload. Ensuite, j'ai modifié les paramètres d'ActionScript et ajouté mon c:\lib dossier dans le chemin. Puis j'ai remis le document un nom de classe de Uploader et enregistré le fichier.

Ensuite, j'ai créé un fichier ActionScript et ajouté le code suivant:

package
{
import flash.display.BitmapData;
import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.net.URLRequestMethod;
import flash.net.URLVariables;
import flash.utils.ByteArray;
import fl.controls.Button;
import com.adobe.images.JPGEncoder;
import com.dynamicflash.util.Base64;
public class Uploader extends MovieClip
{
//Reference to the button on the stage
public var btnUpload:Button;
//Encoder quality
private var _jpegQuality:int = 100;
//Path to the upload script
private var _uploadPath:String = "/upload.aspx";
public function Uploader()
{
btnUpload.addEventListener(MouseEvent.CLICK, buttonClick);
}
private function buttonClick(e:MouseEvent):void
{
//Create a new BitmapData object the size of the upload button.
//We're going to send the image of the button to the server.
var image:BitmapData = new BitmapData(btnUpload.width, btnUpload.height);
//Draw the button into the BitmapData
image.draw(btnUpload);
//Encode the BitmapData into a ByteArray
var enc:JPGEncoder = new JPGEncoder(_jpegQuality);
var bytes:ByteArray = enc.encode(image);
//and convert the ByteArray to a Base64 encoded string
var base64Bytes:String = Base64.encodeByteArray(bytes);
//Add the string to a URLVariables object
var vars:URLVariables = new URLVariables();
vars.imageData = base64Bytes;
//and send it over the wire via HTTP POST
var url:URLRequest = new URLRequest(_uploadPath);
url.data = vars;
url.method = URLRequestMethod.POST;
var loader:URLLoader = new URLLoader();
loader.load(url);
}
}
}

J'ai enregistré ce fichier à côté de la FLA avec le nom Uploader.comme.

J'ai édité le fichier SWF à la racine de mon Asp.NET site web.
Ce code suppose que vous souhaitez télécharger le jpeg avec une qualité de 100% et que le script qui va recevoir les données est appelé le téléchargement.aspx et est situé à la racine du site.

ASP.NET

Dans la racine de mon site j'ai créé un Formulaire nommé le téléchargement.aspx. Dans l' .fichier aspx, j'ai supprimé tout le contenu en dehors de la directive de page. C'est le contenu ressembler à ceci:

<%@ Page Language="C#" AutoEventWireup="true" CodeFile="upload.aspx.cs" Inherits="upload" %>

Ensuite dans le Code-behind, j'ai ajouté ce qui suit:

using System;
using System.IO;
public partial class upload : System.Web.UI.Page
{
protected void Page_Load(object sender, EventArgs e)
{
//Get the data from the POST array
string data = Request.Form["imageData"];
//Decode the bytes from the Base64 string
byte[] bytes = Convert.FromBase64String(data);
//Write the jpeg to disk
string path = Server.MapPath("~/save.jpg");
File.WriteAllBytes(path, bytes);
//Clear the response and send a Flash variable back to the URL Loader
Response.Clear();
Response.ContentType = "text/plain";
Response.Write("ok=ok");
}
}

Il y a évidemment des valeurs codées en dur tels que le chemin de sauvegarde, mais à partir de cela, vous devriez être capable de créer n'importe quel système vous avez besoin.

OriginalL'auteur Greg B

L'avoir poster les fichiers standard de formulaire HTML. Vous pouvez accéder à ces fichiers dans l'événement Page_Load de la page, il affiche en utilisant la collection suivante

Demande.Fichiers

Ce sera de retour une collection de HttpPostedFiles juste comme un contrôle FileUpload.

OriginalL'auteur Peter Lange