Comment puis-je trouver une valeur dans une autre feuille Excel et dans la feuille active à l'aide d'un formulaire?

Eh bien, voici mon problème jusqu'à maintenant, j'ai un formulaire dans visual basic dans le présent formulaire à l'utilisateur de mettre un certain nombre de ce que je veux faire, c'est que excel de recherche dans la Feuil2 Si je reçois ce numéro (si on achte), et dans l'actif de la feuille "Données" s'est déjà conquis, enfin le mettre dans le vide pour la dernière fois Une ligne dans la feuille Sheet1.

J'ai jusqu'à présent.

Private Sub CommandButton1_Click()
Me.TextBox1.Text = ""
Me.TextBox2.Text = ""
End Sub

Private Sub CommandButton2_Click()
Dim lastrow As Double
Dim frange As Range


lastrow = ActiveSheet.UsedRange.Row - 1 + ActiveSheet.UsedRange.Rows.Count

If TextBox1.Text = TextBox2.Text Then


Sheets("Sheet2").Activate
ActiveSheet.Range("A2").Select

If Range("A2:A200").Find(What:=TextBox2.Value _
, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False).Activate Then

Sheets("Datos").Activate

If Range("A3:A200").Find(What:=TextBox2.Value _
, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False).Activate Then

MsgBox ("This number is already registred")

Else

Cells(lastrow + 1, 1) = TextBox2.Value

End If

Else

MsgBox ("The number has not been buyed")

End If

Else

MsgBox ("The number are not the same")

End If

End Sub

J'espère vraiment que quelqu'un de vous peut m'aider car je suis bloqué et je ne vois pas la réponse.

Grâce

Désolé pour mon anglais

InformationsquelleAutor R. Paez | 2012-07-27
  1. 1

    Non testé

    Veuillez voir si c'est ce que vous essayez?

    Private Sub CommandButton1_Click()
    Me.TextBox1.Text = "": Me.TextBox2.Text = ""
End Sub

Private Sub CommandButton2_Click()
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim aCell As Range, bCell As Range
    Dim lrow As Long

    Set ws1 = Sheets("Datos"): Set ws2 = Sheets("Sheet2")

    If TextBox1.Text = TextBox2.Text Then
        Set aCell = ws2.Columns(1).Find(What:=TextBox2.Value _
                , LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, _
                SearchDirection:=xlNext, MatchCase:=False)
        If Not aCell Is Nothing Then
            Set bCell = ws1.Columns(1).Find(What:=TextBox2.Value _
                    , LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, _
                    SearchDirection:=xlNext, MatchCase:=False)
            If Not bCell Is Nothing Then
                MsgBox ("This number is already registred")
            Else
                '~~> This will write to sheet "Datos". if you want to
                '~~> write to sheet Sheet2 then change ws1 to ws2 below
                With ws1
                    lrow = ws1.Range("A" & .Rows.Count).End(xlUp).Row + 1
                    .Cells(lrow, 1) = TextBox2.Value
                End With
            End If
        Else
            MsgBox ("The number has not been buyed")
        End If
    Else
        MsgBox ("The number are not the same")
    End If
End Sub
    • WOW est parfaitement réussie, merci beaucoup.
    InformationsquelleAutor Siddharth Rout