Comment puis-je prendre une référence à un sous-programme Perl?

J'ai un peu de mal à trouver comment faire référence à une sous-routine dans un module externe de fichier. Maintenant, je suis en train de faire ceci:

Fichier externe

package settingsGeneral;    
sub printScreen {
    print $_[0];
}

Principal

use settingsGeneral;    
my $printScreen = settingsGeneral::printScreen;
&$printScreen("test");

mais ce résultat dans une erreur:
Ne pouvez pas utiliser des chaînes de caractères ("1") comme une sous-routine ref tandis que strict "refs" en cours d'utilisation

OriginalL'auteur Pmarcoen | 2010-04-06

  1. 25

    Comme indiqué dans perlmodlib, vous devriez commencer votre module du nom avec une majuscule:

    Perl de manière informelle les réserves de minuscules les noms de module pour "pragma" modules comme integer et strict. D'autres modules normalement commencer avec une lettre majuscule et une utilisation mixte affaire avec aucun des traits de soulignement (doivent être courtes et portable).

    Une façon d'appeler un sous défini dans un autre package est à qualifier pleinement que sous son nom quand vous l'appelez:

    SettingsGeneral::printScreen "important message\n";

    Si tout ce que vous voulez, c'est une référence à printScreen, de la saisir avec la barre oblique inverse de l'opérateur

    my $subref = \&SettingsGeneral::printScreen;

    et de l'appeler avec un de

    &$subref("one\n");
&{$subref}("two\n");
$subref->("three\n");

    Vous pouvez créer une alias dans votre forfait actuel:

    *printScreen = \&SettingsGeneral::printScreen;
printScreen("another urgent flash\n");

    Ignorer les parenthèses (nécessaire car le sub dans le paquet actuel n'est pas connu au moment de la compilation) par écrit:

    use subs 'printScreen';
*printScreen = \&SettingsGeneral::printScreen;
printScreen "the sky is falling!\n";

    La Exportateur module peut faire ce travail de surveillance pour vous:

    SettingsGeneral.pm:

    package SettingsGeneral;

use Exporter 'import';

our @EXPORT = qw/ printScreen /;

sub printScreen {
  print $_[0];
}

1;

    principal:

    #! /usr/bin/perl

use warnings;
use strict;

use SettingsGeneral;

printScreen "foo!\n";
    dans ton premier exemple, printScreen("another urgen flash\n"); besoins des parens
    merci beaucoup ! appris quelque chose 😉
    Merci! Fixe.
    Vous êtes les bienvenus! Je suis content que ça aide.

    OriginalL'auteur Greg Bacon