Comment puis-je surveiller le trafic réseau sur Windows depuis la ligne de commande

Tout tshark est vraiment puissant si vous voulez avoir une granularité fine des statistiques (selon hôtes, protocoles, ...), il a l'inconvénient principal de recueillir des statistiques au cours de la période de temps il est en cours d'exécution. En tant que tel, il n'est bon que dans la présentation des "instantanés" des statistiques, mais pas de rapport de sondage de la circulation à des points réguliers dans le temps pour avoir une idée de la façon dont votre réseau de trafic le long de la journée, de la semaine, ...

En outre, comme tshark fait de la capture de paquets, il y a des frais généraux.

Ainsi, selon vos besoins, vous pourriez être intéressé par le MS Windows net ou netstat commandes (netstat a la possibilité de présenter des statistiques par protocole). 'net statistics [Server|workstation]' ou 'netstat [-e|-s]' sont, autant que les statistiques du trafic réseau, la MS Windows équivalents de Linux 'ifconfig' (ou 'cat /proc/net/dev' si vous préférez).

Noter que, comme ifconfig faire, net ou netstat seul rapport de quantité de données depuis l'interface a été mis en place.

Afin d'obtenir des débits de trafic, vous avez pour horodater vos appels aux commandes et de faire le calcul vous-même.

Autant que je sache, les deux commandes sont expédiées avec toutes les dernières MS versions de Windows.

OriginalL'auteur phep

Je voulais vous donner une solution plus facile, ensuite, j'ai utilisé ma réponse précédente à un code frais de windows script batch qui parcourt toutes les 10 secondes. Il surveille le téléchargement et le téléchargement de la bande passante et la vitesse de la console et des journaux quantité d'octets transférés dans un .fichier csv.

@ECHO off
SETLOCAL ENABLEDELAYEDEXPANSION

set TAB=    
echo Timestamp%TAB%Down bytes%TAB%Up bytes%TAB%Down speed%TAB%Up speed

:: Store console command result
:looptask
SET count=1
FOR /F "tokens=* USEBACKQ" %%F IN (`netstat -e`) DO (
  SET string!count!=%%F
  SET /a count=!count!+1
)
:: Bytes transfered line is string3

:: Get rid of the whitespaces 
:loopreplace
if defined string3 (
  set "new=!string3:  = !"
  if "!new!" neq "!string3!" (
    set "string3=!new!"
    goto :loopreplace
  )
)
if defined string3 if "!string3:~0,1!" equ " " set "string3=!string3:~1!"
if defined string3 if "!string3:~-1!" equ " " set "string3=!string3:~0,-1!"

:: Extracting bytes downloaded and uploaded
set line=%string3:~6%
FOR /F "tokens=1,2 delims= " %%A IN ("%line%") DO (
  set dbytes=%%~A
  set ubytes=%%~B
)

:: Midnight epoch
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set time=%ldt:~8,2%:%ldt:~10,2%:%ldt:~12,2%
FOR /F "tokens=* delims=0" %%A IN ("%ldt:~8,2%") DO SET /A hs=%%A+0
FOR /F "tokens=* delims=0" %%A IN ("%ldt:~10,2%") DO SET /A min=%%A+0
FOR /F "tokens=* delims=0" %%A IN ("%ldt:~12,2%") DO SET /A sec=%%A+0
set /a epoch=%hs%*3600+%min%*60+%sec%

:: Calc speeds
if not defined LOOPCOMPLETE (
    echo %time%%TAB%%dbytes%%TAB%%ubytes%%TAB%0.00 KB/s%TAB%0.00 KB/s
    goto :skip
)
:: Read .CSV file last line values
for /f %%i in ('find /v /c "" ^< bwlog.csv') do set /a lines=%%i
set /a lastLine=%lines% - 1
SET count=1
FOR /F "tokens=* USEBACKQ" %%F IN (`more /e +%lastLine% bwlog.csv`) DO (
  SET string!count!=%%F
  SET /a count=!count!+1
)
FOR /F "tokens=1,2,3 delims=," %%A IN ("%string1%") DO (
  set lasttime=%%~A
  set lastdown=%%~B
  set lastup=%%~C
)
if %epoch% == %lasttime% (  
    goto :skip
)
set /a dspeed=(dbytes-lastdown)/(epoch-lasttime)/10
set ddec=%dspeed:~-2%
set /a dspeed=(dbytes-lastdown)/(epoch-lasttime)/1000
set /a uspeed=(ubytes-lastup)/(epoch-lasttime)/10
set udec=%dspeed:~-2%
set /a uspeed=(ubytes-lastup)/(epoch-lasttime)/1000
echo %time%%TAB%%dbytes%%TAB%%ubytes%%TAB%%dspeed%.%ddec% KB/s%TAB%%uspeed%.%udec% KB/s
:skip

:: Append the .CSV file 
echo %epoch%,%dbytes%,%ubytes% >> "bwlog.csv"

:: Do every 10 seconds
set LOOPCOMPLETE=1
timeout /t 10 /nobreak >nul
goto :looptask

ENDLOCAL

PS: Windows limitations sont le compteur est remis à zéro chaque 4GBytes transférées et à minuit.

---

Vieille solution à l'aide de la tâche scheduller et XAMPP:

J'ai eu de surveiller et de consigner les quantité de données téléchargées comme votre cas, et il a trouvé plus rapide à l'exécution d'un script avec la des tâches de Windows scheduller que vous cherchez un logiciel gratuit pour vider le graphisme info dans un fichier. Peut-être que ma maison script qui fonctionne pour vous.

J'ai commencé un local Apache/PHP serveur à l'aide de XAMPP pour Windows et exécuter ce script en ligne de commande. Par exemple:

"C:\xampp\php\php.exe -f C:\xampp\htdocs\bwlog.php"

La bwlog.php script utilise @phep répondre suggéré de commande de windows netstat -e. Vous pouvez créer le fichier de script avec le bloc-notes, et le code est:

<?php
//Task to schedule "C:\xampp\php\php.exe -f C:\xampp\htdocs\bwlog.php"
//Store console command result
$netstat=shell_exec("netstat -e");
//Start of the bytes transfered line
$line=substr($netstat,strpos($netstat,"Bytes"));    
//End of the line
$line=substr($line,0,strpos($line,"\n"));   
//Get rid of the whitespaces 
$bytes=preg_replace('/\s+/', ' ',$line);    
//Extracting only bytes downloaded
$bytes=substr($bytes,$start=strpos($bytes,' ')+1,strrpos($bytes,' ')-$start);
//Append the .CSV file  
file_put_contents('C:\xampp\htdocs\bwlog.csv',PHP_EOL.time().', '.$bytes,FILE_APPEND);
?>

Puis j'ai traité les la .csv dans un logiciel de feuille de calcul calc le vitesse de téléchargement (bande passante) à l'aide de la différence entre les 2 octets valeur au cours de la différence entre les 2 correspondance des valeurs de temps (octets/secondes).

N'hésitez pas à demander un correctif pour le journal le téléchargement de la octets. Souhaitez-elle être utile.

OriginalL'auteur Leopoldo Sanczyk