Comment puis-je supprimer tous les fichiers/sous-dossiers à l'exception de certains fichiers dans le DOS?

Je suis à la recherche d'un DOS de script pour supprimer tous les fichiers et sous-répertoires dans un répertoire racine, sauf pour un ensemble de fichiers batch (*.chauve-souris) qui sont dans le répertoire racine. DOS jocks qui sais un moyen facile de faire cela?

Mise à jour

Merci pour votre aide tout le monde. C'est là où je suis maintenant (voir ci-dessous). Je suis à l'aide de Ken suggestion pour le supprimer des fichiers. Je voudrais savoir comment je peux arrêter ce script en cours d'exécution si la del ou RD commandes échouent en raison d'un verrou sur un fichier/dir. Quelqu'un sait comment? Maintenant, ce script permet de faire un tas de choses après le supprime et je voudrais arrêter le script si l'un des suppressions d'échouer.

@echo off

REM *********************************************************************
REM *  Delete all files and subdirs except for batch files in the root  *
REM *********************************************************************

REM Delete all files in current dir except bat files.  Does this by a) setting the attributes of *.bat files to 
REM readonly and hidden, b) deleting the rest, c) reseting the attributes 

attrib +r +s *.bat
del *.* /S /Q
attrib -r -s *.bat

REM Deletes ALL subdirectories 

FOR /D  %%G in (*) DO RD /s /q %%G
Est-ce à dire: Ne supprimez pas TOUT .les fichiers bat dans le répertoire de racine? Ou Ne supprimez pas CES .chauve-souris SI elles sont dans le répertoire de racine?
Ne supprimez pas les aucun .les fichiers bat à la racine

OriginalL'auteur Marcus Leon | 2009-02-17

  1. 20

    Vous pouvez définir les attributs des fichiers que vous voulez garder à lecture seule et caché d'abord, supprimer le reste, et puis réinitialiser les attributs de ce qui est caché, lecture seule les fichiers de retour.

    attrib +r +s *.bat
del *.*
attrib -r -s *.bat

    J'ai l'habitude de le faire assez souvent, et écrit un fichier de commandes automatisé ceci:

    @echo off
@ if "%1" == "%9" goto help
@ if /i %1 EQU ? goto help
@ if /i %1 EQU help goto help
@ attrib +h +s %1
@ %2 %3 /Q
@ attrib -h -s %1
@ goto :EOF
:help
@echo        ╔═══════════════════════════════════════════════════════╗
@echo        ║ except filespec1 doscommand filespec2                 ║
@echo        ║                                                       ║
@echo        ║  filespec1  The files to exclude from doscommand      ║
@echo        ║  doscommmand The DOS command to execute on filespec2  ║
@echo        ║  filespec2  The files to execute doscommand against   ║
@echo        ║                                                       ║
@echo        ║ Example:                                              ║
@echo        ║                                                       ║
@echo        ║ except *.txt del *.*                                  ║
@echo        ║                                                       ║
@echo        ║Deletes all files except text files in the directory   ║
@echo        ╚═══════════════════════════════════════════════════════╝

    C'est probablement OK il suffit d'utiliser l'attribut caché, mais je sais que les del ne touche pas fichiers cachés du système, j'ai donc mis les deux. Mieux vaut prévenir que guérir, de l'OMI.

    Basé sur un commentaire de Marcus: Si vous souhaitez élargir à d'inclure les sous-répertoires du répertoire courant, il suffit de changer les deux attrib lignes de

    attrib <remainder of line>  /S

    et modifier la ligne entre les deux attrib lignes de

    @ %2 %3 /Q /S

    Qui devrait fonctionner pour la plupart des choses que vous voulez sauf.chauve-souris pour le faire.

    C'est une excellente idée. J'ai besoin de supprimer également tous les sous-dossiers (et leurs contenus). Semble que ce script ne supprime que les non *.les fichiers bat à la racine.
    Marcus, j'ai mis à jour le post pour montrer l'inclusion de sous-dossiers.

    OriginalL'auteur Ken White

  2. 2

    Fixe basé sur @Ken commentaire:

    >d:
>mkdir bats
>c:
>copy *.bat d:\bats
>del *.* /Y
>copy d:\bats\*.bat c:\
    Vous gardez toujours le dos-attaque de script sur votre système 😉
    Oups, non, vous ne le font pas. Mais ce n' /Y faire?
    Des réponses Y à la question "êtes-vous sûr?"
    cd d: et cd c: ne fonctionne pas. C'est tout simplement D:<enter> ou C:<enter> pour changer les disques. Aussi, vous ne CMD.EXE à l'aide de cd /lecteur d:\répertoire de la syntaxe.
    J'ai besoin de supprimer également tous les sous-dossiers. Je crois que del . supprime uniquement les fichiers dans le répertoire courant.

    OriginalL'auteur Alex Reitbort

  3. 0

    Ceci est basé sur Alex de la méthode de sauvegarde la .Les fichiers BAT, mais supprime tous les sous-dossiers, en utilisant la commande RD.

    @echo off

rem !WARNING!
rem THE_DELETE_DRIVE is the drive to delete
rem THE_BACKUP_DRIVE is the drive to use for backup
set THE_DELETE_DRIVE=T:
set THE_BACKUP_DRIVE=C:
rem !WARNING!

echo This will recursively delete everything from %THE_DELETE_DRIVE%\ (except batch files).
echo Are you sure? Press Ctrl+C to cancel, or any other key to continue...
echo.
pause

rem Make the backup folder
md %THE_BACKUP_DRIVE%\bak12345

rem Copy all batch files from delete-drive root to backup folder
copy %THE_DELETE_DRIVE%\*.bat %THE_BACKUP_DRIVE%\bak12345

rem Delete everything in the delete-drive root
rd /s/q %THE_DELETE_DRIVE%\

rem Copy all backed-up files back to delete-drive root
copy %THE_BACKUP_DRIVE%\bak12345\*.bat %THE_DELETE_DRIVE%\

rem Remove the backup folder
rd /s/q %THE_BACKUP_DRIVE%\bak12345

echo ************************************
echo All Done!
echo ************************************
echo.

pause

    OriginalL'auteur demoncodemonkey