Comment puis-je utiliser le shell variables dans un script awk?

Obtenir des variables shell dans awk

peut être fait de plusieurs façons. Certains sont meilleurs que d'autres. Cela devrait couvrir la plupart d'entre eux. Si vous avez des commentaires, veuillez nous laisser ci-dessous.

---

À l'aide de -v (Le meilleur moyen, le plus portable)

Utiliser le -v option: (P. S. utilisez un espace après -v ou il sera moins portable. E. g., awk -v var= pas awk -vvar=)

variable="line one\nline two"
awk -v var="$variable" 'BEGIN {print var}'
line one
line two

Cela devrait être compatible avec la plupart des awk, et la variable est disponible dans le BEGIN bloc ainsi:

Si vous disposez de plusieurs variables:

awk -v a="$var1" -v b="$var2" 'BEGIN {print a,b}'

Avertissement. Ed Morton écrit, les séquences d'échappement sera interprétée de manière \t devient un véritable tab et pas \t si c'est ce que vous recherchez. Peut être résolu en utilisant ENVIRON[] ou d'y accéder via ARGV[]

---

Variable après le bloc de code

Ici nous obtenons la variable après le awk code. Cela fonctionne très bien tant que vous n'avez pas besoin de la variable dans le BEGIN bloc:

variable="line one\nline two"
echo "input data" | awk '{print var}' var="${variable}"
or
awk '{print var}' var="${variable}" file

Cela fonctionne aussi avec de multiples variables
awk '{print a,b,$0}' a="$var1" b="$var2" file

À l'aide de la variable de cette manière ne fonctionne pas dans BEGIN bloc:

echo "input data" | awk 'BEGIN {print var}' var="${variable}"

---

Chaîne ici

Variable peut également être ajouté à awk à l'aide d'un chaîne ici à partir de coquilles qui les soutiennent (Bash):

awk '{print $0}' <<< "$variable"
test

C'est la même chose que:

printf '%s' "$variable" | awk '{print $0}'

P. S. cette traite la variable en tant que fichier d'entrée.

---

ENVIRON entrée

Comme TrueY écrit, vous pouvez utiliser le ENVIRON pour imprimer Variables d'Environnement.
Définition d'une variable avant de l'exécuter AWK, vous pouvez l'imprimer comme ceci:

X=MyVar awk 'BEGIN{print ENVIRON["X"],ENVIRON["SHELL"]}'
MyVar /bin/bash

---

ARGV entrée

Comme Steven Penny écrit, vous pouvez utiliser ARGV obtenir les données dans awk:

v="my data"
awk 'BEGIN {print ARGV[1]}' "$v"
my data

Pour obtenir les données dans le code lui-même, pas juste de la COMMENCER:

v="my data"
echo "test" | awk 'BEGIN{var=ARGV[1];ARGV[1]=""} {print var, $0}' "$v"
my data test

---

Variable dans le code: à UTILISER AVEC PRUDENCE

Vous pouvez utiliser une variable dans le awk code, mais c'est salissant et difficile à lire, et comme Charles Duffy points à l'extérieur, cette version peut également être une victime de l'injection de code. Si quelqu'un ajoute des choses mauvaises pour la variable, il sera exécuté dans le cadre de la awk code.

Cela fonctionne par extraction de la variable dans le code, de sorte qu'il devient une partie de lui.

Si vous voulez faire un awk qui change de façon dynamique avec l'utilisation de variables, vous pouvez le faire de cette façon, mais NE PAS utiliser pour des variables normales.

variable="line one\nline two"
awk 'BEGIN {print "'"$variable"'"}'
line one
line two

Voici un exemple de l'injection de code:

variable='line one\nline two" ; for (i=1;i<=1000;++i) print i"'
awk 'BEGIN {print "'"$variable"'"}'
line one
line two
1
2
3
.
.
1000

Vous pouvez ajouter beaucoup de commandes à awk de cette façon. Même faire planter avec les commandes valides.

---

Infos supplémentaires:

Utilisation de la double citation

Il est toujours bon de devis double variable "$variable"

Si non, plusieurs lignes seront ajoutées comme une seule longue ligne.

Exemple:

var="Line one
This is line two"

echo $var
Line one This is line two

echo "$var"
Line one
This is line two

D'autres erreurs que vous pouvez obtenir sans double citation:

variable="line one\nline two"
awk -v var=$variable 'BEGIN {print var}'
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ backslash not last character on line
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ syntax error

Et avec une seule citation, il ne développe pas la valeur de la variable:

awk -v var='$variable' 'BEGIN {print var}'
$variable

Plus d'infos sur AWK et les variables

Lisez cette faq.

Utiliser l'un ou l'autre selon la façon dont vous voulez les barres obliques inverses dans le shell variables manipulées (avar est une variable awk, svar est une variable du shell):

awk -v avar="$svar" '... avar ...' file
awk 'BEGIN{avar=ARGV[1];ARGV[1]=""}... avar ...' "$svar" file

Voir http://cfajohnson.com/shell/cus-faq-2.html#Q24 pour plus de détails et d'autres options. La première méthode ci-dessus est presque toujours votre meilleure option et a le plus évident de la sémantique.

Vous pouvez utiliser ARGV:

v=123test
awk 'BEGIN {print ARGV[1]}' "$v"

Notez que si vous allez continuer dans le corps, vous aurez besoin d'ajuster
ARGC:

awk 'BEGIN {ARGC-- } {print ARGV[2], $0}' file "$v"

J'ai juste changé @Jotne réponse à "boucle".

for i in `seq 11 20`; do host myserver-$i | awk -v i="$i" '{print "myserver-"i" " $4}'; done