Comment puis-je remplacer les lignes au milieu d'un fichier avec Perl?

Je pense que c'est la FAQ réponse que j'ai reposté à Stackoverflow le plus. Le perlfaq5 a la réponse à Comment puis-je modifier, supprimer ou insérer une ligne dans un fichier, ou d'ajouter au début du fichier?.

Oublier le mode d'ajout des trucs. Qui va juste vous rendre la vie plus difficile.

---

L'idée de base de l'insertion, la modification ou la suppression d'une ligne d'un fichier texte implique la lecture et l'impression du fichier à l'endroit que vous voulez faire le changement, le changement, puis de la lecture et de l'impression, le reste du fichier. Perl n'est pas de fournir un accès aléatoire aux lignes (surtout depuis l'entrée d'enregistrement séparateur, $/, est sujette au changement), bien que des modules tels que Tie::File peut faux.

Un programme en Perl pour faire ces tâches prend la forme de base de l'ouverture d'un fichier, d'impression de ses lignes, puis de la fermeture du fichier:

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

while( <$in> )
    {
    print $out $_;
    }

close $out;

À l'intérieur de cette forme de base, ajouter les pièces que vous avez besoin d'insérer, de modifier ou de supprimer des lignes.

À ajouter des lignes au début, l'impression de ces lignes avant d'entrer dans la boucle qui imprime les lignes existantes.

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n"; # <--- HERE'S THE MAGIC

while( <$in> )
    {
    print $out $_;
    }

close $out;

De changer les lignes, insérer le code à modifier les lignes à l'intérieur de la boucle while. Dans ce cas, le code est tous mis en minuscule versions de "perl" et majuscules eux. Le phénomène se produit pour chaque ligne, alors assurez-vous que vous êtes censé faire que sur chaque ligne!

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n";

while( <$in> )
    {
    s/\b(perl)\b/Perl/g;
    print $out $_;
    }

close $out;

Changer seulement une ligne en particulier, l'entrée du numéro de ligne, $., est utile. D'abord de lire et d'imprimer les lignes jusqu'à celui que vous voulez modifier. Ensuite, lisez la seule ligne que vous voulez modifier, de le modifier, et de l'imprimer. Après cela, lire le reste de l'lignes et imprimer ces:

while( <$in> )   # print the lines before the change
    {
    print $out $_;
    last if $. == 4; # line number before change
    }

my $line = <$in>;
$line =~ s/\b(perl)\b/Perl/g;
print $out $line;

while( <$in> )   # print the rest of the lines
    {
    print $out $_;
    }

À sauter des lignes, utilisez la boucle de contrôle. La prochaine dans cet exemple, ignore les lignes de commentaires, et le dernier s'arrête tous les traitements une fois qu'elle rencontre soit __END__ ou __DATA__.

while( <$in> )
    {
    next if /^\s+#/;             # skip comment lines
    last if /^__(END|DATA)__$/;  # stop at end of code marker
    print $out $_;
    }

Faire le même genre de chose pour supprimer une ligne en cliquant sur suivant pour sauter les lignes que vous ne voulez pas afficher dans la sortie. Cet exemple saute à chaque cinquième ligne:

while( <$in> )
    {
    next unless $. % 5;
    print $out $_;
    }

Si, pour une raison étrange, vous voulez vraiment voir l'ensemble du dossier à la fois plutôt que de les traiter ligne par ligne, vous pouvez slurp dans (aussi longtemps que vous pouvez équiper toute chose dans la mémoire!):

open my $in,  '<',  $file      or die "Can't read old file: $!"
open my $out, '>', "$file.new" or die "Can't write new file: $!";

my @lines = do { local $/; <$in> }; # slurp!

    # do your magic here

print $out @lines;

Des Modules tels que Fichier::Slurp et Tie::File peut aider avec cela aussi. Si vous le pouvez, toutefois, éviter de lire l'ensemble du dossier à la fois. Perl ne vous donnera pas de mémoire pour le système d'exploitation jusqu'à ce que le processus se termine.

Vous pouvez également utiliser Perl one-liners de modifier un fichier en place. Les modifications suivantes de toutes les "Fred" à 'Barney' dans inFile.txt, en écrasant le fichier avec le nouveau contenu. Avec le -p commutateur, Perl enroule une boucle while autour du code que vous spécifiez avec -e, et -i s'allume dans l'édition. La ligne actuelle est en $_. Avec -p, Perl imprime automatiquement la valeur de $_ à la fin de la boucle. Voir perlrun pour plus de détails.

perl -pi -e 's/Fred/Barney/' inFile.txt

De faire une sauvegarde de inFile.txt, donner -i une extension de fichier à ajouter:

perl -pi.bak -e 's/Fred/Barney/' inFile.txt

De changer seulement la cinquième ligne, vous pouvez ajouter un test de vérification de $., l'entrée numéro de la ligne, puis seulement effectuer l'opération lorsque le test passe:

perl -pi -e 's/Fred/Barney/if $. == 5' inFile.txt

Pour ajouter des lignes avant une certaine ligne, vous pouvez ajouter une ligne (ou des lignes!) avant de Perl imprime $_:

perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt

Vous pouvez même ajouter une ligne au début d'un fichier, depuis la ligne courante imprime à la fin de la boucle:

perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt

Pour insérer une ligne après un déjà dans le fichier, utilisez le -n commutateur. C'est comme -p sauf qu'il n'a pas l'impression $_ à la fin de la boucle, de sorte que vous avez à faire vous-même. Dans ce cas, l'impression $_ d'abord, puis imprimer la ligne que vous souhaitez ajouter.

perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt

À supprimer les lignes, d'imprimer uniquement ceux que vous souhaitez.

perl -ni -e 'print unless /d/' inFile.txt

    ... or ...

perl -pi -e 'next unless /d/' inFile.txt

Un bon langage Perl est à lire et à écrire à la norme d'entrée et de sortie. Vous pouvez pipe et de réorienter si nécessaire. Par le biais de l'opérateur <> (une enveloppe de readline), Perl va ouvrir les fichiers que vous passer en argument sur la ligne de commande.

Pour répondre à votre question, quelques lignes de code (pure) :

#!/usr/bin/env perl
use strict; use warnings;

while (<>) {
  if ($. == 2) {
    print "new data", "\n";
    next;
  }
  if ($. == 3) {
    print "very new data", "\n";
    next;
  }
  print;
}

print "more data", "\n"; 

Ensuite l'appeler de cette façon : perl yourscript.pl inputfile > outputfile

Si vous souhaitez ouvrir les fichiers vous-même (ici, nous avons simplement ignorer les lignes indésirables) :

my open $in_fh, '<', $inputfile
  or die "Can't open file $inputfile: $!";

my open $out_fh, '>', $outputfile
  or die "Can't open file $output: $!";

while (my $line = <$in_fh>) {
  next if ( $. == 2 or $. == 3 or $. == 4 );
  print $out_fh $line;
}
print $out_fh "...whatever\n";

use File::Copy;

        copy("/file1.txt","/file1_old.txt");
        open(FILEHANDLE,">file1.txt");
        open(FILEHANDLE1,"<file1_old.txt");

        my $linecount=1;
        while(<FILEHANDLE1>)
        {
            print $_."\n";

            if($linecount>4)
            {
                print FILEHANDLE "$_";
            }
            $linecount++;
        }

        {
                ## new data will be placed
        }
        #####close the file handle
         close(FILEHANDLE1);
         close(FILEHANDLE);